8.х Ошибка,которой не понимаю.

Тема в разделе "Общие вопросы "1С:Предприятие 8"", создана пользователем philvan, 10 фев 2011.

  1. TopicStarter Overlay
    philvan
    Offline

    philvan

    Регистрация:
    7 фев 2011
    Сообщения:
    14
    Симпатии:
    0
    Баллы:
    1
    Вот программа обработчик

    &НаКлиенте
    Процедура ТабличнаяЧасть1КоличествоПриИзменении(Элемент)
    СтрокаТабличнойЧасти=Элементы.ТабличнаяЧасть1.ТекущиеДанные;
    //при вызове этой функции появляется ошибка см.в.конце Элементы.ТабличнаяЧасть1.ТекущиеДанные.Сумма=РаботаСДокументами.ВычислениеСуммы(СтрокаТабличнойЧасти);
    КонецПроцедуры

    Серверная часть
    &НаСервере
    Функция ВычислениеСуммы(Элемент) Экспорт
    ЗначениеСуммы=Элемент.Количество*Элемент.Цена;
    Сообщить(ЗначениеСуммы);
    Возврат ЗначениеСуммы;
    КонецФункции


    Текст Ошибки:
    Ошибка отображения типов:
    Отсутствует отображение для типа "ДанныеФормыЭлементКоллекции"

    Кто знает, что не так пишите. Буду рад.
  2. shurikvz
    Offline

    shurikvz Модераторы Команда форума Модератор

    Регистрация:
    1 окт 2009
    Сообщения:
    8.409
    Симпатии:
    316
    Баллы:
    104
    Дело в том, что ТекущуюСтроку из ТЗ нельзя передавать на сервер. (У типа "ДанныеФормыЭлементКоллекции" отсутствует свойство "Возможен обмен с сервером"). Для того чтобы передать строку на сервер ее надо выгрузить в структуру, передать на сервер эту структуру, с этой структурой сделать то что надо, и вернуть ее на клиент, и заполнить из нее ТЧ.

    В вашем же конкретном примере - на сервер можно вообще ничего не передавать. Можно ведь все на клиенте выполнить.
  3. TerANik
    Offline

    TerANik Профессионал в 1С

    Регистрация:
    19 ноя 2014
    Сообщения:
    997
    Симпатии:
    70
    Баллы:
    54
    Код:
    {Обработка.медАРМПриёмкиТовара.Форма.Форма.Форма(1022)}: Ошибка при вызове метода контекста (ОткрытьФорму)
            ОткрытьФорму("Обработка.медАРМПриёмкиТовара.Форма.ВыборНоменклатуры",ПараметрыФормы,ЭтаФорма,,,, ОбработчикОповещения, Режим);
    по причине:
    Ошибка передачи данных между клиентом и сервером. Значение недопустимого типа.
    по причине:
    Ошибка преобразования данных XDTO:
    Запись значения свойства 'cr':
        форма: Элемент
        имя: {http://v8.1c.ru/8.2/mngsrv/ws}cr
    по причине:
    Ошибка отображения типов:
    Отсутствует отображение для типа 'ДанныеФормыЭлементКоллекции'
    Ребята всё понимаю, но не понимаю какую я ему коллекцию сую? Передаю Структуру.. На что может ругаться?
  4. Dem0lisher
    Offline

    Dem0lisher Профессионал в 1С

    Регистрация:
    4 авг 2009
    Сообщения:
    1.023
    Симпатии:
    51
    Баллы:
    54
    А в структуре что?
  5. TerANik
    Offline

    TerANik Профессионал в 1С

    Регистрация:
    19 ноя 2014
    Сообщения:
    997
    Симпатии:
    70
    Баллы:
    54
    ПараметрыФормы Структура Структура
    АдресТоваровВХранилище "e1cib/tempstorage/ed0e045f-6c9a-43b2-a363-086808153749" Строка
    ТоварыДокумента "e1cib/tempstorage/61c0f15a-394e-4551-ab4a-4fffd87c3d74" Строка
  6. Dem0lisher
    Offline

    Dem0lisher Профессионал в 1С

    Регистрация:
    4 авг 2009
    Сообщения:
    1.023
    Симпатии:
    51
    Баллы:
    54
    Ничего не понял. Попробуй тоже самое, только вместо своих параметров что-нибудь по-проще типа
    "Новый структура("пар1","пар1")".
    Если тут проблем не будет - смотри еще раз свой отбор, может там не просто строки?
    Если проблема сохранится - возможно еще в обработчике оповещения что-то.
  7. TerANik
    Offline

    TerANik Профессионал в 1С

    Регистрация:
    19 ноя 2014
    Сообщения:
    997
    Симпатии:
    70
    Баллы:
    54
    В ПараметрахФормы два значения, оба типа строка.. передаётся адрес на временное хранилище..
    В ОбработкеОповещения передается структура в структуре, во внутренней структуре один параметр, тоже адрес типа строка.
  8. Dem0lisher
    Offline

    Dem0lisher Профессионал в 1С

    Регистрация:
    4 авг 2009
    Сообщения:
    1.023
    Симпатии:
    51
    Баллы:
    54
    Ну поэкспериментируй:
    1. Убери нафиг свои параметры =)
    2. Убери нафиг свой обработчик оповещения =)
  9. TerANik
    Offline

    TerANik Профессионал в 1С

    Регистрация:
    19 ноя 2014
    Сообщения:
    997
    Симпатии:
    70
    Баллы:
    54
    Самое интересное что падает при завершение процедуры создания.
    Код:
    &НаСервере
    Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
       
        // Пропускаем инициализацию, чтобы гарантировать получение формы при передаче параметра "АвтоТест".
        Если Параметры.Свойство("АвтоТест") Тогда
            Возврат;
        КонецЕсли;
       
        ДополнительныеКолонкиНоменклатуры = ЗначениеНастроекПовтИсп.ПолучитьЗначениеКонстанты("ДополнительнаяКолонкаПриОтображенииНоменклатуры");
       
        ТаблицаТоваров.Загрузить(ПолучитьИзВременногоХранилища(Параметры.АдресТоваровВХранилище));
        СкрытьКолонкуУпаковка = Параметры.СкрытьКолонкуУпаковка;
        ТоварыДокументов.Загрузить(ПолучитьИзВременногоХранилища(Параметры.ТоварыДокумента));   
        Если Параметры.Свойство("ПередаватьШтрихкод") Тогда
            ПередаватьШтрихкод = Параметры.ПередаватьШтрихкод;
        КонецЕсли;
       
        Если Параметры.Свойство("ОтображатьОстатки") Тогда
            Элементы.ТаблицаТоваровОстаток.Видимость = Истина;
        КонецЕсли;
       
        ЭтотОбъект.ТекущийЭлемент = Элементы.ТаблицаТоваров;
        Запрос = Новый Запрос;
        Запрос.Текст = "ВЫБРАТЬ
                       |    ХарактеристикиДокумента.Характеристика
                       |ПОМЕСТИТЬ ХарактеристикиДокумента
                       |ИЗ
                       |    &ХарактеристикиДокумента КАК ХарактеристикиДокумента
                       |;
                       |
                       |////////////////////////////////////////////////////////////////////////////////
                       |ВЫБРАТЬ
                       |    НайденныеХарактеристики.Характеристика
                       |ПОМЕСТИТЬ НайденныеХарактеристики
                       |ИЗ
                       |    &НайденныеХарактеристики КАК НайденныеХарактеристики
                       |;
                       |
                       |////////////////////////////////////////////////////////////////////////////////
                       |ВЫБРАТЬ
                       |    ХарактеристикиДокумента.Характеристика
                       |ИЗ
                       |    ХарактеристикиДокумента КАК ХарактеристикиДокумента
                       |        ПОЛНОЕ СОЕДИНЕНИЕ НайденныеХарактеристики КАК НайденныеХарактеристики
                       |        ПО ХарактеристикиДокумента.Характеристика = НайденныеХарактеристики.Характеристика";
        Запрос.Параметры.Вставить("НайденныеХарактеристики",ТаблицаТоваров.Выгрузить());
        Запрос.Параметры.Вставить("ХарактеристикиДокумента",ТоварыДокументов.Выгрузить());
       
        Выборка = Запрос.Выполнить().Выбрать();
        Если Выборка.Количество()>0 Тогда
            Выборка.Следующий();
            Характеристика = Выборка.Характеристика;
            ПараметрыПоиска = Новый Структура;
            ПараметрыПоиска.Вставить("Характеристика",Характеристика);
            МассивСтрок = ЭтотОбъект.ТаблицаТоваров.НайтиСтроки(ПараметрыПоиска);
            ЭтотОбъект.Элементы.ТаблицаТоваров.Текущ1аяСтрока = МассивСтрок[0];
        КонецЕсли;   
       
    КонецПроцедуры
  10. Dem0lisher
    Offline

    Dem0lisher Профессионал в 1С

    Регистрация:
    4 авг 2009
    Сообщения:
    1.023
    Симпатии:
    51
    Баллы:
    54
    Это в каком случае?
    Попробуй просто форму открыть без всего - может она вообще не откроется =)
  11. TerANik
    Offline

    TerANik Профессионал в 1С

    Регистрация:
    19 ноя 2014
    Сообщения:
    997
    Симпатии:
    70
    Баллы:
    54
    Открывается.
  12. Dem0lisher
    Offline

    Dem0lisher Профессионал в 1С

    Регистрация:
    4 авг 2009
    Сообщения:
    1.023
    Симпатии:
    51
    Баллы:
    54
    Неужели вот это работает:
    ЭтотОбъект.Элементы.ТаблицаТоваров.Текущ1аяСтрока = МассивСтрок[0];
    или "1" - это опечатка?
    Оставь свои параметры, но убери обработчик оповещения, что будет?
  13. TerANik
    Offline

    TerANik Профессионал в 1С

    Регистрация:
    19 ноя 2014
    Сообщения:
    997
    Симпатии:
    70
    Баллы:
    54
    Ошибка, уже исправил, сейчас попробую... Но параметр не мой, он был, я просто в него добавил еще одно значение, адрес временного хранилища.
    --- Объединение сообщений, 22 дек 2015 ---
    Переписал процедуру ПриСозданииНаСервере
    Код:
        // Пропускаем инициализацию, чтобы гарантировать получение формы при передаче параметра "АвтоТест".
        Если Параметры.Свойство("АвтоТест") Тогда
            Возврат;
        КонецЕсли;
       
        ДополнительныеКолонкиНоменклатуры = ЗначениеНастроекПовтИсп.ПолучитьЗначениеКонстанты("ДополнительнаяКолонкаПриОтображенииНоменклатуры");
       
        ТаблицаТоваров.Загрузить(ПолучитьИзВременногоХранилища(Параметры.АдресТоваровВХранилище));
        СкрытьКолонкуУпаковка = Параметры.СкрытьКолонкуУпаковка;
        Если Параметры.Свойство("ПередаватьШтрихкод") Тогда
            ПередаватьШтрихкод = Параметры.ПередаватьШтрихкод;
        КонецЕсли;
       
        Если Параметры.Свойство("ОтображатьОстатки") Тогда
            Элементы.ТаблицаТоваровОстаток.Видимость = Истина;
        КонецЕсли;
       
        ЭтотОбъект.ТекущийЭлемент = Элементы.ТаблицаТоваров;
        Если Параметры.Свойство("ТоварыДокумента") Тогда
        ТоварыДокументов.Загрузить(ПолучитьИзВременногоХранилища(Параметры.ТоварыДокумента));   
    
            Запрос = Новый Запрос;
            Запрос.Текст = "ВЫБРАТЬ
            |    ХарактеристикиДокумента.Характеристика
            |ПОМЕСТИТЬ ХарактеристикиДокумента
            |ИЗ
            |    &ХарактеристикиДокумента КАК ХарактеристикиДокумента
            |;
            |
            |////////////////////////////////////////////////////////////////////////////////
            |ВЫБРАТЬ
            |    НайденныеХарактеристики.Характеристика
            |ПОМЕСТИТЬ НайденныеХарактеристики
            |ИЗ
            |    &НайденныеХарактеристики КАК НайденныеХарактеристики
            |;
            |
            |////////////////////////////////////////////////////////////////////////////////
            |ВЫБРАТЬ
            |    ХарактеристикиДокумента.Характеристика
            |ИЗ
            |    ХарактеристикиДокумента КАК ХарактеристикиДокумента
            |        ПОЛНОЕ СОЕДИНЕНИЕ НайденныеХарактеристики КАК НайденныеХарактеристики
            |        ПО ХарактеристикиДокумента.Характеристика = НайденныеХарактеристики.Характеристика";
            Запрос.Параметры.Вставить("НайденныеХарактеристики",ТаблицаТоваров.Выгрузить());
            Запрос.Параметры.Вставить("ХарактеристикиДокумента",ТоварыДокументов.Выгрузить());
           
            Выборка = Запрос.Выполнить().Выбрать();
            Если Выборка.Количество()>0 Тогда
                Выборка.Следующий();
                Характеристика = Выборка.Характеристика;
                ПараметрыПоиска = Новый Структура;
                ПараметрыПоиска.Вставить("Характеристика",Характеристика);
                МассивСтрок = ЭтотОбъект.ТаблицаТоваров.НайтиСтроки(ПараметрыПоиска);
                ЭтотОбъект.Элементы.ТаблицаТоваров.ТекущаяСтрока = МассивСтрок[0];
            КонецЕсли;   
        КонецЕсли;
       
    

    И закоментировал добавление в структуру ТоварыДокумента.. Работает.. т.е. проблема внутри условия получается?

    Мне кажется ему всё таки вот это не нравится ка кто?
    ЭтотОбъект.Элементы.ТаблицаТоваров.ТекущаяСтрока = МассивСтрок[0];
    Последнее редактирование: 22 дек 2015
  14. Dem0lisher
    Offline

    Dem0lisher Профессионал в 1С

    Регистрация:
    4 авг 2009
    Сообщения:
    1.023
    Симпатии:
    51
    Баллы:
    54
    Если у вас "Элементы.ТаблицаТоваров" - это дин.список, то в тек. строку нужно передать ссылку, а если таблица формы - тогда идентификатор строки.
    У вас похоже массивСтрок[0]- это и есть то самое "ДанныеФормыЭлементКоллекции" на которое 1с и орет
    TerANik нравится это.
  15. TerANik
    Offline

    TerANik Профессионал в 1С

    Регистрация:
    19 ноя 2014
    Сообщения:
    997
    Симпатии:
    70
    Баллы:
    54
    Респект и уважуха.. да ТаблицаТоваров это таблица формы.. а МассивСтрок это данные коллекции.

    Возникает вопрос как получить идентификатор...
    Т.е. необходимо следующее.. ТаблицаТоваров это список номенклатуры с характеристиками и есть ТЗ основной формы, где есть характеристика из этой таблицы.. на ней нужно позиционировать при открытии.
  16. Dem0lisher
    Offline

    Dem0lisher Профессионал в 1С

    Регистрация:
    4 авг 2009
    Сообщения:
    1.023
    Симпатии:
    51
    Баллы:
    54
    Значит нужно присвоить идентификатор.
    Можно глянуть в синтакс-помощник - там должно быть "ПолучитьИдентификатор"
    http://www.forum.mista.ru/topic.php?id=550120
    TerANik нравится это.
  17. TerANik
    Offline

    TerANik Профессионал в 1С

    Регистрация:
    19 ноя 2014
    Сообщения:
    997
    Симпатии:
    70
    Баллы:
    54
    ЭтотОбъект.Элементы.ТаблицаТоваров.ТекущаяСтрока = МассивСтрок[0].ПолучитьИдентификатор();
    Вот "Огонь".
  18. Dem0lisher
    Offline

    Dem0lisher Профессионал в 1С

    Регистрация:
    4 авг 2009
    Сообщения:
    1.023
    Симпатии:
    51
    Баллы:
    54
    Ага! Еще "Огонь" есть - ПроцессорВыводаРезультатаКомпоновкиДанныхВКоллекциюЗначений.Вывести();
    А у вас можно по-короче наверное: Элементы.ТаблицаТоваров.ТекущаяСтрока = МассивСтрок[0].ПолучитьИдентификатор();
    без "ЭтотОбъект"

Поделиться этой страницей