[РЕШЕНО] Печатная форма счет-фактура выданный в Бухгалтерском учете 7.7.600

Тема в разделе "Отчеты и обработки для "1С:Предприятие 7.7"", создана пользователем MyNameNoName, 10 сен 2015.

  1. TopicStarter Overlay
    MyNameNoName
    Offline

    MyNameNoName Опытный в 1С

    Регистрация:
    17 май 2013
    Сообщения:
    931
    Симпатии:
    0
    Баллы:
    26
    В Бухгалтерии предприятия у счет-фактуры выданной есть печатная форма счет-фактура.
    необходимо некоторые изменения по внешнему виду внести, но не могу понять где сама форма находится. это не внешняя форма.
    В самом документе много печатных форм, но это не они.
    Пытался по коду разобраться ссылается на Процедура Печать1137(), но далее не понятно на какую печатную форму.
    Код:
    Процедура Печать1137()
       
        Если ДатаДок >= '01.10.2011' Тогда
           
            Если ВидОперации = Перечисление.ВидыОперацийСчетаФактурыВыданного.СуммоваяРазница Тогда
               
                ТекстСообщения = "Счета-фактуры на суммовые разницы не выписываются, начиная с 01.10.2011 г.";
                Сообщить(ТекстСообщения, "!" );
                Возврат;            
               
            КонецЕсли;
           
        КонецЕсли;
       
        ПустойПоказатель = "----";
       
        НомерДокПечатнойФормы = глПреобразоватьНомерДок(НомерДок, 0, 0);
    
        // В зависимости от даты документа используются разные шаблоны печатной формы.
        // При наличии в каталоге информационной базы файла с именем
        // "ExtForms\PrnForms\1csf*.mxl", будет использоваться шаблон печатной формы
        // размещенный в данном файле.
        Таб = СоздатьОбъект("Таблица");
    
        ИмяФайлаПечатнойФормы = КаталогИБ() + "ExtForms\PrnForms\1csf1137.mxl";
        ИмяТаблицы = "СчетФактура1137";
       
       
        Если ФС.СуществуетФайл(ИмяФайлаПечатнойФормы) = 1 Тогда
            Таб.ИсходнаяТаблица(ИмяФайлаПечатнойФормы);
        Иначе
            Таб.ИсходнаяТаблица(ИмяТаблицы);
        КонецЕсли;
           
        НомерДокумента   = СокрЛ(НомерДок);
        ДатаДокумента    = Формат(ДатаДок ,"Д (0)ДДММММГГГГ");
        ПечНомерИсправления = ПустойПоказатель;
        ПечДатаИсправления  = ПустойПоказатель;
       
        ПечНомерПлатРасчДок = СокрЛП(НомерПлатРасчДок);
        ПечДатаПлатРасчДок  = Формат(ДатаПлатРасчДок ,"Д ДДММГГГГ") + " г.";
       
        Продавец = СокрЛП(Константа.ОфициальноеНазваниеОрганизации);
       
        ИННКПППокупателя = Контрагент.ИНН;
       
        Если ВариантОтправки=1 Тогда
            ПечГрузоотправитель = ПустойПоказатель;
            ПечГрузополучатель = ПустойПоказатель;
           
                ВыбратьСтроки();
                Пока ПолучитьСтроку()=1 Цикл
                    Если ТипЗначенияСтр(Товар) = "Справочник" Тогда
                        Если Товар.Вид() = "Номенклатура" Тогда
                            Если (Товар.ТипНоменклатуры = Перечисление.ТипыНоменклатуры.Услуга) или
                            (Товар.ТипНоменклатуры = Перечисление.ТипыНоменклатуры.Работа) или
                            (Товар.ТипНоменклатуры = Перечисление.ТипыНоменклатуры.ПосредническаяУслуга) или
                            (Товар.ТипНоменклатуры = Перечисление.ТипыНоменклатуры.УслугаЕНВД) Тогда
                                Продолжить;
                            КонецЕсли;
                        КонецЕсли;
                        Если ВидОперации <> Перечисление.ВидыОперацийСчетаФактурыВыданного.Аванс Тогда
                            ПечГрузоотправитель = "Он же";
                            ПечГрузополучатель = СокрП(Грузополучатель.ПолнНаименование)+", "+СокрП(Грузополучатель.ПочтовыйАдрес);
                        КонецЕсли;                   
                        Прервать;
                    КонецЕсли;
                КонецЦикла;       
        Иначе
            ПечГрузополучатель = СокрП(Грузополучатель.ПолнНаименование)+", "+СокрП(Грузополучатель.ПочтовыйАдрес);
            ПечГрузоотправитель = СокрП(Грузоотправитель.ПолнНаименование)+", "+СокрП(Грузоотправитель.ПочтовыйАдрес);
        КонецЕсли;
       
       
        Если ПустоеЗначение(Грузополучатель) = 0 Тогда
            Если КонтрагентЯвляетсяОбособленнымПодразделением = 1 Тогда
                ИНН = ""; КПП = "";
                глРазложитьИННКонтрагента(Контрагент, ИНН, КПП);
                ИННКПППокупателя = ИНН;           
                глРазложитьИННКонтрагента(Грузополучатель, ИНН, КПП);
                ИННКПППокупателя = ИННКПППокупателя + ?(КПП = "", "", "/" + КПП);
            КонецЕсли;
        КонецЕсли;
       
        // Определим валюту оплаты.
        ВалютаПечати = "Российский рубль, 643";
        Если ВидОперации <> Перечисление.ВидыОперацийСчетаФактурыВыданного.СуммоваяРазница Тогда
            Если Договор.ВалютаДоговора.Выбран() = 1 Тогда
               
                Если (ВидОперации = Перечисление.ВидыОперацийСчетаФактурыВыданного.Аванс)
                И (Договор.ОплатаДоговора = 1) Тогда
                    // оплата в рублях
                Иначе   
                   
                    ВалютаПечати = "" + СокрЛП(Договор.ВалютаДоговора.ПолнНаименование) + ", " + Договор.ВалютаДоговора.Код;
                   
                КонецЕсли;
               
            КонецЕсли;
        КонецЕсли;
       
        // Выгрузим табличную часть документа в таблицу значений.
        ТабДок = СоздатьОбъект("ТаблицаЗначений");
        ВыгрузитьТабличнуюЧасть(ТабДок);
       
        //**************************************************
        //Печатаем сч-ф по договору у.е. в рублях
        ТекстПредупреждения = "";
        ЦеныВДоговоре = 1; // в рублях
        ОплатаДоговора = 1; // в рублях
        СчетФактураВУЕ = 0;
        Если Договор.Выбран() = 1 Тогда
            Если ПустоеЗначение(Договор.ВалютаДоговора) = 0 Тогда
                ЦеныВДоговоре = 2; // в валюте
                ОплатаДоговора = Договор.ОплатаДоговора; // 1 - врублях, 2 - в валюте
                Если ОплатаДоговора = 1 Тогда
                    СчетФактураВУЕ = 1;
                    ВестиУчетРасчетовУЕ = Договор.ВестиУчетРасчетовУЕ;
                КонецЕсли;
            КонецЕсли;
        КонецЕсли;
       
    
        Если ((Константа.ФормироватьСчетФактуруПоУЕвРублях.Получить(ДатаДок) = Да)
        или (глПолучитьВерсиюПостановления(ДатаДок) = 2))
        и (СчетФактураВУЕ = 1) Тогда
        ВалютаПечати = "Российский рубль, 643";
            Опер = СоздатьОбъект("Операция");
            //Предварительно получим сумму НДС, если документ проведен
            Сч68_2 = СчетПоКоду("68.2");
            СуммаНДСДокументаРуб = 0;
            Если Проведен() = 1 Тогда
                Если Опер.НайтиОперацию(ТекущийДокумент()) = 1 Тогда
                    Опер.ВыбратьПроводки();
                    Пока Опер.ПолучитьПроводку() = 1 Цикл
                        Если Опер.Кредит.Счет = Сч68_2 Тогда
                            СуммаНДСДокументаРуб = СуммаНДСДокументаРуб + Опер.Сумма;
                        КонецЕсли;
                    КонецЦикла;
                КонецЕсли;
            КонецЕсли;
    
            Сч62_6 = СчетПоКоду("62.6");
            Сч62_7 = СчетПоКоду("62.7");
            Сч62_8 = СчетПоКоду("62.8");
            СчВР_6 = СчетПоКоду("ВР.6");
           
            СуммаЗачетаВал = 0;
            СуммаЗачетаРуб = 0;
            ЗадолженностьВал = 0;
            ЗадолженностьРуб = 0;
           
            Если ДокументОснование.Выбран() = 1 Тогда // поиск зачтенного аванса           
                Если Опер.НайтиОперацию(ДокументОснование) = 1 Тогда
                    Опер.ВыбратьПроводки();
                    Пока Опер.ПолучитьПроводку() = 1 Цикл
                        Если Опер.Дебет.Счет = СчВР_6 Тогда
                            СуммаЗачетаВал = СуммаЗачетаВал + Опер.ВалСумма;
                            СуммаЗачетаРуб = СуммаЗачетаРуб + Опер.Сумма;
                            ЗадолженностьВал = ЗадолженностьВал + Опер.ВалСумма;
                            ЗадолженностьРуб = ЗадолженностьРуб + Опер.Сумма;
                           
                        Иначе
                            Если ((Опер.Дебет.Счет = Сч62_7) и (Опер.Кредит.Счет = Сч62_6))
                            ИЛИ ((Опер.Дебет.Счет = Сч62_7) и (Опер.Кредит.Счет = Сч62_8)) Тогда
                                СуммаЗачетаВал = СуммаЗачетаВал + Опер.ВалСумма;
                                СуммаЗачетаРуб = СуммаЗачетаРуб + Опер.Сумма;
                            КонецЕсли;
                           
                            Если (Опер.Дебет.Счет = Сч62_6) ИЛИ (Опер.Дебет.Счет = Сч62_8) Тогда
                                ЗадолженностьВал = ЗадолженностьВал + Опер.ВалСумма;
                                ЗадолженностьРуб = ЗадолженностьРуб + Опер.Сумма;
                            КонецЕсли;
                        КонецЕсли;
                    КонецЦикла;
                КонецЕсли;
            КонецЕсли;
           
            Если ВерсияОбъекта < "7.70.421" Тогда
                Если Валюта.Выбран() = 1 Тогда
                    ЦеныВДоговоре = 2;
                    КурсДок = Валюта.Курс.Получить(ДатаДок);
                КонецЕсли;
            Иначе
                ВалютаДок = Договор.ВалютаДоговора;
            КонецЕсли;
           
            Если ЦеныВДоговоре = 2 Тогда
                Кратность = ВалютаДок.Кратность.Получить(ДатаДок);
                Кратность = ?(Кратность=0, 1, Кратность);
                Если Договор.ВестиУчетРасчетовУЕ = 1 Тогда
                    Кратность = Кратность * 100 / (100 + Договор.ПроцентКорректировкиКурсаУЕ);
                КонецЕсли;
            КонецЕсли;
           
            ДоляОплаченнойОтгрузки = ?(ЗадолженностьВал = 0, 0, СуммаЗачетаВал / ЗадолженностьВал);       
            КурсОплаты = ?(СуммаЗачетаВал = 0, 0, Окр(СуммаЗачетаРуб / СуммаЗачетаВал, 4, 1));
            КурсСФ = ?(((ЦеныВДоговоре = 2) и (Аванс = 0)) или (ОплатаДоговора = 2), Курс / Кратность, 1);
           
            Если ВидОперации = Перечисление.ВидыОперацийСчетаФактурыВыданного.СуммоваяРазница Тогда
                КурсСФ = 1;
            КонецЕсли;
           
            Если (ВидОперации <> Перечисление.ВидыОперацийСчетаФактурыВыданного.СуммоваяРазница) и (ВидОперации <> Перечисление.ВидыОперацийСчетаФактурыВыданного.Аванс) Тогда
               
                // для документов в у.е. пересчет в рубли
                Если глПересчитатьВалюту(ТекущийДокумент()) = 1 Тогда
                    КурсОплаты = ?(СуммаЗачетаВал = 0, 0, СуммаЗачетаРуб / СуммаЗачетаВал);
                    глПересчетВалютнойТабличнойЧастиВРубли(ТабДок, КурсСФ, КурсОплаты, ДоляОплаченнойОтгрузки, 0, 1, 1);               
                Иначе
                    ТабДок.ВыбратьСтроки();
                    Пока ТабДок.ПолучитьСтроку()= 1 Цикл
                        ОплСумма = ТабДок.Сумма * ДоляОплаченнойОтгрузки;
                        ТабДок.Сумма = Окр(ОплСумма * КурсОплаты + (ТабДок.Сумма - ОплСумма) * КурсСФ, 2, 1);
                       
                        ОплНДС = ТабДок.НДС * ДоляОплаченнойОтгрузки;
                        ТабДок.НДС = Окр(ОплНДС * КурсОплаты + (ТабДок.НДС - ОплНДС) * КурсСФ, 2, 1);
                       
                        ОплНП = ТабДок.НП * ДоляОплаченнойОтгрузки;
                        ТабДок.НП = Окр(ОплНП * КурсОплаты + (ТабДок.НП - ОплНП) * КурсСФ, 2, 1);
                       
                        ОплАкцизСумма = ТабДок.АкцизСумма * ДоляОплаченнойОтгрузки;
                        ТабДок.АкцизСумма = Окр(ОплАкцизСумма * КурсОплаты + (ТабДок.АкцизСумма - ОплАкцизСумма) * КурсСФ, 2, 1);
                       
                        ОплЦена = ТабДок.Цена * ДоляОплаченнойОтгрузки;
                        ТабДок.Цена = Окр(ОплЦена * КурсОплаты + (ТабДок.Цена - ОплЦена) * КурсСФ, 2, 1);
                       
                       
                        ОплВсего = ТабДок.Всего * ДоляОплаченнойОтгрузки;
                        ТабДок.Всего  = Окр(ОплВсего * КурсОплаты + (ТабДок.Всего  - ОплВсего) * КурсСФ, 2, 1);
                    КонецЦикла;
                КонецЕсли;
               
                Если Проведен() = 1 Тогда
                    Если (СуммаНДСДокументаРуб <> ТабДок.Итог("НДС")) и (ДоляОплаченнойОтгрузки <> 0) Тогда
                        ТекстПредупреждения = "Внимание! Сумма НДС в счете-фактуре отличается от суммы НДС отраженной в бухгалтерском учете. Возможно следует перепровести документ.";
                        Таб.ВывестиСекцию("ТекстПредупреждения");
                    Иначе
                        ТекстПредупреждения = "";
                    КонецЕсли;
                КонецЕсли;
            КонецЕсли;
        КонецЕсли;   
       
        Если ВидОперации = Перечисление.ВидыОперацийСчетаФактурыВыданного.Аванс Тогда
            Если ПустаяСтрока(ПечНомерПлатРасчДок)=1 Тогда
                ПечНомерПлатРасчДок = ПустойПоказатель;
                ПечДатаПлатРасчДок = ПустойПоказатель;
            КонецЕсли;
        Иначе
            Если ПустаяСтрока(ПечНомерПлатРасчДок)=1 Тогда
                ПечНомерПлатРасчДок = "";
                ПечДатаПлатРасчДок = "";
            КонецЕсли;
        КонецЕсли;
           
        Таб.ВывестиСекцию("ШапкаИнформация");
        Таб.ВывестиСекцию("Шапка");
           
        // Печать строк документа.
        ТабДок.ВыбратьСтроки();
        Ном=0;
        Пока ТабДок.ПолучитьСтроку()=1 Цикл
            Ном=Ном+1;
            Если ТипЗначения(ТабДок.Товар) = 2 Тогда
                Наименование = ТабДок.Товар;
                ЕдиницаИзмерения = ПустойПоказатель;
                ЕдиницаИзмеренияКод = ПустойПоказатель;
               
            ИначеЕсли ТабДок.Товар.Вид() = "Номенклатура" Тогда
                Наименование = ?(ПустаяСтрока(ТабДок.Товар.ПолнНаименование)=1, ТабДок.Товар.Наименование, ТабДок.Товар.ПолнНаименование);
                ЕдиницаИзмерения = ТабДок.Товар.ЕдиницаИзмерения;
                ЕдиницаИзмеренияКод = ТабДок.Товар.ЕдиницаИзмерения.Код;
               
            ИначеЕсли ТабДок.Товар.Вид() = "ОсновныеСредства" Тогда
                Наименование = ТабДок.Товар.Наименование;
                ЕдиницаИзмерения = ПустойПоказатель;
                ЕдиницаИзмеренияКод = ПустойПоказатель;
               
            ИначеЕсли ТабДок.Товар.Вид() = "НематериальныеАктивы" Тогда
                Наименование = ТабДок.Товар.Наименование;
                ЕдиницаИзмерения = ПустойПоказатель;
                ЕдиницаИзмеренияКод = ПустойПоказатель;
               
            ИначеЕсли ТабДок.Товар.Вид() = "Материалы" Тогда
                Наименование = ТабДок.Товар.Наименование;
                ЕдиницаИзмерения = ТабДок.Товар.ЕдиницаИзмерения;
                ЕдиницаИзмеренияКод = ТабДок.Товар.ЕдиницаИзмерения.Код;
            КонецЕсли;
            Если ВидОперации = Перечисление.ВидыОперацийСчетаФактурыВыданного.Аванс Тогда
                ЕдиницаИзмерения = ПустойПоказатель;
                ЕдиницаИзмеренияКод = ПустойПоказатель;
            КонецЕсли;
            Если ПустоеЗначение(ЕдиницаИзмерения) = 1 Тогда
                ЕдиницаИзмерения = ПустойПоказатель;
                ЕдиницаИзмеренияКод = ПустойПоказатель;
            КонецЕсли;
    
            Если (ВидОперации = Перечисление.ВидыОперацийСчетаФактурыВыданного.Аванс)
            ИЛИ (ПустоеЗначение(ТабДок.ГТД) = 1) Тогда
                НомерГТД_Н = ПустойПоказатель;
                СтранаН = ПустойПоказатель;
                СтранаКод = ПустойПоказатель;
            Иначе
                НомерГТД_Н = ТабДок.ГТД;
                Если ПустаяСтрока(ТабДок.ГТД.СтранаПроисхождения) = 1 Тогда
                    СтранаН = "";
                    СтранаКод = "";
                Иначе
                    СтранаН = ТабДок.ГТД.СтранаПроисхождения;
                    СтранаКод = ТабДок.ГТД.КодПоОКСМ;
                КонецЕсли;
            КонецЕсли;
            Если НДСпоСтавкеНольПроцентов = 1 Тогда
                ПредставлениеСтавкиНДС = "0%";
            Иначе
                Если (ТабДок.СтавкаНДС.Выбран() = 1) и (ТабДок.СтавкаНДС.Ставка > 0) Тогда
                    ПредставлениеСтавкиНДС = "" + ТабДок.СтавкаНДС.Ставка + "%";
                   
                    Если СуммаНДСопределяетсяРасчетнымМетодом = 1 Тогда
                        ПредставлениеСтавкиНДС = ПредставлениеСтавкиНДС + " / 1" + ТабДок.СтавкаНДС.Ставка + "%";
                    КонецЕсли;
                   
                Иначе
                    ПредставлениеСтавкиНДС = "без НДС";
                КонецЕсли;
            КонецЕсли;
            Если ТабДок.Количество = 0 Тогда
                ПечКоличество = ПустойПоказатель;
                ПечЦена          = ПустойПоказатель;
            ИначеЕсли (ВидОперации = Перечисление.ВидыОперацийСчетаФактурыВыданного.Аванс)
            ИЛИ (ВидОперации = Перечисление.ВидыОперацийСчетаФактурыВыданного.СуммоваяРазница)
            ИЛИ (Аванс = 1) Тогда
                ПечКоличество = ПустойПоказатель;
                ПечЦена          = ПустойПоказатель;
            Иначе                
                ПечКоличество = Формат(ТабДок.Количество, "Ч-15.3,");
                Если ТабДок.Цена = 0 Тогда
                    ПечЦена          = ПустойПоказатель;
                Иначе               
                    ПечЦена = Формат(ТабДок.Цена, "Ч-15.2,");
                КонецЕсли;
            КонецЕсли;
            Если (ВидОперации = Перечисление.ВидыОперацийСчетаФактурыВыданного.Аванс)
            ИЛИ (ВидОперации = Перечисление.ВидыОперацийСчетаФактурыВыданного.СуммоваяРазница)
            ИЛИ (Аванс = 1) Тогда
                ПечСумма = ПустойПоказатель;
            ИначеЕсли ТабДок.Сумма = 0 Тогда
                ПечСумма = ПустойПоказатель;
            Иначе                 
                ПечСумма = Формат(ТабДок.Сумма, "Ч-15.2,");
            КонецЕсли;
    
            Если ВидОперации = Перечисление.ВидыОперацийСчетаФактурыВыданного.Аванс Тогда
                ПечАкциз = ПустойПоказатель;
            Иначе
                ПечАкциз = ?(ТабДок.АкцизСумма=0, "без акциза", Формат(ТабДок.АкцизСумма,"Ч-15.2,"));
            КонецЕсли;
                   
            Если НДСпоСтавкеНольПроцентов = 1 Тогда
                ПечНДС = ?(ТабДок.НДС=0,"0,00", Формат(ТабДок.НДС,"Ч-15.2,"));
            Иначе
                ПечНДС = ?(ТабДок.НДС=0,"без НДС", Формат(ТабДок.НДС,"Ч-15.2,"));
            КонецЕсли;   
            ПечВсего = ?(ТабДок.Всего=0,ПустойПоказатель, Формат(ТабДок.Всего,"Ч-15.2,"));       
           
            Таб.ВывестиСекцию("Строка");
        КонецЦикла;
       
        Если НДСпоСтавкеНольПроцентов = 1 Тогда       
            ПечИтогНДС = ?(ТабДок.Итог("НДС")=0,"0,00", Формат(ТабДок.Итог("НДС"),"Ч-15.2,"));
        Иначе
            ПечИтогНДС = ?(ТабДок.Итог("НДС")=0,"без НДС", Формат(ТабДок.Итог("НДС"),"Ч-15.2,"));
        КонецЕсли;
       
        ПечИтогВсего = ?(ТабДок.Итог("Всего")=0,ПустойПоказатель, Формат(ТабДок.Итог("Всего"),"Ч-15.2,"));
       
        Если ВидОперации <> Перечисление.ВидыОперацийСчетаФактурыВыданного.Аванс Тогда
            СуммаБезНДС = ТабДок.Итог("Всего") - ТабДок.Итог("НДС");
            ПечИтогБезНДС = ?(СуммаБезНДС=0,ПустойПоказатель, Формат(СуммаБезНДС,"Ч-15.2,"));
        Иначе
            ПечИтогБезНДС = ПустойПоказатель;
        КонецЕсли;
    
        Таб.ВывестиСекцию("Подвал");
    
        Таб.Опции(0, 0, 0, 0, "ОпцииПечатиСчетаФактуры", "ОкноСчетаФактуры");
       
        Если ПустоеЗначение(ТекстПредупреждения) = 1 Тогда
            Таб.ОбластьПечати(1,,,);
        Иначе
            Таб.ОбластьПечати(2,,,);
        КонецЕсли;
       
        Таб.ПовторятьПриПечатиСтроки( 15, 15 );
        Таб.ТолькоПросмотр(1);
        Таб.ПараметрыСтраницы(2,,,,,,,,,1,,);
        Таб.Показать("Печать счета-фактуры","");
       
    КонецПроцедуры // Печать1137()
    --- Объединение сообщений, 10 сен 2015 ---
    В чем фокус?
  2. ТехБухПривет
    Offline

    ТехБухПривет Профессионал в 1С Команда форума

    Регистрация:
    25 июн 2013
    Сообщения:
    504
    Симпатии:
    53
    Баллы:
    54
    ну у вас же написано:
    ИмяФайлаПечатнойФормы = КаталогИБ() + "ExtForms\PrnForms\1csf1137.mxl";(где лежит база)
    Если файла нет, то
    ИмяТаблицы = "СчетФактура1137";(то есть у документа должна быть таблица с таким названием)
    MyNameNoName нравится это.
  3. TopicStarter Overlay
    MyNameNoName
    Offline

    MyNameNoName Опытный в 1С

    Регистрация:
    17 май 2013
    Сообщения:
    931
    Симпатии:
    0
    Баллы:
    26
    Я так и понял. По в данном каталоге у меня пусто.
    По коду смотрел берется СчетФактура1137, но нет такой:
    upload_2015-9-10_16-21-27.png
    --- Объединение сообщений, 10 сен 2015 ---
    Чтобы убедиться в этом добавил код:
    upload_2015-9-10_16-25-13.png

    upload_2015-9-10_16-25-49.png
  4. TopicStarter Overlay
    MyNameNoName
    Offline

    MyNameNoName Опытный в 1С

    Регистрация:
    17 май 2013
    Сообщения:
    931
    Симпатии:
    0
    Баллы:
    26
    Явно тянется с СчетФактура1137, но где такая таблица может располагаться кроме самого документа? общих печатных форм как я понял в 7-ке нет.
    --- Объединение сообщений, 10 сен 2015 ---
    Вопрос закрыт, я нашел!
    Есть общие таблицы, вот там она!
    Спасибо.

Поделиться этой страницей