8.х Выгрузка информационной базы БП 8.1

Тема в разделе "Конфигурирование на платформе "1С:Предприятие 8"", создана пользователем Evgeny, 11 янв 2008.

  1. TopicStarter Overlay
    Evgeny
    Offline

    Evgeny

    Регистрация:
    11 янв 2008
    Сообщения:
    1
    Симпатии:
    0
    Баллы:
    1
    Здравствуйте!
    Вопрос от новичка начинающего разбираться с администрированием 1С. Каким образом можно организовать автоматическую выгрузку базы (цель резервное копирование) средствами ОС или сторонних программ? Может есть какие нибудь параметры командной строки для конфигуратора?
  2. AlexFF
    Offline

    AlexFF Разбирающийся

    Регистрация:
    6 мар 2007
    Сообщения:
    565
    Симпатии:
    1
    Баллы:
    26
    Это как пример
    http://www.1c-pro.ru/index.php?showtopic=7979

    А вообще поиск - рулит.

    Неужли Вам не лень писать сообщение в три строки вместо того чтобы набрать всего одно слово в поиске?
  3. XXLSoft
    Offline

    XXLSoft Опытный в 1С

    Регистрация:
    1 ноя 2006
    Сообщения:
    55
    Симпатии:
    0
    Баллы:
    26
    У меня это выглядит примерно так:

    Код:
    Option Explicit
    
    ' Объявление переменных
    Dim objWSHShell           ' Хранит: ссылку на объект
    Dim objFSO                ' Хранит: ссылку на объект
    Dim strCreateBackupDate   ' Хранит: дату создания резервной копии
    Dim strDeleteBackupDate   ' Хранит: дату удаления резервной копии
    Dim strPathDB             ' Хранит: путь к файлу БД 1С
    Dim strFileNameDB         ' Хранит: имя файла БД 1С
    Dim strServerDB           ' Хранит: имя компьютера, работающего сервером приложений 1С
    Dim strNameDB             ' Хранит: имя информационной базы
    Dim strUserName           ' Хранит: имя пользователя БД 1С
    Dim strPassword           ' Хранит: пароль для доступа к БД 1С
    
    
    ' Инициализация объектов
    Set objWSHShell = WScript.CreateObject("WScript.Shell")
    Set objFSO      = CreateObject("Scripting.FileSystemObject")
    
    ' Инициализация переменных
    strCreateBackupDate = ConvertDate(DateAdd("d", 0, Now))
    strDeleteBackupDate = ConvertDate(DateAdd("d", -3, Now))
    strPathDB           = "C:\1CLOGISTICS_NET\BASE_NEW_ASU\"
    strFileNameDB       = "1CV81_BASE_IT_"
    strServerDB         = "APP-SML1C02"
    strNameDB           = "1CV81_BASE_IT"
    strUserName         = "[имя пользователя]"
    strPassword         = "[пароль]"
    
    
    if objFSO.FileExists(strPathDB & strFileNameDB & strDeleteBackupDate & ".dt") then
    ' Удаляем файл резервной копии БД 1С, трех дневной давности
    objFSO.DeleteFile strPathDB & strFileNameDB & strDeleteBackupDate & ".dt"
    end if
    
    ' Запускаем 1С в пакетном режиме
    objWSHShell.Run("C:\PROGRA~1\1CV81\BIN\1CV8.EXE CONFIG " & "/S" & strServerDB & "\" & strNameDB & " /N" & strUserName & " /P" & strPassword & " /DumpIB" & strPathDB & strFileNameDB & strCreateBackupDate & ".dt""")
    
    ' Завершаем работу с объектами, и удаляем ссылки на них
    Set objWSHShell = Nothing
    Set objFSO      = Nothing
    
    
    function ConvertDate(strDate)
    
    Dim strDay     ' Хранит: день месяца
    Dim strMonth   ' Хранит: номер месяца
    Dim strYear    ' Хранит: год
    
    
    ' Анализируем дату
    strDay   = mid(strDate, 1, 2)
    strMonth = mid(strDate, 4, 2)
    strYear  = mid(strDate, 7, 4)
    
    ' Возвращаем дату в обратном порядке
    ConvertDate = strYear & strMonth & strDay
    
    end function
    
    

Поделиться этой страницей