Поле основание в Торг12

Тема в разделе "Общие вопросы по бухгалтерии", создана пользователем gor242, 24 дек 2012.

  1. Freeform
    Offline

    Freeform

    Регистрация:
    5 ноя 2013
    Сообщения:
    12
    Симпатии:
    0
    Баллы:
    1
    Alexburn, а что есть в Вашем коде "Ссылка"?
    Если я правильно понимаю на месте "Ссылки" должен быть объект в свойствах которого и хранятся необходимые значения?
  2. Freeform
    Offline

    Freeform

    Регистрация:
    5 ноя 2013
    Сообщения:
    12
    Симпатии:
    0
    Баллы:
    1
    Вот такой вот фрагмент кода:

    Код:
    Функция ПечатьТОРГ12(БезУслуг = Ложь)
    
    ЕдиницаИзмеренияВеса = Константы.ЕдиницаИзмеренияВеса.Получить();
    
    ДопКолонка = Константы.ДополнительнаяКолонкаПечатныхФормДокументов.Получить();
    Если ДопКолонка = Перечисления.ДополнительнаяКолонкаПечатныхФормДокументов.Артикул Тогда
    ТоварКод = "Артикул";
    Иначе
    ТоварКод = "Код";
    КонецЕсли;
    
    Запрос = Новый Запрос;
    Запрос.УстановитьПараметр("ДатаСреза",		  Дата);
    Запрос.УстановитьПараметр("СтруктурнаяЕдиница", Склад);
    Запрос.УстановитьПараметр("ТекущийДокумент",	ЭтотОбъект.Ссылка);
    Запрос.УстановитьПараметр("ПустойКонтрагент",   Справочники.Контрагенты.ПустаяСсылка());
    
    Запрос.Текст =
    "ВЫБРАТЬ
    | Номер,
    | Дата КАК ДатаДокумента,
    | Организация,
    | Организация КАК ЮрФизЛицо,
    | Организация КАК Поставщик,
    | Организация КАК Контрагент,
    | Организация КАК Руководители,
    | АдресДоставки КАК АдресДоставки,
    | ВЫБОР КОГДА Грузополучатель = &ПустойКонтрагент
    |	   ТОГДА Контрагент
    |	   ИНАЧЕ Грузополучатель КОНЕЦ КАК Грузополучатель,
    | ВЫБОР КОГДА Грузоотправитель = &ПустойКонтрагент
    |	   ТОГДА Организация
    |	   ИНАЧЕ Грузоотправитель КОНЕЦ КАК Грузоотправитель,
    | БанковскийСчетОрганизации КАК БанковскийСчет,
    | Контрагент КАК Покупатель,
    | Контрагент КАК Плательщик,
    | Сделка,
    | ДоговорКонтрагента.Представление  КАК Основание,
    | ДоговорКонтрагента.ВедениеВзаиморасчетов КАК ВедениеВзаиморасчетов,
    | ОтветственныеЛица.ФизическоеЛицо КАК ОтветственноеЛицо,
    | Подразделение,
    | ВалютаДокумента,
    | КурсВзаиморасчетов	  КАК Курс,
    | КратностьВзаиморасчетов КАК Кратность,
    | УчитыватьНДС,
    | СуммаВключаетНДС,
    | ОтпускРазрешил,
    | ОтпускПроизвел,
    | ДоверенностьНомер,
    | ДоверенностьДата,
    | ДоверенностьВыдана,
    | ДоверенностьЧерезКого
    |ИЗ
    | Документ.РеализацияТоваровУслуг КАК РеализацияТоваровУслуг
    |
    |ЛЕВОЕ СОЕДИНЕНИЕ
    | РегистрСведений.ОтветственныеЛица.СрезПоследних(&ДатаСреза, СтруктурнаяЕдиница = &СтруктурнаяЕдиница) КАК ОтветственныеЛица
    |ПО
    | ОтветственныеЛица.СтруктурнаяЕдиница = РеализацияТоваровУслуг.Склад
    |
    |ГДЕ
    | РеализацияТоваровУслуг.Ссылка = &ТекущийДокумент
    |";
    
    Шапка = Запрос.Выполнить().Выбрать();
    Шапка.Следующий();
    
    Как понять к какому объекту обращаться, в свойствах которого хранится ссылка на "Договор"?
  3. alexburn
    Offline

    alexburn Модераторы Команда форума Модератор

    Регистрация:
    5 янв 2009
    Сообщения:
    14.782
    Симпатии:
    509
    Баллы:
    204
    Если вы в модуле объекта - то ссылка - это ссылка на текущий(существующий) объект. Блин, может все-таки к спецам:), на работе просто у меня нет возможности подключить тимвьювер.
  4. alexburn
    Offline

    alexburn Модераторы Команда форума Модератор

    Регистрация:
    5 янв 2009
    Сообщения:
    14.782
    Симпатии:
    509
    Баллы:
    204
    Попробую на коленке:
    Код:
    ОбластьМакета.Параметры.Основание = Шапка.Основание;
    Вот тут у вас идет заполнение представления договора, в запросе вот видите код:
    Код:
    ДоговорКонтрагента.Представление  КАК Основание
    Вот в запрос вам нужно добавить что-то типа:
    Код:
    ДоговорКонтрагента.Номер КАК ДоговорНомер
    И тогда вы сможете использовать уже при выводе:

    Код:
    ОбластьМакета.Параметры.Основание = "Договор №: " + Шапка.ДоговорНомер;
    в Представлении уже стоит и договор, и номер, зачем вам такой изврат ?
  5. Freeform
    Offline

    Freeform

    Регистрация:
    5 ноя 2013
    Сообщения:
    12
    Симпатии:
    0
    Баллы:
    1
    Если я правильно рассуждаю, то
    в
    Код:
    Шапка.Сделка
    хранится ссылка на "Заказ покупателя",
    а в
    Код:
    Шапка.ДоговорКонтрагента
    собственно ссылка на "Договор контрагента".

    Правильно ли будет для получения значения договора контрагента обращаться к свойству
    Код:
    Шапка.ДоговорКонтрагента
    ?

    И почему имеет место быть следующая конструкция
    Код:
    ДоговорКонтрагента.Представление  КАК Основание
    , для чего необходимо "Представление"?
    Или правильно получать значение договора при помощи
    Код:
    Шапка.Основание
    ?
  6. Freeform
    Offline

    Freeform

    Регистрация:
    5 ноя 2013
    Сообщения:
    12
    Симпатии:
    0
    Баллы:
    1
    Вобщем то говорим об одном и том же.
    Т.е. правильно все таки обращаться к представлению
    Код:
    Шапка.Основание
    ?
  7. Freeform
    Offline

    Freeform

    Регистрация:
    5 ноя 2013
    Сообщения:
    12
    Симпатии:
    0
    Баллы:
    1
    Значит исходная конструкция примет вид:

    Вариант 1:
    Код:
    Иначе
    Если ЗначениеЗаполнено(Шапка.Сделка) Тогда
    ОбластьМакета.Параметры.Основание = ОбщегоНазначения.СформироватьЗаголовокДокумента(Шапка.Основание, Шапка.Сделка, Строка(Шапка.Сделка.Метаданные().Синоним));
    КонецЕсли;
    КонецЕсли;
    или

    Вариант 2:
    Код:
    Иначе
    Если ЗначениеЗаполнено(Шапка.Сделка) Тогда
    ОбластьМакета.Параметры.Основание = ОбщегоНазначения.СформироватьЗаголовокДокумента(Шапка.Основание,  Строка(Шапка.Основание.Метаданные().Синоним), Шапка.Сделка, Строка(Шапка.Сделка.Метаданные().Синоним));
    КонецЕсли;
    КонецЕсли;
    Какой из вариантов правильный?
    И для чего необходима конструкция
    Код:
    Строка(Шапка.Сделка.Метаданные().Синоним)
    ?
  8. alexburn
    Offline

    alexburn Модераторы Команда форума Модератор

    Регистрация:
    5 янв 2009
    Сообщения:
    14.782
    Симпатии:
    509
    Баллы:
    204
    Вы откуда этот кусок кода взяли?
    Если использовать отладчик, вы поймете откуда ноги растут.
  9. Freeform
    Offline

    Freeform

    Регистрация:
    5 ноя 2013
    Сообщения:
    12
    Симпатии:
    0
    Баллы:
    1
    Код все из того же модуля документа "РеализацияТоваровУслуг" (см. выше), собственно с этого и началась наша беседа
  10. Freeform
    Offline

    Freeform

    Регистрация:
    5 ноя 2013
    Сообщения:
    12
    Симпатии:
    0
    Баллы:
    1
    Варианты 1 и 2 предложенные мною оказались неверными, т.к. в функцию "СформироватьЗаголовокДокумента" модуля "Общего назначения"
    можно передать толька 2 параметра.

    Задача разрешилась путем создания внешней печатной формы.
    Модуль следующего содержания:

    Код:
    Функция Печать() ЭКСПОРТ
    
    БезУслуг = Ложь;
    Ссылка = СсылкаНаОбъект;
    Дата = СсылкаНаОбъект.Дата;
    Склад = СсылкаНаОбъект.Склад;
    ВалютаДокумента = СсылкаНаОбъект.ВалютаДокумента;
    ДоговорКонтрагента = СсылкаНаОбъект.ДоговорКонтрагента;
    мВалютаРегламентированногоУчета = СсылкаНаОбъект.ВалютаДокумента;
    КурсВзаиморасчетов = СсылкаНаОбъект.КурсВзаиморасчетов;
    КратностьВзаиморасчетов = СсылкаНаОбъект.КратностьВзаиморасчетов;
    Организация = СсылкаНаОбъект.Организация;
    
    ЕдиницаИзмеренияВеса = Константы.ЕдиницаИзмеренияВеса.Получить();
    
    ДопКолонка = Константы.ДополнительнаяКолонкаПечатныхФормДокументов.Получить();
    Если ДопКолонка = Перечисления.ДополнительнаяКолонкаПечатныхФормДокументов.Артикул Тогда
    ТоварКод = "Артикул";
    Иначе
    ТоварКод = "Код";
    КонецЕсли;
    
    Запрос = Новый Запрос;
    Запрос.УстановитьПараметр("ДатаСреза",		  Дата);
    Запрос.УстановитьПараметр("СтруктурнаяЕдиница", Склад);
    Запрос.УстановитьПараметр("ТекущийДокумент",    СсылкаНаОбъект.Ссылка);
    Запрос.УстановитьПараметр("ПустойКонтрагент",   Справочники.Контрагенты.ПустаяСсылка());
    
    Запрос.Текст =
    "ВЫБРАТЬ
    | Номер,
    | Дата КАК ДатаДокумента,
    | Организация,
    | Организация КАК ЮрФизЛицо,
    | Организация КАК Поставщик,
    | Организация КАК Контрагент,
    | Организация КАК Руководители,
    | АдресДоставки КАК АдресДоставки,
    | ВЫБОР КОГДА Грузополучатель = &ПустойКонтрагент
    |	   ТОГДА Контрагент
    |	   ИНАЧЕ Грузополучатель КОНЕЦ КАК Грузополучатель,
    | ВЫБОР КОГДА Грузоотправитель = &ПустойКонтрагент
    |	   ТОГДА Организация
    |	   ИНАЧЕ Грузоотправитель КОНЕЦ КАК Грузоотправитель,
    | БанковскийСчетОрганизации КАК БанковскийСчет,
    | Контрагент КАК Покупатель,
    | Контрагент КАК Плательщик,
    | Сделка,
    | ДоговорКонтрагента.Представление  КАК Основание,
    | ДоговорКонтрагента.ВедениеВзаиморасчетов КАК ВедениеВзаиморасчетов,
    | ОтветственныеЛица.ФизическоеЛицо КАК ОтветственноеЛицо,
    | Подразделение,
    | ВалютаДокумента,
    | КурсВзаиморасчетов	  КАК Курс,
    | КратностьВзаиморасчетов КАК Кратность,
    | УчитыватьНДС,
    | СуммаВключаетНДС,
    | ОтпускРазрешил,
    | ОтпускПроизвел,
    | ДоверенностьНомер,
    | ДоверенностьДата,
    | ДоверенностьВыдана,
    | ДоверенностьЧерезКого
    |ИЗ
    | Документ.РеализацияТоваровУслуг КАК РеализацияТоваровУслуг
    |
    |ЛЕВОЕ СОЕДИНЕНИЕ
    | РегистрСведений.ОтветственныеЛица.СрезПоследних(&ДатаСреза, СтруктурнаяЕдиница = &СтруктурнаяЕдиница) КАК ОтветственныеЛица
    |ПО
    | ОтветственныеЛица.СтруктурнаяЕдиница = РеализацияТоваровУслуг.Склад
    |
    |ГДЕ
    | РеализацияТоваровУслуг.Ссылка = &ТекущийДокумент
    |";
    
    Шапка = Запрос.Выполнить().Выбрать();
    Шапка.Следующий();
    
    Запрос = Новый Запрос;
    Запрос.УстановитьПараметр("ТекущийДокумент", СсылкаНаОбъект.Ссылка);
    
    // Вычислим курс документа для печати
    Если ВалютаДокумента <> мВалютаРегламентированногоУчета
    И ДоговорКонтрагента.РасчетыВУсловныхЕдиницах
    И ДоговорКонтрагента.ВестиПоДокументамРасчетовСКонтрагентом Тогда
    
    ЗапросКурсАванса = Новый Запрос;
    ЗапросКурсАванса.УстановитьПараметр("ДокументСсылка", Ссылка);
    ЗапросКурсАванса.Текст =
    "ВЫБРАТЬ
    | Док.СуммаВзаиморасчетов,
    | Док.СуммаРегл
    |ИЗ
    | Документ.РеализацияТоваровУслуг.ДокументыРасчетовСКонтрагентом КАК Док
    |ГДЕ Док.Ссылка = &ДокументСсылка
    |ИТОГИ СУММА(СуммаВзаиморасчетов), СУММА(СуммаРегл) ПО ОБЩИЕ";
    
    Выборка = ЗапросКурсАванса.Выполнить().Выбрать(ОбходРезультатаЗапроса.ПоГруппировкам);
    Если Выборка.Следующий() Тогда
    КурсОплаты				 = ?(Выборка.СуммаВзаиморасчетов = 0, 0, Выборка.СуммаРегл/Выборка.СуммаВзаиморасчетов);
    ВыборкаСуммаВзаиморасчетов = Выборка.СуммаВзаиморасчетов;
    ВыборкаСуммаРегл		   = Выборка.СуммаРегл;
    Иначе
    КурсОплаты				 = 0;
    ВыборкаСуммаВзаиморасчетов = 0;
    ВыборкаСуммаРегл		   = 0;
    КонецЕсли;
    
    СуммаВзаиморасчетов = МодульВалютногоУчета.ПересчитатьИзВалютыВВалюту(УчетНДС.ПолучитьСуммуДокументаСНДС(СсылкаНаОбъект),
    ВалютаДокумента, ДоговорКонтрагента.ВалютаВзаиморасчетов,
    ЗаполнениеДокументов.КурсДокумента(СсылкаНаОбъект, мВалютаРегламентированногоУчета), КурсВзаиморасчетов,
    ЗаполнениеДокументов.КратностьДокумента(СсылкаНаОбъект, мВалютаРегламентированногоУчета), КратностьВзаиморасчетов);
    НеоплаченнаяСумма = СуммаВзаиморасчетов - ВыборкаСуммаВзаиморасчетов;
    Если НеоплаченнаяСумма > 0 Тогда
    КурсДляПечати = (НеоплаченнаяСумма * КурсВзаиморасчетов + ВыборкаСуммаРегл)/(НеоплаченнаяСумма + ВыборкаСуммаВзаиморасчетов);
    Иначе
    КурсДляПечати = КурсОплаты;
    КонецЕсли;
    
    Если КурсДляПечати = 0 Тогда
    Запрос.УстановитьПараметр("Курс",	  СсылкаНаОбъект.КурсВзаиморасчетов);
    Запрос.УстановитьПараметр("Кратность", СсылкаНаОбъект.КратностьВзаиморасчетов);
    Иначе
    Запрос.УстановитьПараметр("Курс",	  КурсДляПечати);
    Запрос.УстановитьПараметр("Кратность", 1);
    КонецЕсли;
    
    ИначеЕсли ВалютаДокумента = ДоговорКонтрагента.ВалютаВзаиморасчетов Тогда
    
    // Документ оформлен в валюте взаиморасчетов
    Запрос.УстановитьПараметр("Курс", СсылкаНаОбъект.КурсВзаиморасчетов);
    Запрос.УстановитьПараметр("Кратность", СсылкаНаОбъект.КратностьВзаиморасчетов);
    
    Иначе
    
    // Документ оформлен в валюте регламентированного учета
    Запрос.УстановитьПараметр("Курс",	  1);
    Запрос.УстановитьПараметр("Кратность", 1);
    
    КонецЕсли;
    
    Запрос.Текст =
    "ВЫБРАТЬ
    | ВложенныйЗапрос.Номенклатура								  КАК Номенклатура,
    | ВЫРАЗИТЬ(ВложенныйЗапрос.Номенклатура.НаименованиеПолное КАК Строка(1000)) КАК ТоварНаименование,
    | ВложенныйЗапрос.Номенклатура." + ТоварКод + "				 КАК ТоварКод,
    | ВложенныйЗапрос.ЕдиницаИзмерения.Представление			    КАК БазоваяЕдиницаНаименование,
    | ВложенныйЗапрос.ЕдиницаИзмерения.ЕдиницаПоКлассификатору.Код  КАК БазоваяЕдиницаКодПоОКЕИ,
    | ВложенныйЗапрос.ЕдиницаИзмерения	 КАК ЕдиницаИзмерения,
    | ВложенныйЗапрос.ЕдиницаИзмеренияМест.Представление		    КАК ВидУпаковки,
    | ВложенныйЗапрос.КоэффициентМест / ВложенныйЗапрос.Коэффициент КАК КоличествоВОдномМесте,
    | ВЫБОР
    |  КОГДА ВложенныйЗапрос.КоличествоМест > 0 ТОГДА ВложенныйЗапрос.КоличествоМест * ВложенныйЗапрос.ЕдиницаИзмеренияМест.Вес
    |  ИНАЧЕ ВложенныйЗапрос.Количество * ВложенныйЗапрос.ЕдиницаИзмерения.Вес
    | КОНЕЦ КАК МассаБрутто,
    | ВложенныйЗапрос.Характеристика	   КАК Характеристика,
    | ВложенныйЗапрос.Серия			    КАК Серия,
    | ВложенныйЗапрос.СтавкаНДС		    КАК СтавкаНДС,
    | ВложенныйЗапрос.Цена				 КАК Цена,
    | ВЫБОР
    |  КОГДА((ВложенныйЗапрос.ПроцентСкидкиНаценки = 0) И
    |	    (ВложенныйЗапрос.ПроцентАвтоматическихСкидок = 0))
    | ТОГДА ЛОЖЬ
    | ИНАЧЕ Истина
    | КОНЕЦ							    КАК ЕстьСкидкиПоСтроке,
    | ВложенныйЗапрос.Количество		   КАК Количество,
    | ВложенныйЗапрос.КоличествоМест	   КАК КоличествоМест,
    | ВложенныйЗапрос.Сумма			    КАК Сумма,
    | ВложенныйЗапрос.СуммаНДС			 КАК СуммаНДС,
    | ВложенныйЗапрос.НомерСтроки		  КАК НомерСтроки,
    | ВложенныйЗапрос.Метка			    КАК Метка
    |ИЗ
    |
    | (
    | ВЫБРАТЬ
    |  РеализацияТоваровУслуг.Номенклатура,
    |  РеализацияТоваровУслуг.Коэффициент,
    |  РеализацияТоваровУслуг.ЕдиницаИзмерения,
    |  РеализацияТоваровУслуг.ЕдиницаИзмеренияМест,
    |  РеализацияТоваровУслуг.ЕдиницаИзмеренияМест.Коэффициент	 КАК КоэффициентМест,
    |  РеализацияТоваровУслуг.ХарактеристикаНоменклатуры		   КАК Характеристика,
    |  РеализацияТоваровУслуг.СерияНоменклатуры				    КАК Серия,
    |  РеализацияТоваровУслуг.СтавкаНДС,
    |  РеализацияТоваровУслуг.Цена * &Курс / &Кратность		    КАК Цена,
    |  РеализацияТоваровУслуг.ПроцентСкидкиНаценки,
    |  РеализацияТоваровУслуг.ПроцентАвтоматическихСкидок,
    |  СУММА(РеализацияТоваровУслуг.Количество)				    КАК Количество,
    |  СУММА(РеализацияТоваровУслуг.КоличествоМест)			    КАК КоличествоМест,
    |  СУММА(РеализацияТоваровУслуг.Сумма    * &Курс / &Кратность) КАК Сумма,
    |  СУММА(РеализацияТоваровУслуг.СуммаНДС * &Курс / &Кратность) КАК СуммаНДС,
    |  МИНИМУМ(РеализацияТоваровУслуг.НомерСтроки)				 КАК НомерСтроки,
    |  0														   КАК Метка
    | ИЗ
    |  Документ.РеализацияТоваровУслуг.Товары КАК РеализацияТоваровУслуг
    | ГДЕ
    |  РеализацияТоваровУслуг.Ссылка = &ТекущийДокумент
    |
    |СГРУППИРОВАТЬ ПО
    |  РеализацияТоваровУслуг.Номенклатура,
    |  РеализацияТоваровУслуг.Коэффициент,
    |  РеализацияТоваровУслуг.ЕдиницаИзмерения,
    |  РеализацияТоваровУслуг.ЕдиницаИзмеренияМест,
    |  РеализацияТоваровУслуг.ХарактеристикаНоменклатуры,
    |  РеализацияТоваровУслуг.СерияНоменклатуры,
    |  РеализацияТоваровУслуг.СтавкаНДС,
    |  РеализацияТоваровУслуг.Цена,
    |  РеализацияТоваровУслуг.ПроцентСкидкиНаценки,
    |  РеализацияТоваровУслуг.ПроцентАвтоматическихСкидок
    | ) КАК ВложенныйЗапрос
    |";
    
    Если НЕ БезУслуг Тогда
    
    СтрокаВыборкиПоляСодержания = ОбработкаТабличныхЧастей.ПолучитьЧастьЗапросаДляВыбораСодержания("РеализацияТоваровУслуг");
    
    Запрос.Текст = Запрос.Текст + "
    |
    |ОБЪЕДИНИТЬ ВСЕ
    |
    |ВЫБРАТЬ
    | РеализацияТоваровУслуг.Номенклатура				  КАК Номенклатура,
    | " + СтрокаВыборкиПоляСодержания + "				  КАК ТоварНаименование,
    | РеализацияТоваровУслуг.Номенклатура." + ТоварКод + " КАК ТоварКод,
    | РеализацияТоваровУслуг.Номенклатура.ЕдиницаХраненияОстатков.Представление КАК БазоваяЕдиницаНаименование,
    | РеализацияТоваровУслуг.Номенклатура.ЕдиницаХраненияОстатков.ЕдиницаПоКлассификатору.Код КАК БазоваяЕдиницаКодПоОКЕИ,
    | РеализацияТоваровУслуг.Номенклатура.ЕдиницаХраненияОстатков КАК ЕдиницаИзмерения,
    | NULL												 КАК ВидУпаковки,
    | NULL												 КАК КоличествоВОдномМесте,
    | 0												    КАК МассаБрутто,
    | NULL												 КАК Характеристика,
    | NULL												 КАК Серия,
    | РеализацияТоваровУслуг.СтавкаНДС					 КАК СтавкаНДС,
    | РеализацияТоваровУслуг.Цена * &Курс / &Кратность	 КАК Цена,
    | ВЫБОР
    |  КОГДА(РеализацияТоваровУслуг.ПроцентСкидкиНаценки = 0)
    | ТОГДА ЛОЖЬ
    | ИНАЧЕ Истина
    | КОНЕЦ											    КАК ЕстьСкидкиПоСтроке,
    | РеализацияТоваровУслуг.Количество				    КАК Количество,
    | NULL												 КАК КоличествоМест,
    | РеализацияТоваровУслуг.Сумма    * &Курс / &Кратность КАК Сумма,
    | РеализацияТоваровУслуг.СуммаНДС * &Курс / &Кратность КАК СуммаНДС,
    | РеализацияТоваровУслуг.НомерСтроки				   КАК НомерСтроки,
    | 1												    КАК Метка
    |ИЗ
    | Документ.РеализацияТоваровУслуг.Услуги КАК РеализацияТоваровУслуг
    |
    |ГДЕ
    | РеализацияТоваровУслуг.Ссылка = &ТекущийДокумент
    |";
    КонецЕсли;
    
    Запрос.Текст = Запрос.Текст + "
    |
    |ОБЪЕДИНИТЬ ВСЕ
    |
    |ВЫБРАТЬ
    | РеализацияТоваровУслуг.Номенклатура				    КАК Номенклатура,
    | ВЫРАЗИТЬ(РеализацияТоваровУслуг.Номенклатура.НаименованиеПолное КАК Строка(1000)) КАК ТоварНаименование,
    | РеализацияТоваровУслуг.Номенклатура." + ТоварКод + "   КАК ТоварКод,
    | РеализацияТоваровУслуг.Номенклатура.ЕдиницаХраненияОстатков.Представление			   КАК БазоваяЕдиницаНаименование,
    | РеализацияТоваровУслуг.Номенклатура.ЕдиницаХраненияОстатков.ЕдиницаПоКлассификатору.Код КАК БазоваяЕдиницаКодПоОКЕИ,
    | РеализацияТоваровУслуг.Номенклатура.ЕдиницаХраненияОстатков							 КАК ЕдиницаИзмерения,
    | NULL												  КАК ВидУпаковки,
    | NULL												  КАК КоличествоВОдномМесте,
    | РеализацияТоваровУслуг.Количество * РеализацияТоваровУслуг.Номенклатура.ЕдиницаХраненияОстатков.Вес КАК МассаБрутто,
    | NULL												  КАК Характеристика,
    | NULL												  КАК Серия,
    | ""Без НДС""										   КАК СтавкаНДС,
    | РеализацияТоваровУслуг.Цена						   КАК Цена,
    | Ложь												  КАК ЕстьСкидкиПоСтроке,
    | РеализацияТоваровУслуг.Количество					 КАК Количество,
    | NULL												  КАК КоличествоМест,
    | РеализацияТоваровУслуг.Сумма						  КАК Сумма,
    | 0													 КАК СуммаНДС,
    | РеализацияТоваровУслуг.НомерСтроки				    КАК НомерСтроки,
    | 2													 КАК Метка
    |ИЗ
    |(
    | ВЫБРАТЬ
    |  РеализацияТоваровУслуг.Номенклатура					  КАК Номенклатура,
    |  РеализацияТоваровУслуг.Цена * &Курс / &Кратность		 КАК Цена,
    |  СУММА(РеализацияТоваровУслуг.Количество)				 КАК Количество,
    |  СУММА(РеализацияТоваровУслуг.Сумма * &Курс / &Кратность) КАК Сумма,
    |  МИНИМУМ(РеализацияТоваровУслуг.НомерСтроки)			  КАК НомерСтроки
    | ИЗ
    |  Документ.РеализацияТоваровУслуг.ВозвратнаяТара КАК РеализацияТоваровУслуг
    |
    | ГДЕ
    |  РеализацияТоваровУслуг.Ссылка = &ТекущийДокумент
    | СГРУППИРОВАТЬ ПО
    |  РеализацияТоваровУслуг.Номенклатура,
    |  РеализацияТоваровУслуг.Цена
    |) КАК РеализацияТоваровУслуг
    |УПОРЯДОЧИТЬ ПО Метка ВОЗР, НомерСтроки ВОЗР
    |
    |";
    
    ЗапросТовары = Запрос.Выполнить().Выгрузить();
    ТабДокумент  = Новый ТабличныйДокумент;
    
    // Зададим параметры макета
    ТабДокумент.ПолеСверху			  = 0;
    ТабДокумент.ПолеСлева			   = 5;
    ТабДокумент.ПолеСнизу			   = 0;
    ТабДокумент.ПолеСправа			  = 5;
    ТабДокумент.РазмерКолонтитулаСверху = 0;
    ТабДокумент.РазмерКолонтитулаСнизу  = 0;
    ТабДокумент.АвтоМасштаб			 = Истина;
    ТабДокумент.ОриентацияСтраницы	  = ОриентацияСтраницы.Ландшафт;
    
    ТабДокумент.ИмяПараметровПечати = "ПАРАМЕТРЫ_ПЕЧАТИ_РеализацияТоваровУслуг_ТОРГ12";
    
    Макет = ПолучитьОбщийМакет("ТОРГ12");
    
    // Выводим общие реквизиты шапки
    СведенияОПоставщике	   = УправлениеКонтактнойИнформацией.СведенияОЮрФизЛице(Шапка.ЮрФизЛицо,	    Шапка.ДатаДокумента,, Шапка.БанковскийСчет);
    СведенияОПокупателе	   = УправлениеКонтактнойИнформацией.СведенияОЮрФизЛице(Шапка.Покупатель,	   Шапка.ДатаДокумента);
    СведенияОГрузополучателе  = УправлениеКонтактнойИнформацией.СведенияОЮрФизЛице(Шапка.Грузополучатель,  Шапка.ДатаДокумента);
    СведенияОГрузоотправитель = УправлениеКонтактнойИнформацией.СведенияОЮрФизЛице(Шапка.Грузоотправитель, Шапка.ДатаДокумента);
    
    ОбластьМакета = Макет.ПолучитьОбласть("Шапка");
    ОбластьМакета.Параметры.Заполнить(Шапка);
    ОбластьМакета.Параметры.НомерДокумента = ОбщегоНазначения.ПолучитьНомерНаПечать(Шапка);
    ОбластьМакета.Параметры.ДатаДокумента  = Шапка.ДатаДокумента;
    
    Если Шапка.ЮрФизЛицо = Шапка.Грузоотправитель Тогда
    ОбластьМакета.Параметры.ПредставлениеОрганизации = ФормированиеПечатныхФорм.ОписаниеОрганизации(СведенияОПоставщике);
    Иначе
    ОбластьМакета.Параметры.ПредставлениеОрганизации = ФормированиеПечатныхФорм.ОписаниеОрганизации(СведенияОГрузоотправитель, "ПолноеНаименование,ИНН,ФактическийАдрес,Телефоны,НомерСчета,Банк,БИК,КоррСчет");
    КонецЕсли;
    
    ОбластьМакета.Параметры.ПредставлениеПодразделения = Шапка.Подразделение;
    ОбластьМакета.Параметры.ПредставлениеГрузополучателя = ФормированиеПечатныхФорм.ОписаниеОрганизации(СведенияОГрузополучателе, "ПолноеНаименование,ИНН,ФактическийАдрес,Телефоны,НомерСчета,Банк,БИК,КоррСчет");
    
    Если СокрЛП(Шапка.АдресДоставки) <> "" Тогда
    ОбластьМакета.Параметры.АдресДоставки = СокрЛП(Шапка.АдресДоставки);
    Иначе
    ОбластьМакета.Параметры.АдресДоставки = ФормированиеПечатныхФорм.ОписаниеОрганизации(СведенияОГрузополучателе, "ФактическийАдрес");
    КонецЕсли;
    
    ОбластьМакета.Параметры.ПредставлениеПоставщика  = ФормированиеПечатныхФорм.ОписаниеОрганизации(СведенияОПоставщике);
    ОбластьМакета.Параметры.ПредставлениеПлательщика = ФормированиеПечатныхФорм.ОписаниеОрганизации(СведенияОПокупателе);
    
    Если Шапка.ВедениеВзаиморасчетов <> Перечисления.ВедениеВзаиморасчетовПоДоговорам.ПоЗаказам
    И Шапка.ВедениеВзаиморасчетов <> Перечисления.ВедениеВзаиморасчетовПоДоговорам.ПоСчетам Тогда
    ОбластьМакета.Параметры.Основание = Шапка.Основание;
    Иначе
    Если ЗначениеЗаполнено(Шапка.Сделка) Тогда
    ОбластьМакета.Параметры.Основание = Шапка.Основание + ", " + ОбщегоНазначения.СформироватьЗаголовокДокумента(Шапка.Сделка, Строка(Шапка.Сделка.Метаданные().Синоним));
    КонецЕсли;
    КонецЕсли;
    
    // Выводим всевозможные коды
    ОбластьМакета.Параметры.ОрганизацияПоОКПО	 = СведенияОГрузоотправитель.КодПоОКПО;
    ОбластьМакета.Параметры.ВидДеятельностиПоОКДП = "";
    ОбластьМакета.Параметры.ГрузополучательПоОКПО = СведенияОГрузополучателе.КодПоОКПО;
    ОбластьМакета.Параметры.ПоставщикПоОКПО	   = СведенияОПоставщике.КодПоОКПО;
    ОбластьМакета.Параметры.ПлательщикПоОКПО	  = СведенияОПокупателе.КодПоОКПО;
    ОбластьМакета.Параметры.ОснованиеНомер	    = "";
    ОбластьМакета.Параметры.ОснованиеДата		 = "";
    ОбластьМакета.Параметры.ТранспортнаяНакладнаяНомер = "";
    ОбластьМакета.Параметры.ТранспортнаяНакладнаяДата  = "";
    
    ТабДокумент.Вывести(ОбластьМакета);
    
    НомерСтраницы   = 1;
    
    КоличествоСтрок = ЗапросТовары.Количество();
    
    // инициализация итогов по странице
    ИтогоМассаБруттоНаСтранице = 0;
    ИтогоМестНаСтранице	    = 0;
    ИтогоКоличествоНаСтранице  = 0;
    ИтогоСуммаНаСтранице	   = 0;
    ИтогоНДСНаСтранице		 = 0;
    ИтогоСуммаСНДСНаСтранице   = 0;
    
    // инициализация итогов по документу
    ИтогоМассаБрутто = 0;
    ИтогоМест	    = 0;
    ИтогоКоличество  = 0;
    ИтогоСуммаСНДС   = 0;
    ИтогоСумма	   = 0;
    ИтогоНДС		 = 0;
    Ном			  = 0;
    
    // Создаем массив для проверки вывода
    МассивВыводимыхОбластей = Новый Массив;
    
    // Выводим многострочную часть докмента
    ОбластьЗаголовокТаблицы = Макет.ПолучитьОбласть("ЗаголовокТаб");
    ОбластьМакета		   = Макет.ПолучитьОбласть("Строка");
    ОбластьИтоговПоСтранице = Макет.ПолучитьОбласть("ИтогоПоСтранице");
    ОбластьВсего		    = Макет.ПолучитьОбласть("Всего");
    ОбластьПодвала		  = Макет.ПолучитьОбласть("Подвал");
    Для Каждого ВыборкаСтрок Из ЗапросТовары Цикл
    
    Если НЕ ЗначениеЗаполнено(ВыборкаСтрок.Номенклатура) Тогда
    Сообщить("В одной из строк не заполнено значение номенклатуры - строка при печати пропущена.", СтатусСообщения.Важное);
    Продолжить;
    КонецЕсли;
    
    Ном		   = Ном + 1;
    
    ОбластьМакета.Параметры.Заполнить(ВыборкаСтрок);
    ОбластьМакета.Параметры.Номер			 = ЗапросТовары.Индекс(ВыборкаСтрок) + 1;
    ОбластьМакета.Параметры.ТоварНаименование = СокрЛП(ВыборкаСтрок.ТоварНаименование)
    + ФормированиеПечатныхФорм.ПредставлениеСерий(ВыборкаСтрок)
    + ?(ВыборкаСтрок.Метка = 2, " (возвратная тара)", "");
    
    Если НЕ ЗначениеЗаполнено(ЕдиницаИзмеренияВеса) Тогда
    МассаБрутто = 0;
    Иначе
    МассаБрутто = ВыборкаСтрок.МассаБрутто;
    МассаБрутто = ?(МассаБрутто <> Неопределено И МассаБрутто <> NULL, МассаБрутто, 0);
    КонецЕсли;
    
    Мест	    = ВыборкаСтрок.КоличествоМест;
    Мест	    = ?(Мест <> Неопределено И Мест <> NULL, Мест, 0);
    
    Количество  = ВыборкаСтрок.Количество;
    СуммаСНДС   = Окр((ВыборкаСтрок.Сумма + ?(Шапка.СуммаВключаетНДС, 0, ВыборкаСтрок.СуммаНДС)), 2);
    СуммаНДС    = Окр(ВыборкаСтрок.СуммаНДС, 2);
    СуммаБезНДС = СуммаСНДС  - СуммаНДС;
    
    ОбластьМакета.Параметры.МассаБрутто = МассаБрутто;
    ОбластьМакета.Параметры.СуммаСНДС   = СуммаСНДС;
    ОбластьМакета.Параметры.СуммаНДС    = СуммаНДС;
    ОбластьМакета.Параметры.СтавкаНДС   = ВыборкаСтрок.СтавкаНДС;
    ОбластьМакета.Параметры.СуммаБезНДС = СуммаБезНДС;
    
    Если Шапка.СуммаВключаетНДС
    Или ВыборкаСтрок.ЕстьСкидкиПоСтроке Тогда
    ОбластьМакета.Параметры.Цена = ?(Количество = 0, 0, СуммаБезНДС / Количество);
    Иначе
    ОбластьМакета.Параметры.Цена = ВыборкаСтрок.Цена;
    КонецЕсли;
    
    Если Ном = 1 Тогда // первая срока
    
    ОбластьЗаголовокТаблицы.Параметры.НомерСтраницы = "Страница " + НомерСтраницы;
    ТабДокумент.Вывести(ОбластьЗаголовокТаблицы);
    
    Иначе
    
    МассивВыводимыхОбластей.Очистить();
    МассивВыводимыхОбластей.Добавить(ОбластьМакета);
    МассивВыводимыхОбластей.Добавить(ОбластьИтоговПоСтранице);
    Если Ном = КоличествоСтрок Тогда
    МассивВыводимыхОбластей.Добавить(ОбластьВсего);
    МассивВыводимыхОбластей.Добавить(ОбластьПодвала);
    КонецЕсли; 
    
    Если Ном <> 1 И НЕ ТабДокумент.ПроверитьВывод(МассивВыводимыхОбластей) Тогда
    
    ОбластьИтоговПоСтранице.Параметры.ИтогМассаБруттоПоСтранице = ИтогоМассаБруттоНаСтранице;
    ОбластьИтоговПоСтранице.Параметры.ИтогМестПоСтранице	    = ИтогоМестНаСтранице;
    ОбластьИтоговПоСтранице.Параметры.ИтогКоличествоПоСтранице  = ИтогоКоличествоНаСтранице;
    ОбластьИтоговПоСтранице.Параметры.ИтогСуммыПоСтранице	   = ИтогоСуммаНаСтранице;
    ОбластьИтоговПоСтранице.Параметры.ИтогНДСПоСтранице		 = ИтогоНДСНаСтранице;
    ОбластьИтоговПоСтранице.Параметры.ИтогСуммыСНДСПоСтранице   = ИтогоСуммаСНДСНаСтранице;
    
    ТабДокумент.Вывести(ОбластьИтоговПоСтранице);
    
    // очистим итоги по странице
    ИтогоМассаБруттоНаСтранице = 0;
    ИтогоМестНаСтранице	    = 0;
    ИтогоКоличествоНаСтранице  = 0;
    ИтогоСуммаНаСтранице	   = 0;
    ИтогоНДСНаСтранице		 = 0;
    ИтогоСуммаСНДСНаСтранице   = 0;
    
    НомерСтраницы = НомерСтраницы + 1;
    ТабДокумент.ВывестиГоризонтальныйРазделительСтраниц();
    ОбластьЗаголовокТаблицы.Параметры.НомерСтраницы = "Страница " + НомерСтраницы;
    ТабДокумент.Вывести(ОбластьЗаголовокТаблицы);
    
    КонецЕсли;
    
    КонецЕсли; 
    
    ТабДокумент.Вывести(ОбластьМакета);
    
    // увеличим итоги по странице
    ИтогоМассаБруттоНаСтранице = ИтогоМассаБруттоНаСтранице + МассаБрутто;
    ИтогоМестНаСтранице	    = ИтогоМестНаСтранице	    + Мест;
    ИтогоКоличествоНаСтранице  = ИтогоКоличествоНаСтранице  + Количество;
    ИтогоСуммаНаСтранице	   = ИтогоСуммаНаСтранице	   + СуммаБезНДС;
    ИтогоНДСНаСтранице		 = ИтогоНДСНаСтранице		 + СуммаНДС;
    ИтогоСуммаСНДСНаСтранице   = ИтогоСуммаСНДСНаСтранице   + СуммаСНДС;
    
    // увеличим итоги по дукументу
    ИтогоМассаБрутто = ИтогоМассаБрутто + МассаБрутто;
    ИтогоМест	    = ИтогоМест	    + Мест;
    ИтогоКоличество  = ИтогоКоличество  + Количество;
    ИтогоСумма	   = ИтогоСумма	   + СуммаБезНДС;
    ИтогоНДС		 = ИтогоНДС		 + СуммаНДС;
    ИтогоСуммаСНДС   = ИтогоСуммаСНДС   + СуммаСНДС;
    
    КонецЦикла;
    
    // Выводим итоги по последней странице
    ОбластьИтоговПоСтранице = Макет.ПолучитьОбласть("ИтогоПоСтранице");
    ОбластьИтоговПоСтранице.Параметры.ИтогМассаБруттоПоСтранице = ИтогоМассаБруттоНаСтранице;
    ОбластьИтоговПоСтранице.Параметры.ИтогМестПоСтранице	    = ИтогоМестНаСтранице;
    ОбластьИтоговПоСтранице.Параметры.ИтогКоличествоПоСтранице  = ИтогоКоличествоНаСтранице;
    ОбластьИтоговПоСтранице.Параметры.ИтогСуммыПоСтранице	   = ИтогоСуммаНаСтранице;
    ОбластьИтоговПоСтранице.Параметры.ИтогНДСПоСтранице		 = ИтогоНДСНаСтранице;
    ОбластьИтоговПоСтранице.Параметры.ИтогСуммыСНДСПоСтранице   = ИтогоСуммаСНДСНаСтранице;
    
    ТабДокумент.Вывести(ОбластьИтоговПоСтранице);
    
    // Выводим итоги по документу в целом
    ОбластьМакета = Макет.ПолучитьОбласть("Всего");
    ОбластьМакета.Параметры.ИтогМассаБрутто = ИтогоМассаБрутто;
    ОбластьМакета.Параметры.ИтогМест	    = ИтогоМест;
    ОбластьМакета.Параметры.ИтогКоличество  = ИтогоКоличество;
    ОбластьМакета.Параметры.ИтогСуммы	   = ИтогоСумма;
    ОбластьМакета.Параметры.ИтогНДС		 = ИтогоНДС;
    ОбластьМакета.Параметры.ИтогСуммыСНДС   = ИтогоСуммаСНДС;
    
    ТабДокумент.Вывести(ОбластьМакета);
    
    // Выводим подвал документа
    ОбластьМакета = Макет.ПолучитьОбласть("Подвал");
    
    ПолнаяДатаДокумента = Формат(Шапка.ДатаДокумента, "ДФ=""дд ММММ гггг """"года""""""");
    ДлинаСтроки = СтрДлина(ПолнаяДатаДокумента);
    ПервыйРазделитель = Найти(ПолнаяДатаДокумента," ");
    ВторойРазделитель = Найти(Прав(ПолнаяДатаДокумента,ДлинаСтроки-ПервыйРазделитель)," ")+ПервыйРазделитель;
    ОбластьМакета.Параметры.ДатаДокументаДень	 = """"+Лев(ПолнаяДатаДокумента,ПервыйРазделитель-1)+"""";
    ОбластьМакета.Параметры.ДатаДокументаМесяц    = Сред(ПолнаяДатаДокумента,ПервыйРазделитель+1,ВторойРазделитель-ПервыйРазделитель-1);
    ОбластьМакета.Параметры.ДатаДокументаГод	  = Прав(ПолнаяДатаДокумента,ДлинаСтроки-ВторойРазделитель);
    
    Руководители = РегламентированнаяОтчетность.ОтветственныеЛицаОрганизации(Шапка.Руководители, Шапка.ДатаДокумента,);
    Руководитель = Руководители.Руководитель;
    Бухгалтер    = Руководители.ГлавныйБухгалтер;
    
    // Главный бухгалтер
    ОбластьМакета.Параметры.ФИОГлавБухгалтера = Бухгалтер;
    
    // Отпуск товара разрешил
    Если НЕ ЗначениеЗаполнено(Шапка.ОтпускРазрешил) Тогда
    ФИООтпускРазрешил	   = Руководитель;
    ДолжностьОтпускРазрешил = Руководители.РуководительДолжность;
    Иначе
    ФамилияИмяОтчествоФизЛица	    = ФормированиеПечатныхФорм.ФамилияИмяОтчество(Шапка.ОтпускРазрешил, Шапка.ДатаДокумента);
    ПодразделениеДолжностьФизЛица    = ФормированиеПечатныхФорм.ДолжностьОтветственногоЛицаОрганизации(Шапка.ОтпускРазрешил, Шапка.ДатаДокумента, Организация);
    ФамилияИмяОтчествоОтпускРазрешил = ФамилияИмяОтчествоФизЛица.Фамилия + " " + ФамилияИмяОтчествоФизЛица.Имя + " " + ФамилияИмяОтчествоФизЛица.Отчество;
    ФИООтпускРазрешил			    = ОбщегоНазначения.ФамилияИнициалыФизЛица(ФамилияИмяОтчествоОтпускРазрешил);
    ДолжностьОтпускРазрешил		  = ПодразделениеДолжностьФизЛица.Должность;
    КонецЕсли;
    
    ОбластьМакета.Параметры.ФИОРуководителя	   = ФИООтпускРазрешил;
    ОбластьМакета.Параметры.ДолжностьРуководителя = ДолжностьОтпускРазрешил;
    
    // Отпуск товара произвел
    Если НЕ ЗначениеЗаполнено(Шапка.ОтпускПроизвел) Тогда
    ФамилияИмяОтчествоФизЛица	 = ФормированиеПечатныхФорм.ФамилияИмяОтчество(Шапка.ОтветственноеЛицо, Шапка.ДатаДокумента);
    ПодразделениеДолжностьФизЛица = ФормированиеПечатныхФорм.ДолжностьОтветственногоЛицаОрганизации(Шапка.ОтветственноеЛицо, Шапка.ДатаДокумента, Организация);
    Иначе
    ФамилияИмяОтчествоФизЛица	 = ФормированиеПечатныхФорм.ФамилияИмяОтчество(Шапка.ОтпускПроизвел, Шапка.ДатаДокумента);
    ПодразделениеДолжностьФизЛица = ФормированиеПечатныхФорм.ДолжностьОтветственногоЛицаОрганизации(Шапка.ОтпускПроизвел, Шапка.ДатаДокумента, Организация);
    КонецЕсли;
    
    ФамилияИмяОтчествоОтпускПроизвел = ФамилияИмяОтчествоФизЛица.Фамилия + " " + ФамилияИмяОтчествоФизЛица.Имя + " " + ФамилияИмяОтчествоФизЛица.Отчество;
    ФИООтпускПроизвел			    = ОбщегоНазначения.ФамилияИнициалыФизЛица(ФамилияИмяОтчествоОтпускПроизвел);
    ДолжностьОтпускПроизвел		  = ПодразделениеДолжностьФизЛица.Должность;
    
    ОбластьМакета.Параметры.ФИОКладовщика	   = ФИООтпускПроизвел;
    ОбластьМакета.Параметры.ДолжностьКладовщика = ДолжностьОтпускПроизвел;
    
    // Доверенность
    ОбластьМакета.Параметры.ДоверенностьНомер	 = Шапка.ДоверенностьНомер;
    ОбластьМакета.Параметры.ДоверенностьДата	  = Формат(Шапка.ДоверенностьДата, "ДФ='дд ММММ гггг'");
    ОбластьМакета.Параметры.ДоверенностьВыдана    = Шапка.ДоверенностьВыдана;
    ОбластьМакета.Параметры.ДоверенностьЧерезКого = Шапка.ДоверенностьЧерезКого;
    
    Если ЗначениеЗаполнено(ЕдиницаИзмеренияВеса) И ИтогоМассаБрутто > 0 Тогда
    ОбластьМакета.Параметры.МассаГрузаПрописью = ЧислоПрописью(ИтогоМассаБрутто, ,",,,,,,,,0")+ " " + СокрЛП(ЕдиницаИзмеренияВеса) + ".";
    КонецЕсли;
    
    Если ИтогоМест > 0 Тогда
    ОбластьМакета.Параметры.ВсегоМестПрописью = ЧислоПрописью(ИтогоМест, ,",,,,,,,,0");
    КонецЕсли;
    
    ОбластьМакета.Параметры.КоличествоПорядковыхНомеровЗаписейПрописью = ЧислоПрописью(КоличествоСтрок, ,",,,,,,,,0");
    ОбластьМакета.Параметры.СуммаПрописью = ОбщегоНазначения.СформироватьСуммуПрописью(ИтогоСуммаСНДС, мВалютаРегламентированногоУчета);
    ТабДокумент.Вывести(ОбластьМакета);
    
    Возврат ТабДокумент;
    
    КонецФункции
    
  11. Бухгалтерский угодник
    Offline

    Бухгалтерский угодник Администраторы Команда форума Администратор

    Регистрация:
    29 дек 2008
    Сообщения:
    21.523
    Симпатии:
    407
    Баллы:
    104
    Уф... Слава богу текст ГМ не выложили....
  12. nipil
    Offline

    nipil

    Регистрация:
    2 дек 2013
    Сообщения:
    1
    Симпатии:
    0
    Баллы:
    1
    Здравствуйте Уважаемые форумчане!

    Кто подскажет, почему в исходнике:
    Код:
    ОбластьМакета.Параметры.ОснованиеНомер	 = "";
    ОбластьМакета.Параметры.ОснованиеДата   = "";
    ...
    ТабДокумент.Вывести(ОбластьМакета);
    см #30 (пред- предыдущий пост) или "Бухгалтерия предприятия 2.0.52.6 РеализацияТоваровУслуг.МодульОбъекта"

    Заранее спасибо.

Поделиться этой страницей