8.х Помогите! поле объекта не обноружено

Тема в разделе "Конфигурирование на платформе "1С:Предприятие 8"", создана пользователем Александр 1906, 17 сен 2015.

Статус темы:
Закрыта.
  1. TopicStarter Overlay
    Александр 1906
    Offline

    Александр 1906 Опытный в 1С

    Регистрация:
    25 июн 2015
    Сообщения:
    351
    Симпатии:
    3
    Баллы:
    29
    ладно буду сам ковыряться , все спасибо!
  2. AlenkaInt
    Offline

    AlenkaInt Опытный в 1С

    Регистрация:
    26 фев 2012
    Сообщения:
    1.008
    Симпатии:
    4
    Баллы:
    29
    Присоединяюсь. А nomad_irk только и отсылает на ИТС, Синтанксис-помощник, почитать методички. Читать методички дело хорошее, но только если знаешь вообще что читать, а то бывает запутываешься еще больше. Я думаю если хочешь помочь - помогай, а нет - иди мимо. А послать учить матчасть каждый дурак может.
  3. alexburn
    Online

    alexburn Модераторы Команда форума Модератор

    Регистрация:
    5 янв 2009
    Сообщения:
    14.755
    Симпатии:
    509
    Баллы:
    204
    Нет, а что вам не нравится ??? С какой стати мы должны кому-то и что-то ??? Мы наталкиваем человека на мысль, советуем что нужно делать, что почитать, исходя из своего опыта. Что толку если мы решим задачу ? Тут потом же помощь требовать будут всякие халявщики. А с чего это нам свои знания бесплатно раздавать ??? Мы помогаем пользователям по мере возможности, и заметьте, БЕСПЛАТНО!
  4. TerANik
    Offline

    TerANik Профессионал в 1С

    Регистрация:
    19 ноя 2014
    Сообщения:
    997
    Симпатии:
    70
    Баллы:
    54
    Блин а я категорически не согласен.. ибо я взял обработку внешнюю печатную форму, хотя ни разу сам под управляемые формы не делал и вижу его структуру.. и сделаю по ней, вот пример кода.

    Код:
    Функция СведенияОВнешнейОбработке() Экспорт
       
        ПараметрыРегистрации = Новый Структура;
       
        ПараметрыРегистрации.Вставить("Вид", "ПечатнаяФорма");
        ПараметрыРегистрации.Вставить("Назначение", ПолучитьНазначениеОбработки());
        ПараметрыРегистрации.Вставить("Наименование", "Акт приема-передачи денежных средств");
        ПараметрыРегистрации.Вставить("Версия", "1.01");    // УдалитьФизЛицо
        ПараметрыРегистрации.Вставить("БезопасныйРежим", Истина);
        ПараметрыРегистрации.Вставить("Информация", "Дополнительная печатная форма к документу Реализация");
       
        ТаблицаКоманд = ПолучитьТаблицуКоманд();
       
        ДобавитьКоманду(ТаблицаКоманд,
        "Акт приема-передачи денежных средств", 
        "АктСдачиПриемкиДС",   
        "ВызовСерверногоМетода",
        Истина,
        "ПечатьMXL");
       
        ПараметрыРегистрации.Вставить("Команды", ТаблицаКоманд);
       
        Возврат ПараметрыРегистрации;
    
    КонецФункции
    
    Функция ПолучитьТаблицуКоманд()
       
        Команды = Новый ТаблицаЗначений;
        Команды.Колонки.Добавить("Представление", Новый ОписаниеТипов("Строка"));
        Команды.Колонки.Добавить("Идентификатор", Новый ОписаниеТипов("Строка"));
        Команды.Колонки.Добавить("Использование", Новый ОписаниеТипов("Строка"));
        Команды.Колонки.Добавить("ПоказыватьОповещение", Новый ОписаниеТипов("Булево"));
        Команды.Колонки.Добавить("Модификатор", Новый ОписаниеТипов("Строка"));
       
        Возврат Команды;
       
    КонецФункции
    
    Процедура ДобавитьКоманду(ТаблицаКоманд, Представление, Идентификатор, Использование, ПоказыватьОповещение = Ложь, Модификатор = "")
    
      НоваяКоманда = ТаблицаКоманд.Добавить();
      НоваяКоманда.Представление = Представление;
      НоваяКоманда.Идентификатор = Идентификатор;
      НоваяКоманда.Использование = Использование;
      НоваяКоманда.ПоказыватьОповещение = ПоказыватьОповещение;
      НоваяКоманда.Модификатор = Модификатор;
    
    КонецПроцедуры
    
    Функция ПолучитьНазначениеОбработки()
       
        Назначение = Новый Массив;
       
        Назначение.Добавить("Документ.РеализацияТоваровУслуг");
        //Назначение.Добавить("Документ.ПеремещениеТоваров");
       
        Возврат Назначение;
       
    КонецФункции
    
    // Интерфейс для запуска логики обработки
    //
    // Параметры ВХОДЯЩИЕ:
    // МассивОбъектов - Массив - массив ссылок на объекты печати
    // Параметры ИСХОДЯЩИЕ:
    // КоллекцияПечатныхФорм - ТаблицаЗначений - таблица содержащая информацию по печатным формам (Сформированные табличные документы)
    // ОбъектыПечати - СписокЗначений - ссылки на объекты печати
    // ПараметрыВывода - Структура - дополнительные параметры вывода (печать покомплектно и др.)
    //
    Процедура Печать(МассивОбъектов, КоллекцияПечатныхФорм,    ОбъектыПечати, ПараметрыВывода) Экспорт
       
        //ПараметрыВывода.ДоступнаПечатьПоКомплектно = Истина;
       
        Если УправлениеПечатью.НужноПечататьМакет(КоллекцияПечатныхФорм, "АктСдачиПриемкиДС") Тогда
            УправлениеПечатью.ВывестиТабличныйДокументВКоллекцию(
                        КоллекцияПечатныхФорм, "АктСдачиПриемкиДС", "Акт приема-передачи товара денежных средств",    //ИмяМакета, СинонимМакета
                        СформироватьПечатнуюФормуАкт(МассивОбъектов, ОбъектыПечати));  //ТабличныйДокумент
        КонецЕсли;
    КонецПроцедуры // Печать()
    
    Функция СформироватьПечатнуюФормуАкт(МассивОбъектов, ОбъектыПечати)
       
        УстановитьПривилегированныйРежим(Истина);
    
        ТабличныйДокумент = Новый ТабличныйДокумент;
        ТабличныйДокумент.ИмяПараметровПечати = "ПАРАМЕТРЫ_ПЕЧАТИ_РеализацияТоваровУслуг_Акт";
       
        МассивРезультатов = ПолучитьДанныеДляПечати(МассивОбъектов);
          ДанныеПечати      = МассивРезультатов[0].Выбрать();
       
        ПервыйДокумент = Истина;
       
        Пока ДанныеПечати.Следующий() Цикл
            Если ДанныеПечати.Контрагент.ЮрФизЛицо = Перечисления.ЮрФизЛицо.ЮрЛицо Тогда
                Сообщение = НСтр("ru = 'Для юридических лиц печатная форма не формируется.'");
                ОбщегоНазначенияКлиентСервер.СообщитьПользователю(Сообщение);
                Продолжить;
            КонецЕсли;   
           
            Если Не ПервыйДокумент Тогда
                ТабличныйДокумент.ВывестиГоризонтальныйРазделительСтраниц();
            КонецЕсли;
           
            ПервыйДокумент    = Ложь;
            НомерСтрокиНачало = ТабличныйДокумент.ВысотаТаблицы + 1;
           
            Макет = ПолучитьМакет("Акт");
           
            // Выводим шапку акта
            НомерДоговора = ?(ЗначениеЗаполнено(ДанныеПечати.Договор.Номер), ДанныеПечати.Договор.Номер,"___________");
            ДатаДоговора  = Формат(ТекущаяДата(), "ДФ=""дд ММММ гггг """"г.""""""");
           
            //Экспедитор -> Контрагент
            Исполнитель = ДанныеПечати.Экспедитор;
            // Лахардов
            //Заказчик    = ДанныеПечати.Контрагент.ФизЛицо;
            Заказчик    = ДанныеПечати.Контрагент.УдалитьФизЛицо;
            Если Заказчик.Пустая () Тогда
                Заказчик = ДанныеПечати.Контрагент.Партнер;
            КонецЕсли;
           
            //
            ОбластьМакета = Макет.ПолучитьОбласть("Заголовок");
            //ОбластьМакета.Параметры.НомерДоговора = НомерДоговора;
            ОбластьМакета.Параметры.ДатаДоговора  = ДатаДоговора;
            ТабличныйДокумент.Вывести(ОбластьМакета);
           
            ОбластьМакета = Макет.ПолучитьОбласть("ТекстШапки");
            ОбластьМакета.Параметры.Организация = ДанныеПечати.Организация.НаименованиеСокращенное;
            Если Исполнитель.Пустая() Тогда
                // Выводим сообщение об ошибке
                Сообщение = НСтр("ru = 'В документе не установлен Экспедитор. Для корректного формирования печатной формы необходимо заполнить данные.'");
                ОбщегоНазначенияКлиентСервер.СообщитьПользователю(Сообщение);
                ОбластьМакета.Параметры.ПредставительИсполнителя = "____________________________________________";
            Иначе
                ОбластьМакета.Параметры.ПредставительИсполнителя = Исполнитель.Наименование;
            КонецЕсли;
            Если Заказчик.Пустая() Тогда
                // Выводим сообщение об ошибке
                Сообщение = НСтр("ru = 'Для контрагента не задано Физическое лицо. Для корректного формирования печатной формы необходимо заполнить данные.'");
                ОбщегоНазначенияКлиентСервер.СообщитьПользователю(Сообщение);
                ОбластьМакета.Параметры.ПредставительЗаказчика = "______________________ ______________________________________";
            Иначе
                ОбластьМакета.Параметры.ПредставительЗаказчика = Заказчик.Наименование;
            КонецЕсли;
            //ОбластьМакета.Параметры.НомерДоверенности = ?(ЗначениеЗаполнено(ДанныеПечати.ДоверенностьНомер), ДанныеПечати.ДоверенностьНомер,"_________");
            //ОбластьМакета.Параметры.ДатаДоверенности  = ?(ЗначениеЗаполнено(ДанныеПечати.ДоверенностьДата), Формат(ДанныеПечати.ДоверенностьДата, "ДФ=""дд ММММ гггг """"года"""""""), "_____  ________________ 20___ г.");
            НомерДатаДоверенности = ПолучитьДанныеДоверенности(Исполнитель);
            Если НомерДатаДоверенности <> Неопределено Тогда
                ОбластьМакета.Параметры.ДанныеДоверенности = НомерДатаДоверенности;
            Иначе
                // Выводим сообщение об ошибке
                Сообщение = НСтр("ru = 'Для экспедитора не установлены сведения о доверенности. Для корректного формирования печатной формы необходимо заполнить данные.'");
                ОбщегоНазначенияКлиентСервер.СообщитьПользователю(Сообщение);
                ОбластьМакета.Параметры.ДанныеДоверенности = "№ ______ от __________________________";
            КонецЕсли;
            ТабличныйДокумент.Вывести(ОбластьМакета);
           
            ОбластьМакета = Макет.ПолучитьОбласть("ТекстШапкиДоп");
            //ОбластьМакета.Параметры.НомерДоговора = НомерДоговора;
            ОбластьМакета.Параметры.ДатаДоговора  = ДатаДоговора;
           
            //ОбластьМакета.Параметры.СуммаЧислом = ФормированиеПечатныхФорм.СуммаПлатежногоДокумента(ДанныеПечати.СуммаДокумента, ЛОЖЬ);
            //ОбластьМакета.Параметры.СуммаПрописью  = РаботаСКурсамиВалют.СформироватьСуммуПрописью(ДанныеПечати.СуммаДокумента, ДанныеПечати.Валюта);
            ОбластьМакета.Параметры.СуммаЧислом    = "_____________________________________________________________________________________";
            ОбластьМакета.Параметры.СуммаПрописью  = "_________________________________________________________________________________";
    
            ТабличныйДокумент.Вывести(ОбластьМакета);
           
            ОбластьМакета = Макет.ПолучитьОбласть("Подписи");
            ОбластьМакета.Параметры.ПредставительЗаказчика = ?(НЕ Заказчик.Пустая(),Заказчик.Наименование,"");
           
            ОбластьМакета.Параметры.ТелефонКлиента = ПолучитьКонтактнуюИнформацию(ДанныеПечати.Партнер, Справочники.ВидыКонтактнойИнформации.ТелефонПартнера, Перечисления.ТипыКонтактнойИнформации.Телефон);
            ОбластьМакета.Параметры.АдресКлиента    = ПолучитьКонтактнуюИнформацию(ДанныеПечати.Партнер, Справочники.ВидыКонтактнойИнформации.АдресПартнера, Перечисления.ТипыКонтактнойИнформации.Адрес);
    
            ТабличныйДокумент.Вывести(ОбластьМакета);
           
            УправлениеПечатью.ЗадатьОбластьПечатиДокумента(ТабличныйДокумент, НомерСтрокиНачало, ОбъектыПечати, ДанныеПечати.Ссылка);
           
        КонецЦикла;
       
        ТабличныйДокумент.АвтоМасштаб = Истина;
       
        Если ПривилегированныйРежим() Тогда
            УстановитьПривилегированныйРежим(Ложь);
        КонецЕсли;
       
        Возврат ТабличныйДокумент;
       
    КонецФункции // СформироватьПечатнуюФормуАкт()
    
    
    Функция ПолучитьКонтактнуюИнформацию(Заказчик, Вид, Тип)
       
        Запрос = Новый Запрос;
        Запрос.Текст =
         "ВЫБРАТЬ
         |    ПартнерыКонтактнаяИнформация.Ссылка КАК Парнер,
         |    ПартнерыКонтактнаяИнформация.Тип,
         |    ПартнерыКонтактнаяИнформация.Вид,
         |    ПартнерыКонтактнаяИнформация.Представление
         |ИЗ
         |    Справочник.Партнеры.КонтактнаяИнформация КАК ПартнерыКонтактнаяИнформация
         |ГДЕ
         |    ПартнерыКонтактнаяИнформация.Ссылка = &Ссылка
         |    И ПартнерыКонтактнаяИнформация.Тип = &Тип
         |    И ПартнерыКонтактнаяИнформация.Вид = &Вид" ;
        
         Запрос.Параметры.Вставить("Ссылка", Заказчик);
         Запрос.Параметры.Вставить("Тип", Тип);
         Запрос.Параметры.Вставить("Вид", Вид);
         РезультатЗапроса = Запрос.Выполнить();
         Выборка = РезультатЗапроса.Выбрать();
         Если Выборка.Следующий() Тогда
             Возврат Выборка.Представление;
         КонецЕсли;
       
    КонецФункции
    
    
      // Функция получения данных необходимых для печати
    //
    // Параметры:
    //         МассивОбъектов - Массив - Массив ссылок на документ Акт выполненных работ
    //
    // Возвращаемое значение:
    //         РезультатЗапроса
    //
    Функция ПолучитьДанныеДляПечати(МассивОбъектов)
       
        Запрос = Новый Запрос(
        "ВЫБРАТЬ
        |    РеализацияТоваровУслуг.Ссылка КАК Ссылка,
        |    РеализацияТоваровУслуг.Номер КАК Номер,
        |    РеализацияТоваровУслуг.Дата КАК Дата,
        |    РеализацияТоваровУслуг.Партнер КАК Партнер,
        |    РеализацияТоваровУслуг.Контрагент КАК Контрагент,
        |    РеализацияТоваровУслуг.Организация КАК Организация,
        |    РеализацияТоваровУслуг.Договор,
        |    РеализацияТоваровУслуг.Организация.Префикс КАК Префикс,
        |    РеализацияТоваровУслуг.Валюта КАК Валюта,
        |    РеализацияТоваровУслуг.ЦенаВключаетНДС КАК ЦенаВключаетНДС,
        |    ВЫБОР
        |        КОГДА РеализацияТоваровУслуг.НалогообложениеНДС = ЗНАЧЕНИЕ(Перечисление.ТипыНалогообложенияНДС.ПродажаНеОблагаетсяНДС)
        |                ИЛИ РеализацияТоваровУслуг.НалогообложениеНДС = ЗНАЧЕНИЕ(Перечисление.ТипыНалогообложенияНДС.ПродажаОблагаетсяЕНВД)
        |            ТОГДА ЛОЖЬ
        |        ИНАЧЕ ИСТИНА
        |    КОНЕЦ КАК УчитыватьНДС,
        |    РеализацияТоваровУслуг.БанковскийСчетОрганизации КАК СчетОрганизации,
        |    РеализацияТоваровУслуг.БанковскийСчетКонтрагента КАК СчетКонтрагента,
        |    ЕСТЬNULL(РегСведения.Значение, ЗНАЧЕНИЕ(Справочник.ФизическиеЛица.ПустаяСсылка)) КАК Экспедитор,
        |    РеализацияТоваровУслуг.ДоверенностьДата,
        |    РеализацияТоваровУслуг.ДоверенностьНомер,
        |    РеализацияТоваровУслуг.СуммаДокумента
        |ИЗ
        |    Документ.РеализацияТоваровУслуг КАК РеализацияТоваровУслуг
        |        ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ДополнительныеСведения КАК РегСведения
        |        ПО РеализацияТоваровУслуг.Ссылка = РегСведения.Объект
        |            И (РегСведения.Свойство = &СвойствоЭкспедитор)
        |ГДЕ
        |    РеализацияТоваровУслуг.Ссылка В(&МассивДокументов)
        |
        |УПОРЯДОЧИТЬ ПО
        |    Ссылка");
       
        Запрос.УстановитьПараметр("МассивДокументов", МассивОбъектов);
        Запрос.УстановитьПараметр("СвойствоЭкспедитор", Справочники.П_РеквизитыОбъектов.Экспедитор.Значение);
       
        Возврат Запрос.ВыполнитьПакет();
       
    КонецФункции // ПолучитьДанныеДляПечати()
    
    Функция ПолучитьДанныеПаспорта(ФизЛицо,ДатаРеализации)
        Запрос = Новый Запрос(
        "ВЫБРАТЬ
        |    ДокументыФизическихЛиц.Серия КАК ПаспортСерия,
        |    ДокументыФизическихЛиц.Номер КАК ПаспортНомер,
        |    ДокументыФизическихЛиц.ДатаВыдачи КАК ПаспортДатаВыдачи,
        |    ДокументыФизическихЛиц.КемВыдан КАК ПаспортВыдан
        |ИЗ
        |    РегистрСведений.ДокументыФизическихЛиц.СрезПоследних(,    //&Дата,
        |            ВидДокумента = ЗНАЧЕНИЕ(Справочник.ВидыДокументовФизическихЛиц.ПаспортРФ)
        |                И ФизЛицо = &ФизЛицо) КАК ДокументыФизическихЛиц");
       
        Запрос.УстановитьПараметр("ФизЛицо", ФизЛицо);
        //Запрос.УстановитьПараметр("Дата", ДатаРеализации);
    
        Выборка = Запрос.Выполнить().Выбрать();
        Если Выборка.Следующий() Тогда
            Возврат Новый Структура("ПаспортСерия, ПаспортНомер, ПаспортДатаВыдачи, ПаспортВыдан", Выборка.ПаспортСерия, Выборка.ПаспортНомер, Выборка.ПаспортДатаВыдачи, Выборка.ПаспортВыдан);
        КонецЕсли;
           
        Возврат Неопределено;
    КонецФункции // ПолучитьДанныеПаспорта()   
    
    Функция ПолучитьДанныеДоверенности(ФизЛицо)
        Запрос = Новый Запрос(
        "ВЫБРАТЬ
        |    ФизическиеЛица.Ссылка,
        |    ЕСТЬNULL(РегСведения.Значение, НЕОПРЕДЕЛЕНО) КАК ДанныеДоверенности
        |ИЗ
        |    Справочник.ФизическиеЛица КАК ФизическиеЛица
        |        ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ДополнительныеСведения КАК РегСведения
        |        ПО ФизическиеЛица.Ссылка = РегСведения.Объект
        |            И (РегСведения.Свойство = &СвойствоДатаНомерДовер)
        |ГДЕ
        |    ФизическиеЛица.Ссылка = &ФизЛицо");
       
        Запрос.УстановитьПараметр("ФизЛицо", ФизЛицо);
        Запрос.УстановитьПараметр("СвойствоДатаНомерДовер", Справочники.П_РеквизитыОбъектов.ДатаНомерДоверенностиФЛ.Значение);
    
        Выборка = Запрос.Выполнить().Выбрать();
        Если Выборка.Следующий() Тогда
            Возврат Выборка.ДанныеДоверенности;
        КонецЕсли;
           
        Возврат Неопределено;
    КонецФункции // ПолучитьДанныеДоверенности()   
    
    Всё структурировано и ясно.. делать по аналогии .. Что тут не понятно?

    Делать по аналогии и всё.
  5. AlenkaInt
    Offline

    AlenkaInt Опытный в 1С

    Регистрация:
    26 фев 2012
    Сообщения:
    1.008
    Симпатии:
    4
    Баллы:
    29
    Я не писала, что должны помогать и решать. Я писала о том, что это иногда выглядит как отписка. Человек спрашивает, а ему на все вопросы - иди читай, кури справку и прочее. Бывает у людей совсем начальный уровень. И читать ему пока рано. Все с чего то начинали. Кому то достаточно почитать, а у кого то другой склад ума, интеллектуальные возможности. Ему надо чтобы объяснили. И это не хуже и не лучше, просто все разные. Решать не надо, но если видно, что не помогает курить справку, может надо как то посерьезнее включиться? Или вообще не писать.
  6. TerANik
    Offline

    TerANik Профессионал в 1С

    Регистрация:
    19 ноя 2014
    Сообщения:
    997
    Симпатии:
    70
    Баллы:
    54
    Если у человека начальный уровень, то пускай сидит и создаёт справочники, а не внешние печатные формы.. это раз.
    Все начинали с малого это два
    Читать никогда и никому не рано это три
    Есть люди которые уже примелькались на форуме и видим как они растут это четыре..
    Всё объяснить ему тут никто не сможет.. хотя бы по факту того что мы не с баночкой пива сидим и форум тут читаем и отвечаем , а так же работаем это пять..
    Прежде чем всё же писать надо взять внешнюю печатную форму любую , а не говорить что не нашёл для РКО и посмотреть как она работает.

    Мы все тут не семь пядей во лбу и ждать что вам будут моментально отвечать и показывать не стоит, нам тоже надо со многими моментами разбираться. Мы тут общаемся, дискутируем, делимся опытом и наталкиваем друг друга на те или иные мысли, но не делаем друг за друга и хотим приобщить других к этому ибо когда человек не будет разбираться сам он никогда и не поймёт.

    P.S. Прошу принять мою критику не как злостный сарказм и оскорбление а как желание достучаться и получить понимание.
  7. nomad_irk
    Online

    nomad_irk Гуру в 1С

    Регистрация:
    20 окт 2008
    Сообщения:
    7.554
    Симпатии:
    716
    Баллы:
    204
    Если написанное в матчасти не понятно, то и ответ на форуме будет так же не понятен, что вы собственно и продемонстрировали в своей теме.
    Если вы ждете, что вам дадут готовое решение - ради бога, ждите дальше, ваш уровень мастерства от этого не повысится.

    Представьте себе, лично я начинал с того, что пошёл на курсы, это было в далеком 2008 году, когда ни методичек, ни удаленных курсов, ни вебинаров по 1С 8.х не было впринципе, а были только бумажные книги, которые стоили 5-ую часть моей ЗП, а интернет был по талонам и по-праздникам. Курсы, если что, стоили мне месячной ЗП, чуть больше даже.
    И да, лично мне приходилось каждый раз лазить в С-П и читать до полного понимания того, что и как нужно сделать, чтобы заработало.

    А сейчас чуть что - тема на форуме вида "ничего не понятно, но надо сделать ВПФ к завтра", а когда говоришь о том, что твой случай уже 100500 раз разобран и есть методичка именно по твоему случаю, начиается вой, что де плохие вы помощники.....
    Войте дальше, ищите готовых решений в другом месте, ждите от других участников форума.....
    Последнее редактирование: 18 сен 2015
  8. AlenkaInt
    Offline

    AlenkaInt Опытный в 1С

    Регистрация:
    26 фев 2012
    Сообщения:
    1.008
    Симпатии:
    4
    Баллы:
    29
    Это похоже на позицию многих бабушек. Которые не хотят сидеть с внуками, аргументируя тем, что "Мне никто не помогал, все сама и ты давай сама крутись". :)
    Да, я подумала над этим. И надеюсь что и люди, отвечающие на форуме, тоже подумают. Собственно для этого и писала.
    Всем спасибо, больше не буду засорять тему, просто накипело.
  9. nomad_irk
    Online

    nomad_irk Гуру в 1С

    Регистрация:
    20 окт 2008
    Сообщения:
    7.554
    Симпатии:
    716
    Баллы:
    204
    Еще раз: если вы не замечаете помощи, то проблема не в помогающих...
  10. shurikvz
    Online

    shurikvz Модераторы Команда форума Модератор

    Регистрация:
    1 окт 2009
    Сообщения:
    8.409
    Симпатии:
    316
    Баллы:
    104
    Так, я так понимаю желающие высказались и по теме больше ничего не будет?
    Эту тему прикрыл, во избежании дальнейшего "обмена мнениями", скатывающегося в какие-то обиды.
    Если у ТС есть желание дальше что-то спросить в этой теме (и по теме) - обратитесь ко мне (или к другому модератору) - эту тему откроем (опять таки, только не для срача).
    alexburn нравится это.
Статус темы:
Закрыта.

Поделиться этой страницей