[РЕШЕНО] Текущая таблица

Тема в разделе "Конфигурирование на платформе "1С:Предприятие 7.7"", создана пользователем Samouchka, 2 апр 2015.

  1. TopicStarter Overlay
    Samouchka
    Offline

    Samouchka Опытный в 1С

    Регистрация:
    20 мар 2013
    Сообщения:
    214
    Симпатии:
    1
    Баллы:
    29
    йоксель имеет недостатки по сравнению с виртуальными принтерами. Пишут на инфостарте, что во-первых, таблица сохраняется картинкой, во-вторых, создается автоматически временный файл. Поэтому, мой способ предпочтительнее. Я еще раз повторю, что печатать на принтер в ПДФ любую таблицу я могу по кнопке принтера. Но для этого мне надо руками выбирать нужный принтер, а затем вручную отправлять файл по эл. почте, т.к. я тогда не смогу обратиться к файлу ПДФ по имени для его добавления в эл. письмо. Я не пойму и не могу нигде найти:
    1) Как обратиться к открытой в 1с таблице, которая может быть любой, но одновременно открыта только одна таблица
    2) Как вывести заголовок открытой таблицы в переменную (чтобы в дальнейшем обратиться к сохраненному файлу для отправки по эл. почте)
  2. TopicStarter Overlay
    Samouchka
    Offline

    Samouchka Опытный в 1С

    Регистрация:
    20 мар 2013
    Сообщения:
    214
    Симпатии:
    1
    Баллы:
    29
    Не понял. Мое последнее сообщение что ли удалили? Я говорил:
    "Йоксель имеет недостаток по сравнению с виртуальными ПДФ принтерами в том, что файл сохраняется в картинку. Поэтому, мой способ предпочтительнее. Напечатать в ПДФ любую таблицу можно, но тогда надо вручную выбирать принтер и вручную отправлять файл по эл. почте. Я не могу понять и нигде найти как:
    1) Сохранить в ПДФ любую открытую таблицу в 1с
    2) Передать в переменную заголовок таблицы (для последующего обращения к файлу, чтобы добавить его в эл. письмо).
    --- Объединение сообщений, 6 апр 2015 ---
    Почему мои сообщения удаляются?
    --- Объединение сообщений, 6 апр 2015 ---
    Извиняюсь дико! Сообщения просто перешли на 2 страницу, и никуда не удаляются. Просто раньше я в одну страницу укладывался. А с этой темой нет.
    Последнее редактирование: 6 апр 2015
  3. Бухгалтерский угодник
    Offline

    Бухгалтерский угодник Администраторы Команда форума Администратор

    Регистрация:
    29 дек 2008
    Сообщения:
    21.523
    Симпатии:
    407
    Баллы:
    104
    в FormEx в методе СЕРВИС есть процедура СписокТаблиц() ею и воспользуйтесь...
    Метод хранимого объекта "записать" аналогичен штатному...
    Методика такая:
    1) Определяем в списке нужную таблицу
    2) Сохраняем как ВРЕМЕННУ
    3) Открываем (имя нам известно)
    4) Без вывода на экран отправляем на нужный вам принтер
    Последнее редактирование: 6 апр 2015
  4. TopicStarter Overlay
    Samouchka
    Offline

    Samouchka Опытный в 1С

    Регистрация:
    20 мар 2013
    Сообщения:
    214
    Симпатии:
    1
    Баллы:
    29
    А вот СписокТаблиц() я уже использовал. Только я не знаю как сохранить таблицу как временную. Из-за этого видимо ошибка

    ТабЗнач.ПараметрыСтраницы(,,,,,,,,,,,"Bullzip PDF Printer");
    {C:\DOCUMENTS AND SETTINGS\USER\РАБОЧИЙ СТОЛ\ДЕНИС ПАПКА\ПДФ И ОТПРАВКА.ERT(32)}: Значение не представляет агрегатный объект (ПараметрыСтраницы)

    Вот еще раз мой код. Исправьте или допишите, пожалуйста, если не затруднит:

    Код:
    Путь = КаталогИБ() + "FormEx.dll";
        Если ЗагрузитьВнешнююКомпоненту(Путь) = 0 Тогда
            Сообщить("Неудачная попытка загрузить FormEx.dll");
            СтатусВозврата(0);
            Возврат;
        КонецЕсли;
        Таблиц = СоздатьОбъект("Сервис");
        СПТ=Таблиц.СписокТаблиц();
        СПТ.ПолучитьЗначение(1,ТабЗнач);
        ТабЗнач.ПараметрыСтраницы(,,,,,,,,,,,"Bullzip PDF Printer");
        ТабЗнач.Напечатать(0);
  5. TopicStarter Overlay
    Samouchka
    Offline

    Samouchka Опытный в 1С

    Регистрация:
    20 мар 2013
    Сообщения:
    214
    Симпатии:
    1
    Баллы:
    29
    Например, если сохранить таблицу методом Записать(), снова ошибка:

    ТабЗнач.Записать(ИмФайл,0);
    {C:\DOCUMENTS AND SETTINGS\USER\РАБОЧИЙ СТОЛ\ДЕНИС ПАПКА\ПДФ И ОТПРАВКА.ERT(13)}: Значение не представляет агрегатный объект (Записать)

    А что вообще возвращает СписокТаблиц(). Таблицы должен, судя по документации. А 1С пишет ошибки, как буд-то бы возвращается строка с заголовком таблицы, но не сама таблица. Вот очередной неверный код:

    Код:
    Перем ТабЗнач;
        //Сохраняем в ПДФ
        //определяем текущую таблицу
       
    Таблиц = СоздатьОбъект("Сервис");
        СПТ=Таблиц.СписокТаблиц();
        СПТ.ПолучитьЗначение(1,ТабЗнач);
        ИмФайл=СокрЛП(Константа.КаталогФайловЭлПочты)+"\"+Лев(ТабЗнач, СтрДлина(ТабЗнач)-3);
        ТабЗнач.Записать(ИмФайл,0);
        ТабЗнач.Открыть(ИмФайл);
        ТабЗнач.ПараметрыСтраницы(,,,,,,,,,,,"Bullzip PDF Printer");
        ТабЗнач.Напечатать(0);
  6. Хряк
    Offline

    Хряк Профессионал в 1С

    Регистрация:
    26 сен 2007
    Сообщения:
    1.447
    Симпатии:
    37
    Баллы:
    54
    СПТ.ПолучитьЗначение(1,ТабЗнач) - неверно
    аКонт=СПТ.ПолучитьЗначение(1) - в аКонт получишь объект Таблица, но имени не будет
    ну а дальше
    аКонт.параметрыстраницы...
    Samouchka нравится это.
  7. TopicStarter Overlay
    Samouchka
    Offline

    Samouchka Опытный в 1С

    Регистрация:
    20 мар 2013
    Сообщения:
    214
    Симпатии:
    1
    Баллы:
    29
    Уррра!!!:) Всё получилось! Осталось только учесть длинные имена файлов, которые автоматически урезаются при сохранении на булзип принтер (отчеты, акт сверки и т.п.). Для таких таблиц надо сделать возможность исправлять имя сохраняемого файла вручную, т.е. в форме обработки указывать имя сохраняемого файла, которое будет скопировано из формы печати булзип принтера. Тогда всё будет ништякого. Вот он победоносный код, в дальнейшем выложу обработку - может кому пригодится.

    Код:
    Процедура СохранитьВПДФ()
        Перем ТабЗнач;
        //Сохраняем в ПДФ
        //определяем текущую таблицу   
        Таблиц = СоздатьОбъект("Сервис");
        СПТ=Таблиц.СписокТаблиц();
        СПТ.ПолучитьЗначение(1,ТабЗнач);
        ТабЗначБезЗвезды=Лев(ТабЗнач, СтрДлина(ТабЗнач)-3);
        Если Прав(ТабЗначБезЗвезды,3)="pdf" Тогда
            ТабЗнач1=ТабЗначБезЗвезды;
        КонецЕсли;
        Если Прав(ТабЗначБезЗвезды,3)<>"pdf" Тогда
            ТабЗнач1=ТабЗначБезЗвезды+".pdf";
        КонецЕсли;
        аКонт=СПТ.ПолучитьЗначение(1);
        аКонт.ПараметрыСтраницы(,,,,,,,,,,,"Bullzip PDF Printer");
        аКонт.Напечатать(0);
        //Название файла - это заголовок открытой таблицы +pdf
        ВыборОтчет=СокрЛП(Константа.КаталогФайловЭлПочты);
        НазваниеФайла=ТабЗнач1;
        ПутьКФайлу=ВыборОтчет+"\"+НазваниеФайла;
        //Пихаем в строку что нужно
    КонецПроцедуры
  8. Хряк
    Offline

    Хряк Профессионал в 1С

    Регистрация:
    26 сен 2007
    Сообщения:
    1.447
    Симпатии:
    37
    Баллы:
    54
    Слава тебе, ...
  9. Бухгалтерский угодник
    Offline

    Бухгалтерский угодник Администраторы Команда форума Администратор

    Регистрация:
    29 дек 2008
    Сообщения:
    21.523
    Симпатии:
    407
    Баллы:
    104
    Я бы на этом не успокаивался... А вдруг на форме не одна открытая таблица?
    И первая не является нужной? Доделывать уж до конца........
  10. TopicStarter Overlay
    Samouchka
    Offline

    Samouchka Опытный в 1С

    Регистрация:
    20 мар 2013
    Сообщения:
    214
    Симпатии:
    1
    Баллы:
    29
    Если на форме несколько таблиц, то это скорее всего будут внутренние документы (акт сдачи-приема ОС, 1-НДФЛ, например), которые формировать в ПДФ и отправлять не нужно. Так что лично я уже успокоился. Высылаю обработку, как и обещал. В обработке у меня создается документ ЭлектронноеПисьмоИсходящее, потому привожу его модуль. Кому надо и отправлять ПДФ из формы обработки, смотрите процедуру ОтправитьПисьмо().

    Код:
    Перем НазваниеФайла;
    Перем СЗ;
    Перем СЗ2;
    
    
    Функция СканироватьКаталог(_каталог)
        списокФайлов = СоздатьОбъект("СписокЗначений");
            ФС.УстТекКаталог(_каталог);
            файл_ = СокрЛП(ФС.НайтиПервыйФайл("*.*"));
            Пока файл_ <> "" Цикл
                Если (файл_=".") или (файл_="..") Тогда
                    файл_=ФС.НайтиСледующийФайл();
                    Продолжить;
                КонецЕсли; //(файл_=".") или (файл_="..")
                списокФайлов.ДобавитьЗначение(файл_);
                файл_=ФС.НайтиСледующийФайл();
            КонецЦикла;
            // Теперь пройдемся по списку
            Для ы=1 По списокФайлов.РазмерСписка() Цикл
                ФС.УстТекКаталог(_каталог);
                файл_ = списокФайлов.ПолучитьЗначение(ы);
                ФС.АтрибутыФайла(файл_,"","");
                ТЗ.НоваяСтрока();
                ТЗ.НаимФайла=файл_;
                ТЗ.ПутьФайла=_каталог+"\"+файл_;
            КонецЦикла;
    КонецФункции
    
    Процедура ЗагрузитьТЗВложения()
        ВосстановитьЗначение(СтрокаПутьФайла);
        ВосстановитьЗначение(СтрокаНаимФайла);
       
        Если ПустаяСтрока(СтрокаПутьФайла)=0 Тогда
            Если ПустаяСтрока(СтрокаНаимФайла)=0 Тогда
                СЗ.ИзСтрокиСРазделителями(СтрокаПутьФайла);
                СЗ2.ИзСтрокиСРазделителями(СтрокаНаимФайла);
                Для сч=1 по СЗ.РазмерСписка() Цикл
                    ТЗ.НоваяСтрока();
                    ТЗ.ПутьФайла=СЗ.ПолучитьЗначение(ТЗ.НомерСтроки);
                    ТЗ.НаимФайла=СЗ2.ПолучитьЗначение(ТЗ.НомерСтроки);
                КонецЦикла;
            КонецЕсли;
        КонецЕсли;
    КонецПроцедуры
    
    Процедура ПриОткрытии()
        Если ТЗ.КоличествоКолонок()=0 Тогда
        ТЗ.ВставитьКолонку("ПутьФайла",,,1000,,"Путь файла",14);
        ТЗ.ВставитьКолонку("НаимФайла",,,500,,"Имя файла",3);
        КонецЕсли;
       
        Форма.ИспользоватьСлой("Основной",2);
        Форма.ИспользоватьЗакладки(1);
        Форма.Закладки.ДобавитьЗначение(1, "Основной");
        Форма.Закладки.ДобавитьЗначение(2, "Получатели");
        Форма.Закладки.ДобавитьЗначение(3, "Вложения");
       
        ЗагрузитьТЗВложения();
       
        //Прикрепляем файл если нужно
        Конт=Форма.Параметр;
        Если ПустоеЗначение(Конт)=0 Тогда
            ТЗ.НоваяСтрока();
            ПозКонт=Найти(Конт,";");
            Конт3=Сред(Конт,ПозКонт+1);
            ТЗ.НаимФайла=Конт3;
            ТЗ.ПутьФайла=Лев(Конт,ПозКонт-1);
        КонецЕсли;
    КонецПроцедуры
    
    Процедура ПриВыбореЗакладки(НомерЗакладки, ЗначениеЗакладки)
        Если НомерЗакладки = 1 Тогда
            Форма.ИспользоватьСлой("Основной",2);
        КонецЕсли;
        Если НомерЗакладки = 2 Тогда
            Форма.ИспользоватьСлой("Получатели",2);
        КонецЕсли;
        Если НомерЗакладки = 3 Тогда
            Форма.ИспользоватьСлой("Вложения",2);
        КонецЕсли;
    КонецПроцедуры
    
    Процедура ПолучателиПоУмолчанию()
        Получат = СоздатьОбъект("Справочник.МылоПолучателей");
        Получат.ВыбратьЭлементы();
        Пока Получат.ПолучитьЭлемент()=1 Цикл
            Если Получат.ДобЭП=1 Тогда
                НоваяСтрока();
                ДобМыло=Получат.ТекущийЭлемент();
                Получатель=ДобМыло;
                МылоПолучателя=ДобМыло.Имейл;
                НазваниеПолучателя=ДобМыло.Наименование;
                Контрагент=ДобМыло.Контрагент;
            КонецЕсли;
        КонецЦикла;
    КонецПроцедуры
    
    Процедура СменаПолучателя()
        МылоПолучателя=Получатель.Имейл;
        НазваниеПолучателя=Получатель.Наименование;
        Контрагент=Получатель.Контрагент;
    КонецПроцедуры
    
    Процедура ДобавитьПапку()
        ДобПапка=СокрЛП(Константа.КаталогФайловЭлПочты);
        ВыбПапка=ФС.ВыбратьКаталог(ДобПапка,"Выберите папку для добавления",);
        Если ВыбПапка=1 Тогда
            СканироватьКаталог(ДобПапка);
        КонецЕсли;
    КонецПроцедуры
    
    Процедура ДобавитьФайл()
        ВыборОтчет=СокрЛП(Константа.КаталогФайловЭлПочты);
        ВыбКаталОтчета=ФС.ВыбратьФайл(0,НазваниеФайла,ВыборОтчет,"Выберите файл",,,);
        Если ВыбКаталОтчета=1 Тогда
            ТЗ.НоваяСтрока();
            ТЗ.ПутьФайла=ВыборОтчет+НазваниеФайла;
            ТЗ.НаимФайла=НазваниеФайла;
        КонецЕсли;
    КонецПроцедуры
    
    Процедура ПросмотрФайла()
        ЗапуститьПриложение(ТЗ.ПутьФайла);
    КонецПроцедуры
    
    Процедура УдалитьФайл()
        ТЗ.УдалитьСтроку(ТЗ.НомерСтроки);
    КонецПроцедуры
    
    Процедура СохранитьТЗВложения()
        СЗ.УдалитьВсе();
        СЗ2.УдалитьВсе();
        ТЗ.Выгрузить(СЗ,,,"ПутьФайла");
        ТЗ.Выгрузить(СЗ2,,,"НаимФайла");
        СтрокаПутьФайла=СЗ.ВСтрокуСРазделителями();
        СтрокаНаимФайла=СЗ2.ВСтрокуСРазделителями();
        СохранитьЗначение(СтрокаПутьФайла,СтрокаПутьФайла);
        СохранитьЗначение(СтрокаНаимФайла,СтрокаНаимФайла);
       
        Форма.Обновить();
        Записать();
    КонецПроцедуры
    
    Процедура УдалитьПриОтправке()
        Ответ=Вопрос("Очистить папку "+СокрЛП(Константа.КаталогФайловЭлПочты)+"?",4);
        Если Ответ=7 тогда
            Возврат;
        КонецЕсли;
        Если Ответ=6 тогда
       
        _каталог=СокрЛП(Константа.КаталогФайловЭлПочты);
        списокФайлов = СоздатьОбъект("СписокЗначений");
            ФС.УстТекКаталог(_каталог);
            файл_ = СокрЛП(ФС.НайтиПервыйФайл("*.*"));
            Пока файл_ <> "" Цикл
                Если (файл_=".") или (файл_="..") Тогда
                    файл_=ФС.НайтиСледующийФайл();
                    Продолжить;
                КонецЕсли; //(файл_=".") или (файл_="..")
                списокФайлов.ДобавитьЗначение(файл_);
                файл_=ФС.НайтиСледующийФайл();
            КонецЦикла;
            // Теперь пройдемся по списку
            Для ы=1 По списокФайлов.РазмерСписка() Цикл
                ФС.УстТекКаталог(_каталог);
                файл_ = списокФайлов.ПолучитьЗначение(ы);
                ФС.АтрибутыФайла(файл_,"","");
                ФС.УдалитьФайл(файл_);
            КонецЦикла;
        КонецЕсли;
    КонецПроцедуры
    
    Процедура ОтправитьПисьмо()
        СохранитьТЗВложения();
        ДатаОтправкиПисьма=ТекущаяДата();
        ПисьмоОтправлено=1;
        //загрузка компоненты v7plus
        Если ЗагрузитьВнешнююКомпоненту(КаталогИБ()+"v7plus.dll") <> 1 Тогда
               Предупреждение("Компонента v7plus.dll не найдена!");
               Возврат; //прервать выполнение процедуры
        КонецЕсли;
           Попытка
        Почта = СоздатьОбъект("AddIn.V7Mail");
        Исключение
        Предупреждение("Не удалось создать объект Addin.V7Mail!");
        КонецПопытки;
    
        Попытка
        Почта.Подключиться();
        Почта.НовоеСообщение();
       
        ВыбратьСтроки();
        Пока ПолучитьСтроку()=1 Цикл
            Почта.ДобавитьАдрес(СокрЛП(МылоПолучателя));
        КонецЦикла;
        ТЗ.ВыбратьСтроки();
        Пока ТЗ.ПолучитьСтроку()=1 Цикл
            Почта.ДобавитьФайл(ТЗ.ПутьФайла);
        КонецЦикла;
    
        Почта.Заголовок = ТемаПисьма;
        Почта.Текст = ТекстПисьма;
        Почта.Послать(1);
        //Почта.Отключиться();
        Исключение
        Предупреждение("Неудачная попытка! Отправка письма по эл. почте не произведена!");
        Возврат;
        КонецПопытки;
    КонецПроцедуры
    
    Процедура ВводНового()
        ТЗ.ВставитьКолонку("ПутьФайла",,,1000,,"Путь файла",14);
        ТЗ.ВставитьКолонку("НаимФайла",,,500,,"Имя файла",3);
        АдресОтправителяПисьма=Константа.АдресЭлПочты;
        ДобПапка=СокрЛП(Константа.КаталогФайловЭлПочты);
        Конт=Форма.Параметр;
        Если ПустоеЗначение(Конт)=1 Тогда
            СканироватьКаталог(ДобПапка);
        КонецЕсли;
        ПолучателиПоУмолчанию();
    КонецПроцедуры
    
    Процедура ПриЗаписи()
        СохранитьТЗВложения();
    КонецПроцедуры
    
    Процедура ПриЗакрытии()
        СохранитьТЗВложения();
    КонецПроцедуры
    
    
    СЗ=СоздатьОбъект("СписокЗначений");
    СЗ2=СоздатьОбъект("СписокЗначений");
  11. Бухгалтерский угодник
    Offline

    Бухгалтерский угодник Администраторы Команда форума Администратор

    Регистрация:
    29 дек 2008
    Сообщения:
    21.523
    Симпатии:
    407
    Баллы:
    104
    Удобнее было бы выложить в виде обработки в копилку...
  12. TopicStarter Overlay
    Samouchka
    Offline

    Samouchka Опытный в 1С

    Регистрация:
    20 мар 2013
    Сообщения:
    214
    Симпатии:
    1
    Баллы:
    29
    А .ert файлы разве у вас на форуме не грузятся? Тогда ловите полный модуль обработки - просто очень хочется поделиться:

    Код:
    //*******************************************
    Перем Конт2;
    Перем ВыборОтчет;
    Перем СПТ;
    Перем ТабЗначБезЗвезды;
    
    Процедура АвтоСменаНазвания()
        //Урежем длинный заголовок таблицы до 35 символов (включая ".pdf")
        Если СтрДлина(ТабЗначБезЗвезды)>31 Тогда
            ТабЗнач1=Лев(ТабЗначБезЗвезды,31)+".pdf";
            НазваниеФайла=ТабЗнач1;
            ПутьКФайлу=ВыборОтчет+"\"+НазваниеФайла;
            Текст1="Имя сохраняемого в PDF файла требуется сократить до 35 символов, включая расширение.";
            Текст2=" Если Вас устраивает получившееся обрезанное название файла, сразу жмите кнопки Сохранить в PDF и Отправить PDF.";
            Текст3=" Если Вас не устраивает получившееся обрезанное название файла надо сделать следующее:";
            Текст4=" - Придумать имя которое вам нравится, обязательно оканчивающееся на .pdf. Удалить имя по умолчанию, нажав кнопку Х возле названия файла. Ввести придуманное имя и подтвердить ввод кнопкой V";
            Текст5=" - При этом действии путь к файлу автоматически изменится. Далее нажмите кнопку Сохранить PDF.";
            Текст6=" - В открывшемся диалоге Bullzip PDF Printer - Создать файл жмёте Сохранить.";
            Текст7=" Теперь можно отправлять файл по кнопке Отправить PDF.";
            Перенос = Симв(13)+Симв(10);
            Предупреждение(Текст1+Перенос+Текст2+Перенос+Текст3+Перенос+Текст4+Перенос+Текст5+Перенос+Текст6+Перенос+Текст7);
        КонецЕсли;
    КонецПроцедуры
    
    Процедура ПриОткрытии()
        Перем ТабЗнач;
        //определяем текущую таблицу
        Таблиц = СоздатьОбъект("Сервис");
        СПТ=Таблиц.СписокТаблиц();
        СПТ.ПолучитьЗначение(1,ТабЗнач);
        ТабЗначБезЗвезды=Лев(ТабЗнач, СтрДлина(ТабЗнач)-3);
        Если Прав(ТабЗначБезЗвезды,4)=".pdf" Тогда
            ТабЗнач1=ТабЗначБезЗвезды;
        КонецЕсли;
        Если Прав(ТабЗначБезЗвезды,4)<>".pdf" Тогда
            ТабЗнач1=ТабЗначБезЗвезды+".pdf";
        КонецЕсли;
       
        //Заполняем имя файла и путь
        //Название файла - это заголовок открытой таблицы + ".pdf"
        ВыборОтчет=СокрЛП(Константа.КаталогФайловЭлПочты);
        НазваниеФайла=ТабЗнач1;
        ПутьКФайлу=ВыборОтчет+"\"+НазваниеФайла;
        //Учтем длинные имена файлов и обрежем их для сохранения в ПДФ
        Если СтрДлина(ТабЗначБезЗвезды)>31 Тогда
            АвтоСменаНазвания();
        КонецЕсли;
    КонецПроцедуры
    
    Процедура СохранитьВПДФ()
        //Устанавливаем ПутьКФайлу в настройки принтера
        ПринтерPDF = СоздатьОбъект ("Bullzip.PDFPrinterSettings");
        ПринтерPDF.SetValue("output",ПутьКФайлу);
        ПринтерPDF.WriteSettings();
        //Сохраняем в ПДФ   
        аКонт=СПТ.ПолучитьЗначение(1);
        аКонт.ПараметрыСтраницы(,,,,,,,,,,,"Bullzip PDF Printer");
        аКонт.Напечатать(0);
    КонецПроцедуры
    
    Процедура ОтправитьПДФ()
        //Пихаем в строку что нужно
        Конт2=ПутьКФайлу+";"+НазваниеФайла;
        //открываем форму электронного письма
        ОткрытьФорму("Документ.ЭлектронноеПисьмоИсходящее", Конт2);
    КонецПроцедуры
    
    Процедура УдалитьПДФ()
        Ответ=Вопрос("Удалить файл "+СокрЛП(НазваниеФайла)+" из папки "+ВыборОтчет+"?",4);
        Если Ответ=7 тогда
            Возврат;
        КонецЕсли;
        Если Ответ=6 тогда
        ФС.УдалитьФайл(ПутьКФайлу);
        КонецЕсли;
    КонецПроцедуры
    
    Процедура СменаНазвания()
        ПутьКФайлу=ВыборОтчет+"\"+НазваниеФайла;
    КонецПроцедуры
    
    Путь = КаталогИБ() + "FormEx.dll";
        Если ЗагрузитьВнешнююКомпоненту(Путь) = 0 Тогда
            Сообщить("Неудачная попытка загрузить FormEx.dll");
            СтатусВозврата(0);
            //Возврат;
        КонецЕсли;
    
  13. man37
    Offline

    man37 Опытный в 1С

    Регистрация:
    10 дек 2013
    Сообщения:
    197
    Симпатии:
    5
    Баллы:
    29
    Как не сохраняется? А "Загрузить файл" разве не работает.
  14. Хряк
    Offline

    Хряк Профессионал в 1С

    Регистрация:
    26 сен 2007
    Сообщения:
    1.447
    Симпатии:
    37
    Баллы:
    54
    не грузит ert
  15. Бухгалтерский угодник
    Offline

    Бухгалтерский угодник Администраторы Команда форума Администратор

    Регистрация:
    29 дек 2008
    Сообщения:
    21.523
    Симпатии:
    407
    Баллы:
    104
    так запакуйте архиватором

Поделиться этой страницей