8.х Можно ли в запросе как в цикле из числа отнимать полученные данные

Тема в разделе "Конфигурирование на платформе "1С:Предприятие 8"", создана пользователем Ленок87, 29 окт 2012.

  1. shurikvz
    Offline

    shurikvz Модераторы Команда форума Модератор

    Регистрация:
    1 окт 2009
    Сообщения:
    8.409
    Симпатии:
    316
    Баллы:
    104
    Вот этот запрос в консоли запросов попробуйте. Посмотрите что выводит. Так нет?
    Код:
    "ВЫБРАТЬ
    ВнутреннийЗапрос.Сделка,
    СУММА(ВнутреннийЗапрос.СуммаВзаиморасчетовНачальныйОстатокБУ) КАК СуммаВзаиморасчетовНачальныйОстатокБУ,
    СУММА(ВнутреннийЗапрос.СуммаВзаиморасчетовПриходБУ) КАК СуммаВзаиморасчетовПриходБУ,
    СУММА(ВнутреннийЗапрос.СуммаВзаиморасчетовРасходБУ) КАК СуммаВзаиморасчетовРасходБУ,
    СУММА(ВнутреннийЗапрос.СуммаВзаиморасчетовКонечныйОстатокБУ) КАК СуммаВзаиморасчетовКонечныйОстатокБУ,
    СУММА(ВнутреннийЗапрос.СуммаВзаиморасчетовНачальныйОстатокУУ) КАК СуммаВзаиморасчетовНачальныйОстатокУУ,
    СУММА(ВнутреннийЗапрос.СуммаВзаиморасчетовПриходУУ) КАК СуммаВзаиморасчетовПриходУУ,
    СУММА(ВнутреннийЗапрос.СуммаВзаиморасчетовРасходУУ) КАК СуммаВзаиморасчетовРасходУУ,
    СУММА(ВнутреннийЗапрос.СуммаВзаиморасчетовКонечныйОстатокУУ) КАК СуммаВзаиморасчетовКонечныйОстатокУУ
    ПОМЕСТИТЬ ВТ_Взаиморасчеты
    ИЗ
    (ВЫБРАТЬ
    РасчетыПоРеализацииВУсловныхЕдиницахОрганизацииОстаткиИОбороты.Сделка КАК Сделка,
    РасчетыПоРеализацииВУсловныхЕдиницахОрганизацииОстаткиИОбороты.СуммаВзаиморасчетовНачальныйОстаток КАК СуммаВзаиморасчетовНачальныйОстатокБУ,
    РасчетыПоРеализацииВУсловныхЕдиницахОрганизацииОстаткиИОбороты.СуммаВзаиморасчетовРасход КАК СуммаВзаиморасчетовПриходБУ,
    РасчетыПоРеализацииВУсловныхЕдиницахОрганизацииОстаткиИОбороты.СуммаВзаиморасчетовПриход КАК СуммаВзаиморасчетовРасходБУ,
    -РасчетыПоРеализацииВУсловныхЕдиницахОрганизацииОстаткиИОбороты.СуммаВзаиморасчетовКонечныйОстаток КАК СуммаВзаиморасчетовКонечныйОстатокБУ,
    0 КАК СуммаВзаиморасчетовНачальныйОстатокУУ,
    0 КАК СуммаВзаиморасчетовПриходУУ,
    0 КАК СуммаВзаиморасчетовРасходУУ,
    0 КАК СуммаВзаиморасчетовКонечныйОстатокУУ
    ИЗ
    РегистрНакопления.РасчетыПоРеализацииВУсловныхЕдиницахОрганизации.ОстаткиИОбороты(&НачалоПериода, &КонецПериода, , , Организация = &Организация) КАК РасчетыПоРеализацииВУсловныхЕдиницахОрганизацииОстаткиИОбороты
    
    ОБЪЕДИНИТЬ ВСЕ
    
    ВЫБРАТЬ
    ВзаиморасчетыСКонтрагентамиОстаткиИОбороты.Сделка,
    0,
    0,
    0,
    0,
    ВзаиморасчетыСКонтрагентамиОстаткиИОбороты.СуммаВзаиморасчетовНачальныйОстаток,
    ВзаиморасчетыСКонтрагентамиОстаткиИОбороты.СуммаВзаиморасчетовПриход,
    ВзаиморасчетыСКонтрагентамиОстаткиИОбороты.СуммаВзаиморасчетовРасход,
    ВзаиморасчетыСКонтрагентамиОстаткиИОбороты.СуммаВзаиморасчетовКонечныйОстаток
    ИЗ
    РегистрНакопления.ВзаиморасчетыСКонтрагентами.ОстаткиИОбороты(&НачалоПериода, &КонецПериода, , , Организация = &Организация) КАК ВзаиморасчетыСКонтрагентамиОстаткиИОбороты) КАК ВнутреннийЗапрос
    СГРУППИРОВАТЬ ПО
    ВнутреннийЗапрос.Сделка
    ;
    ////////////////////////////////////////////////////////////////////////////////
    ВЫБРАТЬ
    ВТ_Взаиморасчеты.Сделка КАК ЗаказПокупателя,
    ЗаказПокупателя.СуммаДокумента,
    ВТ_Взаиморасчеты.СуммаВзаиморасчетовНачальныйОстатокБУ,
    ВТ_Взаиморасчеты.СуммаВзаиморасчетовПриходБУ,
    ВТ_Взаиморасчеты.СуммаВзаиморасчетовРасходБУ,
    ВТ_Взаиморасчеты.СуммаВзаиморасчетовКонечныйОстатокБУ,
    ВТ_Взаиморасчеты.СуммаВзаиморасчетовНачальныйОстатокУУ,
    ВТ_Взаиморасчеты.СуммаВзаиморасчетовПриходУУ,
    ВТ_Взаиморасчеты.СуммаВзаиморасчетовРасходУУ,
    ВТ_Взаиморасчеты.СуммаВзаиморасчетовКонечныйОстатокУУ
    ИЗ
    ВТ_Взаиморасчеты КАК ВТ_Взаиморасчеты
    ВНУТРЕННЕЕ СОЕДИНЕНИЕ Документ.ЗаказПокупателя КАК ЗаказПокупателя
    ПО ВТ_Взаиморасчеты.Сделка = ЗаказПокупателя.Ссылка"
  2. vartanet
    Offline

    vartanet Опытный в 1С Команда форума

    Регистрация:
    16 ноя 2010
    Сообщения:
    2.698
    Симпатии:
    15
    Баллы:
    29
    вот такой вариант:

    Код:
    ВЫБРАТЬ
    РеализацияТоваровУслуг.Ссылка,
    РеализацияТоваровУслуг.Сделка,
    ВЫБОР
    КОГДА РеализацияТоваровУслуг.ОтражатьВУправленческомУчете
    ТОГДА РеализацияТоваровУслуг.СуммаДокумента
    ИНАЧЕ 0
    КОНЕЦ КАК РасходТовараСуммаУпр,
    ВЫБОР
    КОГДА РеализацияТоваровУслуг.ОтражатьВБухгалтерскомУчете
    ТОГДА РеализацияТоваровУслуг.СуммаДокумента
    ИНАЧЕ 0
    КОНЕЦ КАК РасходТовараСуммаБух,
    NULL КАК ПриходДенегСуммаУпр,
    NULL КАК ПриходДенегСуммаБух
    ПОМЕСТИТЬ Таблица1
    ИЗ
    Документ.РеализацияТоваровУслуг КАК РеализацияТоваровУслуг
    ОБЪЕДИНИТЬ ВСЕ
    ВЫБРАТЬ
    ПлатежноеПоручениеВходящееРасшифровкаПлатежа.Ссылка,
    ПлатежноеПоручениеВходящееРасшифровкаПлатежа.Сделка,
    NULL,
    NULL,
    ВЫБОР
    КОГДА ПлатежноеПоручениеВходящееРасшифровкаПлатежа.Ссылка.ОтраженоВОперУчете
    ТОГДА ПлатежноеПоручениеВходящееРасшифровкаПлатежа.СуммаПлатежа
    ИНАЧЕ 0
    КОНЕЦ,
    ВЫБОР
    КОГДА ПлатежноеПоручениеВходящееРасшифровкаПлатежа.Ссылка.ОтражатьВБухгалтерскомУчете
    ТОГДА ПлатежноеПоручениеВходящееРасшифровкаПлатежа.СуммаПлатежа
    ИНАЧЕ 0
    КОНЕЦ
    ИЗ
    Документ.ПлатежноеПоручениеВходящее.РасшифровкаПлатежа КАК ПлатежноеПоручениеВходящееРасшифровкаПлатежа
    ;
    ////////////////////////////////////////////////////////////////////////////////
    ВЫБРАТЬ
    Таблица1.Ссылка,
    Таблица1.Сделка,
    СУММА(Таблица1.РасходТовараСуммаУпр) КАК РасходТовараСуммаУпр,
    СУММА(Таблица1.РасходТовараСуммаБух) КАК РасходТовараСуммаБух,
    СУММА(Таблица1.ПриходДенегСуммаУпр) КАК ПриходДенегСуммаУпр,
    СУММА(Таблица1.ПриходДенегСуммаБух) КАК ПриходДенегСуммаБух
    ПОМЕСТИТЬ Таблица2
    ИЗ
    Таблица1 КАК Таблица1
    СГРУППИРОВАТЬ ПО
    Таблица1.Ссылка,
    Таблица1.Сделка
    ;
    ////////////////////////////////////////////////////////////////////////////////
    ВЫБРАТЬ
    Таблица2.Ссылка,
    Таблица2.Сделка,
    Таблица2.РасходТовараСуммаУпр,
    Таблица2.РасходТовараСуммаБух,
    Таблица2.ПриходДенегСуммаУпр,
    Таблица2.ПриходДенегСуммаБух,
    ВЫБОР
    КОГДА &ТекущаяДата < ДОБАВИТЬКДАТЕ(Таблица2.Сделка.Дата, ДЕНЬ, Таблица2.Сделка.ДоговорКонтрагента.ЧислоДнейОтсрочкаПлатежа)
    ТОГДА "нормальный пацанчег"
    КОГДА &ТекущаяДата < ДОБАВИТЬКДАТЕ(Таблица2.Сделка.Дата, ДЕНЬ, Таблица2.Сделка.ДоговорКонтрагента.ЧислоДнейОтсрочкаПлатежа + 7)
    ТОГДА "дадим ему шанс исправиться"
    ИНАЧЕ "упырь"
    КОНЕЦ КАК СтатусКонтрагента
    ИЗ
    Таблица2 КАК Таблица2
  3. TopicStarter Overlay
    Ленок87
    Offline

    Ленок87 Опытный в 1С

    Регистрация:
    7 фев 2012
    Сообщения:
    261
    Симпатии:
    0
    Баллы:
    26
    Огромное Вам спасибо за помощь сама бы я не додумалась.Огромное Огромное Вам спасибо!

    Большое Вам спасибо за то что пытались вместе со мной решить мою проблему.К сожалению о вашего запроса я видимо пока не доросла но обещаю что и в нем в скором времени смогу разобраться
  4. vartanet
    Offline

    vartanet Опытный в 1С Команда форума

    Регистрация:
    16 ноя 2010
    Сообщения:
    2.698
    Симпатии:
    15
    Баллы:
    29
    кидайте этот запрос в СКД, чтобы не выводить макет "руками". 4 ресурса: РасходТовараСуммаУпр, РасходТовараСуммаБух, ПриходДенегСуммаУпр, ПриходДенегСуммаБух. группировка по статусу и сделке.

    это я так - на всякий случай.. если вы не знакомы с СКД и попытаетесь отчет программно в макет выводить.
Похожие темы
  1. Amber
    Ответов:
    6
    Просмотров:
    1.626
Загрузка...

Поделиться этой страницей