8.х Как открыть форму РеализацияТоваровУслуг

Тема в разделе "Конфигурирование на платформе "1С:Предприятие 8"", создана пользователем __Вячеслав__, 4 янв 2015.

  1. TopicStarter Overlay
    __Вячеслав__
    Offline

    __Вячеслав__

    Регистрация:
    4 янв 2015
    Сообщения:
    7
    Симпатии:
    0
    Баллы:
    1
    Доброго времени суток.
    Подскажите как открыть форму документа РеализацияТоваровУслуг именно услуги,
    а то открываются только товары.
    Открываю так:
    Код:
    &НаКлиенте
    Процедура ОткрытьФормуНезаписанногоДокумента(Команда)
       мФорма = ПолучитьФорму("Документ.РеализацияТоваровУслуг.Форма.ФормаДокументаУслуги");
      ДокОбъект = мФорма.Объект;
      ОткрытьФормуНезаписанногоДокументаНаСервере(ДокОбъект);
      КопироватьДанныеФормы(ДокОбъект, мФорма.Объект);
      мФорма.Открыть();
    КонецПроцедуры
    
    
    &НаСервере
    Процедура ОткрытьФормуНезаписанногоДокументаНаСервере(ДокОбъект)
       НовыйДокумент= Документы.РеализацияТоваровУслуг.СоздатьДокумент();  
       НовыйДокумент.Дата=ТекущаяДата();
       НовыйДокумент.СпособЗачетаАвансов=Перечисления.СпособыЗачетаАвансов.Автоматически;  
       //поиск контрагента
       НайденнаяСсылка=Справочники.Контрагенты.НайтиПоНаименованию(ЗначениеАрендатор);
       НовыйДокумент.Контрагент=НайденнаяСсылка;  
       //добавлям табличную часть
       ТабличнаяЧасть=НовыйДокумент.Услуги;
       НоваяСтрока=ТабличнаяЧасть.Добавить();
       НоваяСтрока.Номенклатура=Справочники.Номенклатура.НайтиПоНаименованию("Услуги по аренде");
       НоваяСтрока.Содержание="Арендная плата за "+ Формат(ЗначениеДатаС, "ДФ=ММММ"); 
       НоваяСтрока.Количество=1;
       НоваяСтрока.Сумма=ЗначениеСумма;
       ЗначениеВДанныеФормы(НовыйДокумент,ДокОбъект);
    КонецПроцедуры
    
    Заранее благодарен.
    Последнее редактирование модератором: 23 янв 2015
  2. LordMaverick
    Offline

    LordMaverick Профессионал в 1С

    Регистрация:
    17 мар 2014
    Сообщения:
    3.429
    Симпатии:
    372
    Баллы:
    104
    конфигурация?
  3. TopicStarter Overlay
    __Вячеслав__
    Offline

    __Вячеслав__

    Регистрация:
    4 янв 2015
    Сообщения:
    7
    Симпатии:
    0
    Баллы:
    1
    1С:Предприятие 8.3 (8.3.4.437)
    Бухгалтерия предприятия (базовая), редакция 3.0 (3.0.32.7)
  4. LordMaverick
    Offline

    LordMaverick Профессионал в 1С

    Регистрация:
    17 мар 2014
    Сообщения:
    3.429
    Симпатии:
    372
    Баллы:
    104
    8.3 это платформа, я спросил конфигурацию
  5. TopicStarter Overlay
    __Вячеслав__
    Offline

    __Вячеслав__

    Регистрация:
    4 янв 2015
    Сообщения:
    7
    Симпатии:
    0
    Баллы:
    1
    Бухгалтерия предприятия (базовая), редакция 3.0 (3.0.32.7)
  6. LordMaverick
    Offline

    LordMaverick Профессионал в 1С

    Регистрация:
    17 мар 2014
    Сообщения:
    3.429
    Симпатии:
    372
    Баллы:
    104
    сие окошко ни о чём не говорит?
    upload_2015-1-5_0-13-0.png
    --- Объединение сообщений, 4 янв 2015 ---
    модуль формы документа, там идёт передача параметров, вам их надо заполнить
    Код:
    ////////////////////////////////////////////////////////////////////////////////
    // ОБРАБОТЧИКИ СОБЫТИЙ ФОРМЫ
    
    &НаСервере
    Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
       
        Если Параметры.Ключ.Пустая() Тогда
            ПодготовитьФормуНаСервере();
        КонецЕсли;
       
        Если Параметры.Свойство("ИзменитьВидОперации") Тогда
            ИзменитьВидОперации = Истина;
        КонецЕсли;
       
    КонецПроцедуры
    
    &НаСервере
    Процедура ПриЧтенииНаСервере(ТекущийОбъект)
       
        ПодготовитьФормуНаСервере();
       
    КонецПроцедуры
    
    ////////////////////////////////////////////////////////////////////////////////
    // ОБРАБОТЧИКИ КОМАНД ФОРМЫ
    
    &НаКлиенте
    Процедура ОткрытьДокумент(Команда)
       
        СтрокаТаблицы = Элементы.СписокВидовОпераций.ТекущиеДанные;
       
        Если НЕ СтрокаТаблицы = Неопределено Тогда
           
            ОткрытьДокументВида(СтрокаТаблицы.Значение);
           
        КонецЕсли;
           
    КонецПроцедуры
    
    ////////////////////////////////////////////////////////////////////////////////
    // СЛУЖЕБНЫЕ ПРОЦЕДУРЫ И ФУНКЦИИ
    
    &НаСервере
    Процедура ПодготовитьФормуНаСервере()
       
        ЗначениеКопирования = Параметры.ЗначениеКопирования;
        ЗначенияЗаполнения  = Параметры.ЗначенияЗаполнения;
        Основание           = Параметры.Основание;
       
        Параметры.ЗначениеКопирования    = Неопределено;
        Параметры.ЗначенияЗаполнения    = Неопределено;
        Параметры.Основание                = Неопределено;
       
        ФормыДокумента   = Новый ФиксированноеСоответствие(
            Документы.РеализацияТоваровУслуг.ПолучитьСоответствиеВидовОперацийФормам());
           
        ВидыОпераций = ПолучитьСписокВидовОпераций();
        Для Каждого ВидОперации Из ВидыОпераций Цикл
            НоваяОперация = СписокВидовОпераций.Добавить();
            ЗаполнитьЗначенияСвойств(НоваяОперация, ВидОперации);
        КонецЦикла;
       
        Если ЗначениеЗаполнено(Объект.ВидОперации) Тогда
            ВыделенныйЭлементСписка = СписокВидовОпераций.НайтиПоЗначению(Объект.ВидОперации);
            Если ВыделенныйЭлементСписка <> Неопределено Тогда
                Элементы.СписокВидовОпераций.ТекущаяСтрока = ВыделенныйЭлементСписка.ПолучитьИдентификатор();
            КонецЕсли;
        КонецЕсли;
       
    КонецПроцедуры
    
    &НаСервереБезКонтекста
    Функция ПолучитьСписокВидовОпераций()
    
        СписокВидовОпераций = Новый СписокЗначений;
       
        ЗначенияПеречисления = Метаданные.Перечисления.ВидыОперацийРеализацияТоваров.ЗначенияПеречисления;
        Для Каждого ЗначениеПеречисления Из ЗначенияПеречисления Цикл
            ТекущийВидОперации = Перечисления.ВидыОперацийРеализацияТоваров[ЗначениеПеречисления.Имя];
            СписокВидовОпераций.Добавить(ТекущийВидОперации, Строка(ТекущийВидОперации));
        КонецЦикла;
       
        Возврат СписокВидовОпераций;
    
    КонецФункции
    
    &НаКлиенте
    Процедура СписокВидовОперацийВыбор(Элемент, ВыбраннаяСтрока, Поле, СтандартнаяОбработка)
       
        СтрокаТаблицы = СписокВидовОпераций.НайтиПоИдентификатору(ВыбраннаяСтрока);
       
        ОткрытьДокументВида(СтрокаТаблицы.Значение);
    
    КонецПроцедуры
    
    &НаКлиенте
    Процедура ОткрытьДокументВида(ВыбранныйВидОперации)
       
        ЗначенияЗаполнения.Вставить("ВидОперации",            ВыбранныйВидОперации);
       
        СтруктураПараметров = Новый Структура;
        СтруктураПараметров.Вставить("Ключ",                Параметры.Ключ);
        СтруктураПараметров.Вставить("ЗначениеКопирования", ЗначениеКопирования);
        СтруктураПараметров.Вставить("ЗначенияЗаполнения",  ЗначенияЗаполнения);
        СтруктураПараметров.Вставить("Основание",           Основание);
        Если ИзменитьВидОперации И ВыбранныйВидОперации <> Объект.ВидОперации Тогда
            СтруктураПараметров.Вставить("ИзменитьВидОперации", ИзменитьВидОперации);
        КонецЕсли;
       
        Модифицированность = Ложь;
        Закрыть();
       
        Если ВыбранныйВидОперации = ПредопределенноеЗначение("Перечисление.ВидыОперацийРеализацияТоваров.Товары") Тогда
            КлючеваяОперация = "СозданиеФормыРеализацияТоваровУслугТовары";
        ИначеЕсли ВыбранныйВидОперации = ПредопределенноеЗначение("Перечисление.ВидыОперацийРеализацияТоваров.Услуги") Тогда
            КлючеваяОперация = "СозданиеФормыРеализацияТоваровУслугУслуги";
        Иначе
            КлючеваяОперация = "СозданиеФормыРеализацияТоваровУслугОбщая";
        КонецЕсли;
        ОценкаПроизводительностиКлиентСервер.НачатьЗамерВремени(КлючеваяОперация);
       
        ОткрытьФорму("Документ.РеализацияТоваровУслуг.Форма." + ФормыДокумента[ВыбранныйВидОперации], СтруктураПараметров, ВладелецФормы);
       
    КонецПроцедуры
    
    --- Объединение сообщений, 4 янв 2015 ---
    upload_2015-1-5_0-19-23.png
    Последнее редактирование: 4 янв 2015
  7. TopicStarter Overlay
    __Вячеслав__
    Offline

    __Вячеслав__

    Регистрация:
    4 янв 2015
    Сообщения:
    7
    Симпатии:
    0
    Баллы:
    1
    Большое спасибо!
  8. LordMaverick
    Offline

    LordMaverick Профессионал в 1С

    Регистрация:
    17 мар 2014
    Сообщения:
    3.429
    Симпатии:
    372
    Баллы:
    104
    Пользуйтесь на здоровье.
  9. TopicStarter Overlay
    __Вячеслав__
    Offline

    __Вячеслав__

    Регистрация:
    4 янв 2015
    Сообщения:
    7
    Симпатии:
    0
    Баллы:
    1
    Вопрос так и остался открытым!
    Последнее редактирование: 5 янв 2015
  10. TopicStarter Overlay
    __Вячеслав__
    Offline

    __Вячеслав__

    Регистрация:
    4 янв 2015
    Сообщения:
    7
    Симпатии:
    0
    Баллы:
    1
    Уфф не язык, а дерьмо!
    Структура внутри структуры!

    СтруктураПараметров = Новый Структура;
    ЗначенияЗаполнения = Новый Структура;
    ВидОперации = ПредопределенноеЗначение("Перечисление.ВидыОперацийРеализацияТоваров.Услуги");
    ЗначенияЗаполнения.Вставить("ВидОперации", ВидОперации);

    СтруктураПараметров.Вставить("ЗначенияЗаполнения", ЗначенияЗаполнения);

    ОткрытьФорму("Документ.РеализацияТоваровУслуг.ФормаОбъекта", СтруктураПараметров, ЭтаФорма);
Похожие темы
  1. kogor
    Ответов:
    13
    Просмотров:
    1.654
Загрузка...

Поделиться этой страницей