8.х Как править макет печатной формы?

Собственно сабж
ЗУП 8.1
Конфигуратор > Документы > КадровоеПеремещениеОрганизаций > Макеты > Т5

Надо чтобы в графе надбавка отображался ее размер согласно штатному расписанию. Помогите разобраться

вот так в модуле описан оклад:

Я так понимаю что для премии надо просто скопировать и немного поправить этот кусок коа, но вражения для премии я не знаю...

не все так просто, как кажется с первого взгляда.
Для начала нужно выяснить, содержит ли ВыборкаРаботники нужные данные. Если содержит, то просто добавляем нужный код, подобно приведенному выше, если не содержит - придется ещё и запрос править.

Так вот и проблема в написании этого самого "нужного кода"

Если что-то делали и не получается, выкладывайте сюда - за вас работу никто делать не будет.
Мало того, телепатические способности у программистов мало развиты - какие именно премии вам нужны и в каком виде/месте на печатной форме - никто не знает....

Итак, в Кадровом учете > Штатном Расписании у некоторых должностей к зарплате начисляются фиксированные надбавки.
Необходимо чтобы при распечатке формы Т-5 и Т-5а в графе "тарифная ставка" печаталась кроме ставки еще и надбавка.

Код приведенный в первом посте - описывает вывод на печатную форму оклада! Насколько я понимаю его же (немного подкорректированный) можно использовать и для вывода на печать значения Надбавки.

ну хотя б скриншот того, как хотите видеть эту самую надбавку в форме Т-5 и Т-5а выложите что ли......

Первый скрин показывает что надбавка начисляется работнику данной должности вместе с зарплатой
Второй скрин показывает где я хочу чтобы данная надбавка печаталась - вместе с тарифной ставкой

Я так понимаю, необходимо просто просуммировать надбавку и оклад и результат вывести на место текущей суммы оклада?
Или таки выделить, что оклад - хххх, надбавка - ууууу?

В модуле формы находим процедуру СформироватьЗапросДляПечати. Меняем текст последнего запроса на:

Код:

