[РЕШЕНО] Ошибка в запросе

Тема в разделе "Конфигурирование на платформе "1С:Предприятие 8"", создана пользователем sashadeo, 12 авг 2015.

  1. TopicStarter Overlay
    sashadeo
    Offline

    sashadeo Опытный в 1С

    Регистрация:
    29 дек 2010
    Сообщения:
    379
    Симпатии:
    0
    Баллы:
    26
    Помогите разобраться всю голову сломал... слегка доработал функцию теперь выходит ошибка

    "
    {Документ.РасчетСНиСО(255)}: Ошибка при вызове метода контекста (Выполнить)
    ТЗИсчисленныйСН = Запрос.Выполнить().Выгрузить();
    по причине:
    {(6, 26)}: Ожидается выражение "ВЫБРАТЬ"
    ВНУТРЕННЕЕ СОЕДИНЕНИЕ (<<?>>ВТ_СписокРаботников) КАК Работники

    "

    Процедура

    Код:
    Функция Автозаполнение(ПостроительЗапроса = Неопределено) Экспорт
    
        ГоловнаяОрганизация = ОбщегоНазначения.ГоловнаяОрганизация(Организация);
       
        Запрос = Новый Запрос;
        Запрос.МенеджерВременныхТаблиц = Новый МенеджерВременныхТаблиц;
    
        // Установим параметры запроса
        Запрос.УстановитьПараметр("парамНачало" , ПериодРегистрации);
        Запрос.УстановитьПараметр("парамКонец" , КонецМесяца(ПериодРегистрации));
        Запрос.УстановитьПараметр("парамОрганизация" , Организация);
        Запрос.УстановитьПараметр("парамГоловнаяОрганизация" , ГоловнаяОрганизация);
        Запрос.УстановитьПараметр("парамПользователь" , Ответственный);
        Запрос.УстановитьПараметр("парамПодразделение" , ПодразделениеОрганизации);
        Запрос.УстановитьПараметр("Уволен", Перечисления.ПричиныИзмененияСостояния.Увольнение);
        Запрос.УстановитьПараметр("Принят", Перечисления.ПричиныИзмененияСостояния.ПриемНаРаботу);
        Запрос.УстановитьПараметр("парамПриход", ВидДвиженияНакопления.Приход);
        Запрос.УстановитьПараметр("парамНалогВзнос", Перечисления.ВидыПлатежейВБюджетИФонды.Налог);
        Запрос.УстановитьПараметр("парамИсчисление", Перечисления.РасчетыСБюджетомФондамиВидСтроки.Исчисление);
        Запрос.УстановитьПараметр("парамВнутреннееСовместительство", Перечисления.ВидыЗанятостиВОрганизации.ВнутреннееСовместительство);
    
        // узнаем учетную политику по налоговому учету
        мОрганизацияЯвляетсяПлательщикомСН = ПроцедурыНалоговогоУчета.ПолучитьПризнакПлательщикаСоциальногоНалога(Организация, ПериодРегистрации);
        мОрганизацияЯвляетсяВкладчикомОППВ = ПроцедурыНалоговогоУчета.ПолучитьПризнакВкладчикаПрофПенсионныхВзносов(Организация, ПериодРегистрации);
       
        ПустоеПодразделение = Справочники.ПодразделенияОрганизаций.ПустаяСсылка();
       
        Если ПодразделениеОрганизации = ПустоеПодразделение Тогда
            ПоВсемПодразделениямОрганизации = Истина;
            УсловиеНаПодразделение = "РаботникиОрганизации.ПодразделениеОрганизации.Владелец = &парамОрганизация";
        Иначе
            ПоВсемПодразделениямОрганизации = Ложь;
            УсловиеНаПодразделение = "РаботникиОрганизации.ПодразделениеОрганизации В ИЕРАРХИИ (&парамПодразделение)";
        КонецЕсли;
       
        //СписокРаботниковТекст
        //Описание:
        //    Выбирает список работников, отвечающих условиям отбора, числящихся на начало месяца и принятых за месяц,
        //  а также переведенных в середине месяца из других обособленных подразделений
        СписокРаботниковТекст = "
        |        // срез работников на начало месяца
        |        ВЫБРАТЬ
        |            РаботникиОрганизации.Физлицо КАК Физлицо
        |        ИЗ
        |            РегистрСведений.РаботникиОрганизаций.СрезПоследних(
        |                    &парамНачало,
        |                    Организация = &парамГоловнаяОрганизация
        |                    И (ВидЗанятости <> &парамВнутреннееСовместительство)) КАК РаботникиОрганизации
        |        ГДЕ
        |            РаботникиОрганизации.ОбособленноеПодразделение = &парамОрганизация
        |            И РаботникиОрганизации.Организация = &парамГоловнаяОрганизация
        |        "+?(ПоВсемПодразделениямОрганизации, "", "И "+УсловиеНаПодразделение)+"
        |       
        |        ОБЪЕДИНИТЬ
        |
        |        // движения работников за месяц
        |        ВЫБРАТЬ
        |            РаботникиОрганизации.Физлицо
        |        ИЗ
        |            РегистрСведений.РаботникиОрганизаций КАК РаботникиОрганизации
        |
        |            ЛЕВОЕ СОЕДИНЕНИЕ (ВЫБРАТЬ
        |                                    ТекущееНазначение.Регистратор,
        |                                    ТекущееНазначение.НомерСтроки,
        |                                    МАКСИМУМ(ПредыдущееНазначение.Период) КАК ДатаПредыдущегоНазначения
        |                                ИЗ
        |                                    РегистрСведений.РаботникиОрганизаций КАК ТекущееНазначение
        |                                    ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.РаботникиОрганизаций КАК ПредыдущееНазначение
        |                                        ПО ТекущееНазначение.ФизЛицо = ПредыдущееНазначение.ФизЛицо
        |                                            И ТекущееНазначение.Приказ = ПредыдущееНазначение.Приказ
        |                                            И ПредыдущееНазначение.Организация = &парамГоловнаяОрганизация
        |                                            И ПредыдущееНазначение.Период < ТекущееНазначение.Период
        |                                ГДЕ
        |                                    ТекущееНазначение.Период > &парамНачало
        |                                    И ТекущееНазначение.Период <= &парамКонец
        |                                    И ТекущееНазначение.Организация = &парамГоловнаяОрганизация
        |                                    И ТекущееНазначение.ОбособленноеПодразделение = &парамОрганизация
        |                                СГРУППИРОВАТЬ ПО
        |                                    ТекущееНазначение.Регистратор,
        |                                    ТекущееНазначение.НомерСтроки) КАК ДатыПредыдущихНазначений
        |                ПО РаботникиОрганизации.Регистратор = ДатыПредыдущихНазначений.Регистратор
        |                    И РаботникиОрганизации.НомерСтроки = ДатыПредыдущихНазначений.НомерСтроки
        |                   
        |            ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.РаботникиОрганизаций КАК ПредыдущиеНазначения
        |                ПО РаботникиОрганизации.ФизЛицо = ПредыдущиеНазначения.ФизЛицо
        |                    И РаботникиОрганизации.Приказ = ПредыдущиеНазначения.Приказ
        |                    И ПредыдущиеНазначения.Организация = &парамГоловнаяОрганизация
        |                    И ДатыПредыдущихНазначений.ДатаПредыдущегоНазначения = ПредыдущиеНазначения.Период
        |       
        |        ГДЕ
        |            РаботникиОрганизации.Период > &парамНачало
        |            И РаботникиОрганизации.Период <= &парамКонец
        |            И РаботникиОрганизации.Организация = &парамГоловнаяОрганизация
        |            И (РаботникиОрганизации.ВидЗанятости <> &парамВнутреннееСовместительство)
        |            И (РаботникиОрганизации.ПричинаИзмененияСостояния = &Принят
        |                    ИЛИ РаботникиОрганизации.ОбособленноеПодразделение <> ПредыдущиеНазначения.ОбособленноеПодразделение)
        |            И РаботникиОрганизации.ОбособленноеПодразделение = &парамОрганизация
        |            "+?(ПоВсемПодразделениямОрганизации, "", "И "+УсловиеНаПодразделение)+"
        |";
    
        Если ПостроительЗапроса <> Неопределено Тогда
    
            // Установим параметры запроса
            ПостроительЗапроса.Параметры.Вставить("парамНачало" , ПериодРегистрации);
            ПостроительЗапроса.Параметры.Вставить("парамКонец" , КонецМесяца(ПериодРегистрации));
            ПостроительЗапроса.Параметры.Вставить("парамОрганизация" , Организация);
            ПостроительЗапроса.Параметры.Вставить("парамГоловнаяОрганизация" , ГоловнаяОрганизация);
            ПостроительЗапроса.Параметры.Вставить("парамПользователь" , Ответственный);
            ПостроительЗапроса.Параметры.Вставить("парамПодразделение" , ПодразделениеОрганизации);
            ПостроительЗапроса.Параметры.Вставить("Уволен", Перечисления.ПричиныИзмененияСостояния.Увольнение);
            ПостроительЗапроса.Параметры.Вставить("Принят", Перечисления.ПричиныИзмененияСостояния.ПриемНаРаботу);
            ПостроительЗапроса.Параметры.Вставить("парамПриход", ВидДвиженияНакопления.Приход);
            ПостроительЗапроса.Параметры.Вставить("парамНалогВзнос", Перечисления.ВидыПлатежейВБюджетИФонды.Налог);
            ПостроительЗапроса.Параметры.Вставить("парамИсчисление", Перечисления.РасчетыСБюджетомФондамиВидСтроки.Исчисление);
            ПостроительЗапроса.Параметры.Вставить("парамВнутреннееСовместительство", Перечисления.ВидыЗанятостиВОрганизации.ВнутреннееСовместительство);
           
            ИсходныйТекстПостроителя = ПостроительЗапроса.Текст;
            СписокРаботниковТекст = СтрЗаменить(ИсходныйТекстПостроителя,"РАЗРЕШЕННЫЕ","");
            СписокРаботниковТекст = Лев(СписокРаботниковТекст, Найти(СписокРаботниковТекст,"УПОРЯДОЧИТЬ") - 1);
           
        КонецЕсли;
    
        // Еще берем людей, которые не являются работниками или договорниками, но
        // за месяц расчета имеют налогооблагаемый доход, и по которым еще не был рассчитан
        // налог в периоде регистрации
        СписокРаботниковТекст = "
        |ВЫБРАТЬ
        |    РаботникиОрганизации.ФизЛицо
        |ПОМЕСТИТЬ ВТ_СписокРаботников
        |ИЗ
        |    (" + СписокРаботниковТекст + ") КАК РаботникиОрганизации
        |
        |ОБЪЕДИНИТЬ
        |
        |ВЫБРАТЬ
        |    СНСведенияОДоходах.ФизЛицо
        |ИЗ
        |    РегистрНакопления.СНСведенияОДоходах КАК СНСведенияОДоходах
        |
        |    ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.РаботникиОрганизаций.СрезПоследних(
        |                &парамКонец,
        |                Организация = &парамГоловнаяОрганизация
        |                И ВидЗанятости <> &парамВнутреннееСовместительство) КАК РаботникиОрганизации
        |        ПО СНСведенияОДоходах.ФизЛицо = РаботникиОрганизации.ФизЛицо
        |
        |    ЛЕВОЕ СОЕДИНЕНИЕ РегистрНакопления.СНИсчисленный КАК СНИсчисленный
        |        ПО СНСведенияОДоходах.ФизЛицо = СНИсчисленный.ФизЛицо
        |           И СНИсчисленный.Организация = &парамОрганизация
        |           И СНИсчисленный.Период МЕЖДУ &парамНачало И &парамКонец
        |ГДЕ
        |    СНСведенияОДоходах.ПериодРегистрации = &парамНачало И
        |    СНСведенияОДоходах.Организация = &парамОрганизация И
        |    РаботникиОрганизации.ФизЛицо ЕСТЬ NULL И
        |    СНИсчисленный.ФизЛицо ЕСТЬ NULL
        |
        |ОБЪЕДИНИТЬ
        |
        |ВЫБРАТЬ
        |    СОСведенияОДоходах.ФизЛицо
        |ИЗ
        |    РегистрНакопления.СОСведенияОДоходах КАК СОСведенияОДоходах
        |
        |    ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.РаботникиОрганизаций.СрезПоследних(
        |                &парамКонец,
        |                Организация = &парамГоловнаяОрганизация
        |                И ВидЗанятости <> &парамВнутреннееСовместительство) КАК РаботникиОрганизации
        |        ПО СОСведенияОДоходах.ФизЛицо = РаботникиОрганизации.ФизЛицо
        |
        |    ЛЕВОЕ СОЕДИНЕНИЕ РегистрНакопления.СОРасчетыСФондами КАК СОРасчетыСФондами
        |        ПО СОСведенияОДоходах.Физлицо = СОРасчетыСФондами.ФизЛицо
        |           И СОРасчетыСФондами.Организация = &парамОрганизация
        |           И СОРасчетыСФондами.Период МЕЖДУ &парамНачало И &парамКонец
        |           И СОРасчетыСФондами.ВидДвижения = &парамПриход
        |           И СОРасчетыСФондами.ВидСтроки = &парамИсчисление
        |ГДЕ
        |    СОСведенияОДоходах.ПериодРегистрации = &парамНачало И
        |    СОСведенияОДоходах.Организация = &парамОрганизация И   
        |    РаботникиОрганизации.ФизЛицо ЕСТЬ NULL И
        |    СОРасчетыСФондами.ФизЛицо ЕСТЬ NULL
        |ОБЪЕДИНИТЬ
        |
        |ВЫБРАТЬ
        |    ОППВСведенияОДоходах.ФизЛицо
        |ИЗ
        |    РегистрНакопления.ОППВСведенияОДоходах КАК ОППВСведенияОДоходах
        |
        |    ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.РаботникиОрганизаций.СрезПоследних(
        |                &парамКонец,
        |                Организация = &парамГоловнаяОрганизация) КАК РаботникиОрганизации
        |        ПО ОППВСведенияОДоходах.ФизЛицо = РаботникиОрганизации.ФизЛицо
        |            И РаботникиОрганизации.ОбособленноеПодразделение = &парамОрганизация
        |           И (ВЫБОР
        |                КОГДА (РаботникиОрганизации.ПричинаИзмененияСостояния = &Уволен
        |                    И РаботникиОрганизации.Период >= &парамНачало)
        |                    ИЛИ РаботникиОрганизации.ПричинаИзмененияСостояния <> &Уволен
        |                    ТОГДА ИСТИНА
        |                ИНАЧЕ ЛОЖЬ
        |            КОНЕЦ)
        |
        |ГДЕ
        |    ОППВСведенияОДоходах.ПериодРегистрации = &парамНачало И
        |    ОППВСведенияОДоходах.Организация = &парамОрганизация И
        |    РаботникиОрганизации.ФизЛицо ЕСТЬ NULL
        |";
    
        Если ПостроительЗапроса = Неопределено Тогда
            Запрос.Текст = СписокРаботниковТекст;
            Запрос.Выполнить();
            СписокРаботниковТекст = "ВТ_СписокРаботников";
        Иначе       
            СписокРаботниковТекст = СтрЗаменить(СписокРаботниковТекст,"РАЗРЕШЕННЫЕ","");
            СписокРаботниковТекст = "(" + СтрЗаменить(СписокРаботниковТекст,"ПОМЕСТИТЬ ВТ_СписокРаботников","") + ")";
        КонецЕсли;
    
    
        Если мОрганизацияЯвляетсяПлательщикомСН Тогда
    
            // заполнение табличной части "ИсчисленныйСН", если налоговый режим не на основе упрощенной декларации
            ИсчисленныйСНТекст =
            "ВЫБРАТЬ РАЗЛИЧНЫЕ РАЗРЕШЕННЫЕ
            |    Работники.ФизЛицо,
            |    &парамНачало КАК МесяцНалоговогоПериода
            |ИЗ
            |    РегистрНакопления.СНСведенияОДоходах КАК СНСведенияОДоходах
            |        ВНУТРЕННЕЕ СОЕДИНЕНИЕ " + СписокРаботниковТекст + " КАК Работники
            |        ПО СНСведенияОДоходах.ФизЛицо = Работники.ФизЛицо
            |
            |ГДЕ
            |    СНСведенияОДоходах.ПериодРегистрации = &парамНачало И
            |    СНСведенияОДоходах.Организация = &парамОрганизация
            |";
           
            Если ПостроительЗапроса = Неопределено Тогда
                Запрос.Текст = ИсчисленныйСНТекст;
                ТЗИсчисленныйСН = Запрос.Выполнить().Выгрузить();
            Иначе
                ПостроительЗапроса.Текст = ИсчисленныйСНТекст;
                ПостроительЗапроса.Выполнить();
                ТЗИсчисленныйСН = ПостроительЗапроса.Результат.Выгрузить();
            КонецЕсли;
            ИсчисленныйСН.Загрузить(ТЗИсчисленныйСН);
       
        КонецЕсли;
       
        // заполнение табличной части "ИсчисленныеСО"
       
        // ФизлицаБезСоциальногоСтрахования
        //    Поля:
        //        Физлицо
        //
        //    Описание:
        //    список физлиц не подлежащих социальному страхованию
        ФизлицаБезСоциальногоСтрахованияТекст = "
        |ВЫБРАТЬ РАЗЛИЧНЫЕ
        |    ГражданствоФизЛиц.ФизЛицо
        |ИЗ
        |    РегистрСведений.ГражданствоФизЛиц.СрезПоследних(&парамКонец) КАК ГражданствоФизЛиц
        |
        |ГДЕ
        |    (ГражданствоФизЛиц.НеПодлежитСоциальномуСтрахованию)";
       
        // ФизлицаПенсионеры
        //    Поля:
        //        Физлицо
        //
        //    Описание:
        //    список физлиц достигших пенсионный возраст
        ФизлицаПенсионерыТекст = "
        |ВЫБРАТЬ РАЗЛИЧНЫЕ
        |    СведенияОПенсионномОбеспеченииФизЛиц.ФизЛицо
        |ИЗ
        |    РегистрСведений.СведенияОПенсионномОбеспеченииФизЛиц.СрезПоследних(&парамКонец) КАК СведенияОПенсионномОбеспеченииФизЛиц
        |
        |ГДЕ
        |    (СведенияОПенсионномОбеспеченииФизЛиц.Пенсионер)";
    
        ИсчисленныеСОТекст =
        "ВЫБРАТЬ РАЗЛИЧНЫЕ РАЗРЕШЕННЫЕ
        |    Работники.ФизЛицо,
        |    &парамНачало КАК МесяцНалоговогоПериода
        |ИЗ
        |    РегистрНакопления.СОСведенияОДоходах КАК СОСведенияОДоходах
        |        ВНУТРЕННЕЕ СОЕДИНЕНИЕ (" + СписокРаботниковТекст + ") КАК Работники
        |        ПО СОСведенияОДоходах.ФизЛицо = Работники.ФизЛицо
        |
        |ГДЕ
        |    СОСведенияОДоходах.ПериодРегистрации = &парамНачало И
        |    СОСведенияОДоходах.Организация = &парамОрганизация И
        |    СОСведенияОДоходах.ФизЛицо НЕ В (" + ФизлицаПенсионерыТекст + ") И
        |    СОСведенияОДоходах.ФизЛицо НЕ В (" + ФизлицаБезСоциальногоСтрахованияТекст + ")
        |";
       
        Если ПостроительЗапроса = Неопределено Тогда
            Запрос.Текст = ИсчисленныеСОТекст;
            ТЗИсчисленныеСО = Запрос.Выполнить().Выгрузить();
        Иначе
            ПостроительЗапроса.Текст = ИсчисленныеСОТекст;
            ПостроительЗапроса.Выполнить();
            ТЗИсчисленныеСО = ПостроительЗапроса.Результат.Выгрузить();
        КонецЕсли;
        ИсчисленныеСО.Загрузить(ТЗИсчисленныеСО);
       
       
       
            // заполнение табличной части "ИсчисленныйОППВ"   
        Если мОрганизацияЯвляетсяВкладчикомОППВ Тогда
           
            // ФизлицаБезПраваНаПенсию
            //    Поля:
            //        Физлицо
            //
            //    Описание:
            //    список физлиц не имеющих право на пенсионное обеспечение
            ФизлицаБезПраваНаПенсиюТекст = "
            |ВЫБРАТЬ РАЗЛИЧНЫЕ РАЗРЕШЕННЫЕ
            |    ГражданствоФизЛиц.ФизЛицо
            |ПОМЕСТИТЬ ВТ_ФизлицаБезПраваНаПенсию
            |ИЗ
            |    РегистрСведений.ГражданствоФизЛиц.СрезПоследних(&парамКонец) КАК ГражданствоФизЛиц
            |
            |ГДЕ
            |    (ГражданствоФизЛиц.НеИмеетПравоНаПенсию)";
                   
            Если ПостроительЗапроса = Неопределено Тогда
                Запрос.Текст = ФизлицаБезПраваНаПенсиюТекст;
                Запрос.Выполнить();                                                
                ФизлицаБезПраваНаПенсиюТекст = "ВТ_ФизлицаБезПраваНаПенсию";
            Иначе       
                ФизлицаБезПраваНаПенсиюТекст = СтрЗаменить(ФизлицаБезПраваНаПенсиюТекст,"РАЗРЕШЕННЫЕ","");
                ФизлицаБезПраваНаПенсиюТекст = "(" + СтрЗаменить(ФизлицаБезПраваНаПенсиюТекст,"ПОМЕСТИТЬ ВТ_ФизлицаБезПраваНаПенсию","") + ")";
            КонецЕсли;
       
            ИсчисленныйОППВТекст =
            "ВЫБРАТЬ РАЗЛИЧНЫЕ РАЗРЕШЕННЫЕ
            |    Работники.ФизЛицо,
            |    &парамНачало КАК МесяцНалоговогоПериода
            |ИЗ
            |    РегистрНакопления.ОППВСведенияОДоходах КАК ОППВСведенияОДоходах
            |        ВНУТРЕННЕЕ СОЕДИНЕНИЕ (" + СписокРаботниковТекст + ") КАК Работники
            |        ПО ОППВСведенияОДоходах.ФизЛицо = Работники.ФизЛицо
            |
            |ГДЕ
            |    ОППВСведенияОДоходах.ПериодРегистрации = &парамНачало И
            |    ОППВСведенияОДоходах.Организация = &парамОрганизация И
            |    ОППВСведенияОДоходах.ФизЛицо НЕ В (ВЫБРАТЬ ФизЛицо ИЗ " + ФизлицаПенсионерыТекст + " КАК ФизлицаПенсионеры) И
            |    ОППВСведенияОДоходах.ФизЛицо НЕ В (ВЫБРАТЬ ФизЛицо ИЗ " + ФизлицаБезПраваНаПенсиюТекст + " КАК ФизлицаБезПраваНаПенсию)
            |";
                   
            Если ПостроительЗапроса = Неопределено Тогда
                Запрос.Текст = ИсчисленныйОППВТекст;
                ТЗИсчисленныйОППВ = Запрос.Выполнить().Выгрузить();
            Иначе
                ПостроительЗапроса.Текст = ИсчисленныйОППВТекст;
                ПостроительЗапроса.Выполнить();
                ТЗИсчисленныйОППВ = ПостроительЗапроса.Результат.Выгрузить();
            КонецЕсли;
           
            // переносим в табличную часть документа, не затирая существующие строки
            Для Каждого СтрокаТЗ Из ТЗИсчисленныйОППВ Цикл
                НоваяСтрока = ИсчисленныйОППВ.Добавить();
                ЗаполнитьЗначенияСвойств(НоваяСтрока, СтрокаТЗ);
            КонецЦикла;
           
        КонецЕсли;
    
       
       
       
       
       
        Возврат Истина;
       
    КонецФункции // Автозаполнение()
    
  2. alexburn
    Offline

    alexburn Модераторы Команда форума Модератор

    Регистрация:
    5 янв 2009
    Сообщения:
    14.735
    Симпатии:
    508
    Баллы:
    204
    Не нужно делать копипаст :)
    В вашем варианте проще всего сделать через конструктор запроса. Т.е. вставить скопированный текст запроса в запрос.
    sashadeo нравится это.
  3. nomad_irk
    Offline

    nomad_irk Гуру в 1С

    Регистрация:
    20 окт 2008
    Сообщения:
    7.549
    Симпатии:
    716
    Баллы:
    204
    Т.е. вы не можете самостоятельно проанализировать текст процедуры визуально/с помощью отладчика?
    Причина в том, что происходит замена текста используемого запроса.
    --- Объединение сообщений, 12 авг 2015 ---
    Алекс, тут дело даже не в этом совсем.
    ТС просто ленится выполнять свою работу.
  4. Draco
    Offline

    Draco Модераторы Команда форума Модератор

    Регистрация:
    28 окт 2009
    Сообщения:
    13.628
    Симпатии:
    946
    Баллы:
    204
    вот тут косяк

    Если ПостроительЗапроса = Неопределено Тогда
    Запрос.Текст = СписокРаботниковТекст;
    Запрос.Выполнить();
    СписокРаботниковТекст = "ВТ_СписокРаботников";

    что значит просто ВТ_СписокРаботников вы же потом это подставляете вот сюда

    РегистрНакопления.СНСведенияОДоходах КАК СНСведенияОДоходах
    | ВНУТРЕННЕЕ СОЕДИНЕНИЕ " + СписокРаботниковТекст + " КАК Работники

    и что получается
    | ВНУТРЕННЕЕ СОЕДИНЕНИЕ " + ВТ_СписокРаботников + " КАК Работники
    sashadeo нравится это.
  5. TopicStarter Overlay
    sashadeo
    Offline

    sashadeo Опытный в 1С

    Регистрация:
    29 дек 2010
    Сообщения:
    379
    Симпатии:
    0
    Баллы:
    26
    Спасибо огромное теперь понял!

    Не много не понял какой именно текст вставить?
    Весь текст начиная от слова запрос исключая условия?

    Спасибо конечно но я просил помощи, а не рассказов о том как легко это выполнить.
    Люди которые могут быстро визуально найти ошибку мне помогли ОГРОМНОЕ ИМ СПАСИБО!

Поделиться этой страницей