Запрос.Текст =
"ВЫБРАТЬ
|	ОсновныеНачисления.НомерСтроки,
|	ОсновныеНачисления.Ссылка,
|	ОсновныеНачисления.Сотрудник КАК Сотрудник,
|	ОсновныеНачисления.ВидРасчета,
|	ВЫБОР
|		КОГДА ОсновныеНачисления.ВидРасчета.ПроизвольнаяФормулаРасчета
|			ТОГДА ВЫБОР
|					КОГДА Показатели.Показатель1 В (&ТарифнаяСтавкаОклад)
|							ИЛИ Показатели.Показатель1.ТарифнаяСтавка
|						ТОГДА ОсновныеНачисления.Показатель1
|					КОГДА Показатели.Показатель2 В (&ТарифнаяСтавкаОклад)
|							ИЛИ Показатели.Показатель2.ТарифнаяСтавка
|						ТОГДА ОсновныеНачисления.Показатель2
|					КОГДА Показатели.Показатель3 В (&ТарифнаяСтавкаОклад)
|							ИЛИ Показатели.Показатель3.ТарифнаяСтавка
|						ТОГДА ОсновныеНачисления.Показатель3
|					КОГДА Показатели.Показатель4 В (&ТарифнаяСтавкаОклад)
|							ИЛИ Показатели.Показатель4.ТарифнаяСтавка
|						ТОГДА ОсновныеНачисления.Показатель4
|					КОГДА Показатели.Показатель5 В (&ТарифнаяСтавкаОклад)
|							ИЛИ Показатели.Показатель5.ТарифнаяСтавка
|						ТОГДА ОсновныеНачисления.Показатель5
|					КОГДА Показатели.Показатель6 В (&ТарифнаяСтавкаОклад)
|							ИЛИ Показатели.Показатель6.ТарифнаяСтавка
|						ТОГДА ОсновныеНачисления.Показатель6
|					ИНАЧЕ 0
|				КОНЕЦ
|		ИНАЧЕ ОсновныеНачисления.Показатель1
|	КОНЕЦ КАК Показатель1,
|	ОсновныеНачисления.Валюта1,
|	ВЫБОР
|		КОГДА (НЕ ОсновныеНачисления.ВидРасчета.ТребуетВводаТарифногоРазряда)
|			ТОГДА ВЫБОР
|					КОГДА Показатели.Показатель1.ТипПоказателя = ЗНАЧЕНИЕ(Перечисление.ТипыПоказателейСхемМотивации.ТарифныйРазряд)
|						ТОГДА ОсновныеНачисления.ТарифныйРазряд1
|					КОГДА Показатели.Показатель2.ТипПоказателя = ЗНАЧЕНИЕ(Перечисление.ТипыПоказателейСхемМотивации.ТарифныйРазряд)
|							ИЛИ Показатели.Показатель2.ТарифнаяСтавка
|						ТОГДА ОсновныеНачисления.ТарифныйРазряд2
|					КОГДА Показатели.Показатель3.ТипПоказателя = ЗНАЧЕНИЕ(Перечисление.ТипыПоказателейСхемМотивации.ТарифныйРазряд)
|						ТОГДА ОсновныеНачисления.ТарифныйРазряд3
|					КОГДА Показатели.Показатель4.ТипПоказателя = ЗНАЧЕНИЕ(Перечисление.ТипыПоказателейСхемМотивации.ТарифныйРазряд)
|						ТОГДА ОсновныеНачисления.ТарифныйРазряд4
|					КОГДА Показатели.Показатель5.ТипПоказателя = ЗНАЧЕНИЕ(Перечисление.ТипыПоказателейСхемМотивации.ТарифныйРазряд)
|						ТОГДА ОсновныеНачисления.ТарифныйРазряд5
|					КОГДА Показатели.Показатель6.ТипПоказателя = ЗНАЧЕНИЕ(Перечисление.ТипыПоказателейСхемМотивации.ТарифныйРазряд)
|						ТОГДА ОсновныеНачисления.ТарифныйРазряд6
|					ИНАЧЕ НЕОПРЕДЕЛЕНО
|				КОНЕЦ
|		ИНАЧЕ ОсновныеНачисления.ТарифныйРазряд1
|	КОНЕЦ КАК ТарифныйРазряд1,
|	ОсновныеНачисления.ВидРасчета.ТребуетВводаТарифногоРазряда КАК ТребуетВводаТарифногоРазряда,
|	ОсновныеНачисления.Валюта1.Наименование
|ПОМЕСТИТЬ ВТНачисления
|ИЗ
|	Документ.КадровоеПеремещениеОрганизаций.ОсновныеНачисления КАК ОсновныеНачисления
|		ЛЕВОЕ СОЕДИНЕНИЕ (ВЫБРАТЬ
|			МАКСИМУМ(ВЫБОР
|					КОГДА Показатели.НомерСтроки = 1
|						ТОГДА Показатели.Показатель
|					ИНАЧЕ NULL
|				КОНЕЦ) КАК Показатель1,
|			МАКСИМУМ(ВЫБОР
|					КОГДА Показатели.НомерСтроки = 2
|						ТОГДА Показатели.Показатель
|					ИНАЧЕ NULL
|				КОНЕЦ) КАК Показатель2,
|			МАКСИМУМ(ВЫБОР
|					КОГДА Показатели.НомерСтроки = 3
|						ТОГДА Показатели.Показатель
|					ИНАЧЕ NULL
|				КОНЕЦ) КАК Показатель3,
|			МАКСИМУМ(ВЫБОР
|					КОГДА Показатели.НомерСтроки = 4
|						ТОГДА Показатели.Показатель
|					ИНАЧЕ NULL
|				КОНЕЦ) КАК Показатель4,
|			МАКСИМУМ(ВЫБОР
|					КОГДА Показатели.НомерСтроки = 5
|						ТОГДА Показатели.Показатель
|					ИНАЧЕ NULL
|				КОНЕЦ) КАК Показатель5,
|			МАКСИМУМ(ВЫБОР
|					КОГДА Показатели.НомерСтроки = 6
|						ТОГДА Показатели.Показатель
|					ИНАЧЕ NULL
|				КОНЕЦ) КАК Показатель6,
|			ОсновныеНачисления.НомерСтроки КАК НомерСтроки
|		ИЗ
|			Документ.КадровоеПеремещениеОрганизаций.ОсновныеНачисления КАК ОсновныеНачисления
|				ВНУТРЕННЕЕ СОЕДИНЕНИЕ ПланВидовРасчета.ОсновныеНачисленияОрганизаций.Показатели КАК Показатели
|				ПО ОсновныеНачисления.ВидРасчета = Показатели.Ссылка
|		ГДЕ
|			ОсновныеНачисления.Ссылка = &ДокументСсылка
|			И ОсновныеНачисления.ВидРасчета.ЗачетОтработанногоВремени
|			И ОсновныеНачисления.ВидРасчета.ЗачетНормыВремени
|		
|		СГРУППИРОВАТЬ ПО
|			ОсновныеНачисления.НомерСтроки) КАК Показатели
|		ПО ОсновныеНачисления.НомерСтроки = Показатели.НомерСтроки
|ГДЕ
|	ОсновныеНачисления.Ссылка = &ДокументСсылка
|	И ОсновныеНачисления.ВидРасчета.ЗачетОтработанногоВремени
|	И ОсновныеНачисления.ВидРасчета.ЗачетНормыВремени
|	И (НЕ ОсновныеНачисления.Сторно)
|
|ИНДЕКСИРОВАТЬ ПО
|	Сотрудник
|;
|
|////////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ
|	РаботникиОрганизации.НомерСтроки,
|	РаботникиОрганизации.Ссылка,
|	РаботникиОрганизации.Сотрудник КАК Сотрудник,
|	РаботникиОрганизации.Сотрудник.Физлицо КАК Физлицо,
|	РаботникиОрганизации.Сотрудник.Код КАК ТабельныйНомер,
|	РаботникиОрганизации.Сотрудник.Наименование,
|	РаботникиОрганизации.Сотрудник.ДатаДоговора,
|	РаботникиОрганизации.Сотрудник.НомерДоговора,
|	РаботникиОрганизации.ДатаНачала,
|	РаботникиОрганизации.ДатаОкончания,
|	РаботникиОрганизации.ПодразделениеОрганизации,
|	РаботникиОрганизации.Должность,
|	РаботникиОрганизации.ЗанимаемыхСтавок,
|	РаботникиОрганизации.СпособРасчета,
|	РаботникиОрганизации.ГрафикРаботы,
|	РаботникиОрганизации.ОснованиеПеремещения,
|	РаботникиОрганизации.НапомнитьПоЗавершении
|ПОМЕСТИТЬ ВТРаботники
|ИЗ
|	Документ.КадровоеПеремещениеОрганизаций.РаботникиОрганизации КАК РаботникиОрганизации
|ГДЕ
|	РаботникиОрганизации.Ссылка = &ДокументСсылка
|	И (НЕ РаботникиОрганизации.Сторно)
|
|ИНДЕКСИРОВАТЬ ПО
|	Сотрудник
|;
|
|////////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ
|	ФИОФизЛицСрезПоследних.ФизЛицо КАК ФизЛицо,
|	ФИОФизЛицСрезПоследних.Фамилия,
|	ФИОФизЛицСрезПоследних.Имя,
|	ФИОФизЛицСрезПоследних.Отчество
|ПОМЕСТИТЬ ВТФИОФизЛиц
|ИЗ
|	РегистрСведений.ФИОФизЛиц.СрезПоследних(
|			&ДатаДокумента,
|			ФизЛицо В
|				(ВЫБРАТЬ
|					ВТРаботники.Физлицо
|				ИЗ
|					ВТРаботники)) КАК ФИОФизЛицСрезПоследних
|
|ИНДЕКСИРОВАТЬ ПО
|	ФизЛицо
|;
|
|////////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ
|	СписокДат.Сотрудник КАК Сотрудник,
|	РаботникиОрганизации.ПодразделениеОрганизации.Наименование КАК ПодразделениеОрганизацииНаименование,
|	РаботникиОрганизации.Должность.Наименование КАК ДолжностьНаименование,
|	РаботникиОрганизации.ПодразделениеОрганизацииЗавершения.Наименование КАК ПодразделениеОрганизацииЗавершенияНаименование,
|	РаботникиОрганизации.ДолжностьЗавершения.Наименование КАК ДолжностьЗавершенияНаименование,
|	РаботникиОрганизации.ПериодЗавершения КАК ПериодЗавершения
|ПОМЕСТИТЬ ВТДанныеРаботников
|ИЗ
|	(ВЫБРАТЬ
|		Док.Сотрудник КАК Сотрудник,
|		МАКСИМУМ(РаботникиВнутри.Период) КАК ДатаПоследнегоИзменения
|	ИЗ
|		ВТРаботники КАК Док
|			ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.РаботникиОрганизаций КАК РаботникиВнутри
|			ПО Док.Сотрудник = РаботникиВнутри.Сотрудник
|				И Док.ДатаНачала > РаботникиВнутри.Период
|	
|	СГРУППИРОВАТЬ ПО
|		Док.Сотрудник) КАК СписокДат
|		ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.РаботникиОрганизаций КАК РаботникиОрганизации
|		ПО СписокДат.ДатаПоследнегоИзменения = РаботникиОрганизации.Период
|			И СписокДат.Сотрудник = РаботникиОрганизации.Сотрудник
|
|ИНДЕКСИРОВАТЬ ПО
|	Сотрудник
|;
|
|////////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ
|	СписокДат.НомерСтроки КАК НомерСтроки,
|	РазмерТарифныхСтавок.Размер КАК Размер,
|	РазмерТарифныхСтавок.Валюта КАК Валюта,
|	РазмерТарифныхСтавок.Валюта.Наименование,
|	РазмерТарифныхСтавок.ТарифныйРазряд
|ПОМЕСТИТЬ ВТДанныеТарифныхРазрядов
|ИЗ
|	(ВЫБРАТЬ
|		НачисленияРаботников.НомерСтроки КАК НомерСтроки,
|		МАКСИМУМ(РазмерТарифныхСтавок.Период) КАК ДатаПоследнегоИзменения,
|		РазмерТарифныхСтавок.ТарифныйРазряд КАК ТарифныйРазряд
|	ИЗ
|		(ВЫБРАТЬ
|			Начисления.НомерСтроки КАК НомерСтроки,
|			Работники.ДатаНачала КАК ДатаНачала
|		ИЗ
|			ВТНачисления КАК Начисления
|				ЛЕВОЕ СОЕДИНЕНИЕ ВТРаботники КАК Работники
|				ПО Начисления.Сотрудник = Работники.Сотрудник) КАК НачисленияРаботников
|			ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.РазмерТарифныхСтавок КАК РазмерТарифныхСтавок
|			ПО НачисленияРаботников.ДатаНачала >= РазмерТарифныхСтавок.Период
|	
|	СГРУППИРОВАТЬ ПО
|		НачисленияРаботников.НомерСтроки,
|		РазмерТарифныхСтавок.ТарифныйРазряд) КАК СписокДат
|		ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.РазмерТарифныхСтавок КАК РазмерТарифныхСтавок
|		ПО СписокДат.ДатаПоследнегоИзменения = РазмерТарифныхСтавок.Период
|			И СписокДат.ТарифныйРазряд = РазмерТарифныхСтавок.ТарифныйРазряд
|
|ИНДЕКСИРОВАТЬ ПО
|	НомерСтроки
|;
|
|////////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ
|	Док.НомерСтроки КАК НомерСтроки,
|	Док.ДатаНачала,
|	Док.ДатаОкончания,
|	ЕСТЬNULL(ФИОФизЛицСрезПоследних.Фамилия + "" "" + ФИОФизЛицСрезПоследних.Имя + "" "" + ФИОФизЛицСрезПоследних.Отчество, Док.СотрудникНаименование) КАК Работник,
|	Док.Физлицо.Пол КАК ФизлицоПол,
|	Док.ТабельныйНомер КАК ТабельныйНомер,
|	ЕСТЬNULL(Док.СотрудникДатаДоговора, ДАТАВРЕМЯ(1, 1, 1, 0, 0, 0)) КАК ТрудовойДоговорДата,
|	ЕСТЬNULL(Док.СотрудникНомерДоговора, """") КАК ТрудовойДоговорНомер,
|	Док.ОснованиеПеремещения КАК ОснованиеПеремещения,
|	Док.ПодразделениеОрганизации.Наименование КАК НовоеПодразделение,
|	Док.Должность.Наименование КАК НоваяДолжность,
|	ВЫБОР
|		КОГДА Работники.ПериодЗавершения <= Док.ДатаНачала
|				И Работники.ПериодЗавершения <> ДАТАВРЕМЯ(1, 1, 1, 0, 0, 0)
|			ТОГДА Работники.ПодразделениеОрганизацииЗавершенияНаименование
|		ИНАЧЕ Работники.ПодразделениеОрганизацииНаименование
|	КОНЕЦ КАК ПрежнееПодразделение,
|	ВЫБОР
|		КОГДА Работники.ПериодЗавершения <= Док.ДатаНачала
|				И Работники.ПериодЗавершения <> ДАТАВРЕМЯ(1, 1, 1, 0, 0, 0)
|			ТОГДА Работники.ДолжностьЗавершенияНаименование
|		ИНАЧЕ Работники.ДолжностьНаименование
|	КОНЕЦ КАК ПрежняяДолжность,
|	ВЫБОР
|		КОГДА ЕСТЬNULL(Начисления.ТребуетВводаТарифногоРазряда, ЛОЖЬ)
|			ТОГДА ВЫБОР
|					КОГДА ЕСТЬNULL(РазмерыТарифныхРазрядов.Валюта, &РеглВалюта) = &РеглВалюта
|						ТОГДА """"
|					ИНАЧЕ РазмерыТарифныхРазрядов.ВалютаНаименование
|				КОНЕЦ
|		КОГДА ЕСТЬNULL(Начисления.Валюта1, &РеглВалюта) = &РеглВалюта
|			ТОГДА """"
|		ИНАЧЕ Начисления.Валюта1Наименование
|	КОНЕЦ КАК ВалютаТарифнойСтавки,
|	ВЫБОР
|		КОГДА ЕСТЬNULL(Начисления.ТребуетВводаТарифногоРазряда, ЛОЖЬ)
|			ТОГДА ЕСТЬNULL(РазмерыТарифныхРазрядов.Размер, 0)
|		ИНАЧЕ ВЫБОР
|				КОГДА ЕСТЬNULL(Начисления.Показатель1, 0) = 0
|						И ЕСТЬNULL(РазмерыТарифныхРазрядов.Размер, 0) <> 0
|					ТОГДА ЕСТЬNULL(РазмерыТарифныхРазрядов.Размер, 0)
|				ИНАЧЕ ЕСТЬNULL(Начисления.Показатель1 + НадбавкиПоШтатномуРасписаниюОрганизаций.Показатель1, 0)
|			КОНЕЦ
|	КОНЕЦ КАК ОкладТарифнаяСтавка
|ИЗ
|	ВТРаботники КАК Док
|		ЛЕВОЕ СОЕДИНЕНИЕ ВТФИОФизЛиц КАК ФИОФизЛицСрезПоследних
|		ПО Док.Физлицо = ФИОФизЛицСрезПоследних.ФизЛицо
|		ЛЕВОЕ СОЕДИНЕНИЕ ВТДанныеРаботников КАК Работники
|		ПО Док.Сотрудник = Работники.Сотрудник
|		ЛЕВОЕ СОЕДИНЕНИЕ ВТНачисления КАК Начисления
|			ЛЕВОЕ СОЕДИНЕНИЕ ВТДанныеТарифныхРазрядов КАК РазмерыТарифныхРазрядов
|			ПО Начисления.НомерСтроки = РазмерыТарифныхРазрядов.НомерСтроки
|				И Начисления.ТарифныйРазряд1 = РазмерыТарифныхРазрядов.ТарифныйРазряд
|		ПО Док.Сотрудник = Начисления.Сотрудник
|		ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.НадбавкиПоШтатномуРасписаниюОрганизаций КАК НадбавкиПоШтатномуРасписаниюОрганизаций
|		ПО Док.ПодразделениеОрганизации = НадбавкиПоШтатномуРасписаниюОрганизаций.ПодразделениеОрганизации
|			И Док.Должность = НадбавкиПоШтатномуРасписаниюОрганизаций.Должность
|
|УПОРЯДОЧИТЬ ПО
|	НомерСтроки";

Проверяем результат

такой вариант будет корректно работать ТОЛЬКО в случае, когда надбавка - фиксированная сумма, другие варианты начисления надбавок можете описать сами.

p.s. однако, в запросе нужно использовать срез последних на дату &ДатаДокумента.
почему-то не могу отредактировать своё сообщение.....

Спасибо работает, но мне нужно чтобы именно выделить, что оклад - хххх, надбавка - ууууу
Заранее спасибо за помощь

Выделение надбавки влечет переделывание механизма формирования строк(надбавок может быть несколько и разных) - нужно ещё процедуру вывода менять - в масштабах форума несколько проблематично......