8.х УПП ГТД по импорту

Тема в разделе ""1С:Управление производственным предприятием УПП"", создана пользователем Goldy, 22 мар 2011.

  1. TopicStarter Overlay
    Goldy
    Offline

    Goldy Опытный в 1С

    Регистрация:
    14 апр 2009
    Сообщения:
    57
    Симпатии:
    0
    Баллы:
    26
    Добрый день всем! Помогите, пожалуйста, разобраться как правильно нужно вводить документ ГТД по импорту, если по ГТД несколько товаров в дополнении????
  2. x_under
    Offline

    x_under Модераторы Команда форума Модератор

    Регистрация:
    25 апр 2007
    Сообщения:
    2.576
    Симпатии:
    13
    Баллы:
    29
    Укажите наименование конфигурации, в которой вы хотите провести данныю операцию.
  3. TopicStarter Overlay
    Goldy
    Offline

    Goldy Опытный в 1С

    Регистрация:
    14 апр 2009
    Сообщения:
    57
    Симпатии:
    0
    Баллы:
    26
    1С Предприятие 8.2 (8.2.12.92) комплексная автоматизация ред 1.1(1.1.6.1)
  4. Svb
    Offline

    Svb Опытный в 1С Команда форума

    Регистрация:
    12 янв 2011
    Сообщения:
    980
    Симпатии:
    19
    Баллы:
    29
    Тоже пытаюсь разобраться с этим механизмом.
    Я делаю так:
    1. Делаю заказ поставщику, перечисляю там необходимые товары
    2. Делаю аванс по этому заказу
    3. Ввожу на основании заказа документ "ГТД по импорту", там на вкладке "Разделы ГТД" перечислены товары из Заказа.
    4. Указываю платежи, сборы.
    Или проблема в чем-то другом?
    Если есть книга из поставки то в части 3 на страницах 167-175 описан весь этот механизм.

    У меня засада в другом:
    1. Нет в конфигурации отдельного поля для ввода акцизных платежей
    2. В счет-фактуре выдаваемой требуется указывать номер ГТД в таком виде "ХХХХХХ\ХХХХХ\ХХХХ\<номер товара в ГТД>", например 10009150/170810/0008007/3. И вот непонятно как это правильно сделать, вариант ввести кучу ГТД с этой дополнительной цифрой как-то не очень.
  5. TopicStarter Overlay
    Goldy
    Offline

    Goldy Опытный в 1С

    Регистрация:
    14 апр 2009
    Сообщения:
    57
    Симпатии:
    0
    Баллы:
    26
    Да эта ситуация не только с акцизными платежами, но и с товаром другим. Да, получается, что если по одной ГТД несколько товаров с разными ТНВЭД то нужно формировать столько ГТД сколько товаров в ней, чтобы номер ГТД фиксировался правильно, т.е. как написали выше....((( но это не радует, т.к. по логике тогда нужно пропорционально считать сбор таможенный.....
  6. Svb
    Offline

    Svb Опытный в 1С Команда форума

    Регистрация:
    12 янв 2011
    Сообщения:
    980
    Симпатии:
    19
    Баллы:
    29
    Итог, как я понимаю в КА 1.1.5.1:
    1. для каждого номера ГТД необходимо создавать свой документ "ГТД по импорту"
    2. акциз необходимо вручную разбивать по товарам в ГТД и руками приплюсовывать к пошлине в таблице товаров.
  7. Hr0n
    Offline

    Hr0n Опытный в 1С

    Регистрация:
    17 авг 2009
    Сообщения:
    353
    Симпатии:
    0
    Баллы:
    26
    Имел плотный опыт работы с этим документом.
    Задача стояла именно такая: автоматическое разнесение расходов по ГТД, по разделам.
    Таможим товар сами, брокер работает в ГТД-Альта.
    Как вышел из ситуации: создал свой документ ГТД, куда подгружаю из XML-контейнера данные по кодам ТНВЭД (у нас 1 код ТНВЭД - 1 раздел ГТД). Загружаются сводные данные по разделам (пошлина, НДС), + другие нужные данные (сбор, дата, поставщик, договор поставщика и т.д.) Затем при загрузке в бухию, заполняю разделы программно в документе ГТД по Импорту на основании моего документа, добавляю недостающие реквизиты, распределяю пошлину и НДС по номенклатуре, привязываю к номенклатуре номера разделов.
    В итоге получаем полностью автоматически заполняемый документ
  8. Hr0n
    Offline

    Hr0n Опытный в 1С

    Регистрация:
    17 авг 2009
    Сообщения:
    353
    Симпатии:
    0
    Баллы:
    26
    типовой документ поддерживает большое количество разделов, только по умолчанию создает 1, куда и кидает все товары. Типовой код:
    Код:
    // Заполним Табличную часть 
    Раздел = ДобавитьРаздел();
    ЗаполнитьПоПоступлению(Основание, 1);
    
    Причем не отображается ТЧ "Разделы", если раздел всего 1, а есть только отдельные реквизиты для заполнения (вспомните документы расчетные документы вроде ПКО и редактирование списком).
  9. Hr0n
    Offline

    Hr0n Опытный в 1С

    Регистрация:
    17 авг 2009
    Сообщения:
    353
    Симпатии:
    0
    Баллы:
    26
    Создал в документе ГТДИмпорт реквизит ДокументОснование и реквизит ГТД (мой документ на основании XML-контейнера). У меня КодТНВЭД это характеристика номенклатуры, справочник с реквизитами Код, Наименование, СтавкаНДС. Обработку заполнения вынес в общий модуль, чтобы не портить типовую конфигурацию (работало в БУ 2.0, сейчас перенес в КА 1.1)

    Код:
    Процедура ЗаполнитьГТДПоИмпорту(Объект) Экспорт
    
    Объект.Товары.Загрузить(Объект.ДокументОснование.Товары.Выгрузить());
    МассивФактурнаяСтоимость = Объект.ДокументОснование.Товары.ВыгрузитьКолонку("Сумма");
    Объект.Товары.ЗагрузитьКолонку(МассивФактурнаяСтоимость, "ФактурнаяСтоимость");
    
    //формируем список разделов из характеристик номенклатуры
    Разделы = СформироватьРазделыДляГТД(Объект.ДокументОснование);
    //создаем разделы по сформированной таблице
    Для Каждого СтрокаРаздел Из Разделы Цикл
    Отбор = Новый Структура;
    Отбор.Вставить("КодТНВЭД", СтрокаРаздел.КодТНВЭД);
    Результат = Объект.ГТД.Товары.НайтиСтроки(Отбор);
    Если Результат.Количество() = 0 Тогда
    Сообщить("Не найдено раздела " + СтрокаРаздел.КодТНВЭД + " в ГТД!");
    Возврат;
    КонецЕсли;
    СтрокаГТД = Результат[0];
    //заполняем раздел данными ГТД
    Раздел = Объект.Разделы.Добавить();
    ЗаполнитьЗначенияСвойств(Раздел, СтрокаГТД);
    ЗаполнитьЗначенияСвойств(Раздел, СтрокаРаздел);                     
    //проставляем номер раздела в ТЧ Номенклатуры
    Для Каждого Строка Из Объект.Товары Цикл
    Строка.ДокументПартии = Объект.ДокументОснование;           
    Если НайтиКодТНВЭД(Строка.ХарактеристикаНоменклатуры) = СтрокаРаздел.КодТНВЭД Тогда
    Строка.НомерРаздела = Раздел.НомерСтроки;
    КонецЕсли;
    КонецЦикла;
    КонецЦикла;
    
    //распределим пошлину и НДС по разделам
    Для Каждого Раздел Из Объект.Разделы Цикл
    РаспределитьПоРазделу(Раздел, Объект.Товары);
    КонецЦикла;
    
    КонецПроцедуры
    
    
    Функция СформироватьРазделыДляГТД(Поступление)
    
    Запрос = Новый Запрос;
    Запрос.Текст = 
    "ВЫБРАТЬ РАЗЛИЧНЫЕ
    |    ЗначенияСвойствОбъектов.Значение КАК КодТНВЭД,
    |    КодТНВЭД.СтавкаНДС КАК СтавкаНДС,
    |    КодТНВЭД.Код КАК Код,
    |    СУММА(ПоступлениеТовары.Сумма) КАК ТаможеннаяСтоимость
    |ИЗ
    |    Документ.ПоступлениеТоваровУслуг.Товары КАК ПоступлениеТовары
    |        ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.ЗначенияСвойствОбъектов КАК ЗначенияСвойствОбъектов
    |            ВНУТРЕННЕЕ СОЕДИНЕНИЕ Справочник.КодТНВЭД КАК КодТНВЭД
    |            ПО (КодТНВЭД.Ссылка = ЗначенияСвойствОбъектов.Значение)
    |        ПО ПоступлениеТовары.ХарактеристикаНоменклатуры = ЗначенияСвойствОбъектов.Объект
    |ГДЕ
    |    ЗначенияСвойствОбъектов.Свойство = &Свойство
    |    И ПоступлениеТовары.Ссылка = &Ссылка
    |
    |СГРУППИРОВАТЬ ПО
    |    ЗначенияСвойствОбъектов.Значение,
    |    КодТНВЭД.СтавкаНДС,
    |    КодТНВЭД.Код
    |
    |УПОРЯДОЧИТЬ ПО
    |    СтавкаНДС,
    |    Код";
    
    Запрос.УстановитьПараметр("Свойство", ПланыВидовХарактеристик.СвойстваОбъектов.НайтиПоНаименованию("Код ТНВЭД"));
    Запрос.УстановитьПараметр("Ссылка", Поступление);
    Возврат Запрос.Выполнить().Выгрузить().Скопировать(,"КодТНВЭД, СтавкаНДС, ТаможеннаяСтоимость");
    
    КонецФункции
    
    Процедура РаспределитьПоРазделу(Раздел, Товары) Экспорт
    
    // Проверим, есть ли что распределять.
    ТаможеннаяСтоимость = Раздел.ТаможеннаяСтоимость;
    СуммаПошлины        = Раздел.СуммаПошлины;
    СуммаНДС            = Раздел.СуммаНДС;
    
    МассивСтрок  = Товары.НайтиСтроки(Новый Структура("НомерРаздела", Раздел.НомерСтроки));
    БазисРаспределения = Новый Массив();
    //нам важно распределение по количеству а не по фактурной стоимости, т.к. используем не только 1, но и 6 метод ОТС
    ВсегоКоличество = 0;
    Для каждого ЭлементМассива Из МассивСтрок Цикл
    ВсегоКоличество = ВсегоКоличество + ЭлементМассива.Количество;
    БазисРаспределения.Добавить(ЭлементМассива.Количество);
    КонецЦикла;    
    
    Если ВсегоКоличество = 0 Тогда
    
    Сообщить("Общее количество раздела " + Раздел.НомерСтроки + " нулевое!
    |Распределение невозможно.", СтатусСообщения.Важное);
    Возврат;
    
    КонецЕсли;
    
    Если Не СуммаПошлины = 0 Тогда
    МассивРезультатаРаспределения_Пошлина = ОбщегоНазначения.РаспределитьПропорционально(СуммаПошлины, БазисРаспределения);
    КонецЕсли; 
    Если Не СуммаНДС = 0 Тогда
    МассивРезультатаРаспределения_НДС = ОбщегоНазначения.РаспределитьПропорционально(СуммаНДС, БазисРаспределения);
    КонецЕсли;
    
    Для ИндексСтроки =0 по МассивСтрок.Количество()-1 Цикл
    Если не СуммаПошлины = 0 Тогда
    МассивСтрок[ИндексСтроки].СуммаПошлины = МассивРезультатаРаспределения_Пошлина[ИндексСтроки];
    Иначе
    МассивСтрок[ИндексСтроки].СуммаПошлины = 0;
    КонецЕсли; 
    Если не СуммаНДС = 0 Тогда
    МассивСтрок[ИндексСтроки].СуммаНДС = МассивРезультатаРаспределения_НДС[ИндексСтроки];
    Иначе
    МассивСтрок[ИндексСтроки].СуммаНДС = 0;
    КонецЕсли;
    КонецЦикла;
    
    КонецПроцедуры
    
    Функция НайтиКодТНВЭД(ХарактеристикаНоменклатуры) Экспорт
    
    Запрос = Новый Запрос;
    Запрос.Текст =
    "ВЫБРАТЬ ПЕРВЫЕ 1
    |    КодТНВЭД.Ссылка КАК КодТНВЭД
    |ИЗ
    |    РегистрСведений.ЗначенияСвойствОбъектов КАК ЗначенияСвойствОбъектов
    |        ВНУТРЕННЕЕ СОЕДИНЕНИЕ Справочник.КодТНВЭД КАК КодТНВЭД
    |        ПО (КодТНВЭД.Ссылка = ЗначенияСвойствОбъектов.Значение)
    |ГДЕ
    |    ЗначенияСвойствОбъектов.Свойство = &Свойство
    |    И ЗначенияСвойствОбъектов.Объект = &Характеристика";
    Запрос.УстановитьПараметр("Свойство", ПланыВидовХарактеристик.СвойстваОбъектов.НайтиПоНаименованию("Код ТНВЭД"));
    Запрос.УстановитьПараметр("Характеристика", ХарактеристикаНоменклатуры);
    Результат = Запрос.Выполнить().Выгрузить();
    Если Результат.Количество() = 0 Тогда
    Возврат Справочники.КодТНВЭД.ПустаяСсылка();
    Иначе
    Возврат Результат[0].КодТНВЭД;
    КонецЕсли;
    
    КонецФункции
    
    
  10. Svb
    Offline

    Svb Опытный в 1С Команда форума

    Регистрация:
    12 янв 2011
    Сообщения:
    980
    Симпатии:
    19
    Баллы:
    29
    Спасибо, за информацию! В выходные буду пытаться разобраться, наверняка появится еще куча вопросов.
    Объсните, пожалуйста, подробнее.
    У меня в документе "ПоступлениеТоваровИУслуг" допустим 2 строки (2 разных товара с двумя разными ГТД). На основании его , в принципе, я могу сделать один документ "ГТД по импорту", на вкладке "разделы ГТД" будут перечислены мои товары с правильными (различными) номерами ГТД. Но при попытке провести этот документ вываливается "В строке номер "2" табличной части "Товары": Номер ГТД в серии не совпадает с номером ГТД документа!".
    Я правильно Вас понял, что внутренний механизм документа "ГТД по импорту" позволяет корректно провести его, надо только данные в него программно заполнить?

    у меня вроде всегда вкладка "разделы" представляет из себя табличную часть.

    Ваш документ "ГТД" представляет собой контейнер, который загружает в себя сводные данные по ГТД и данные по разделам ГТД? Затем процедура "ЗаполнитьГТДПоИмпорту(Объект)" заполняет данные в типовом "ГТД по импорту" и распределяет сводные данные по разделам?
    Потом документ "ГТД по импорту" проводится без проблем и не ругается что на первой вкладке одна ГТД, а в ТЧ "Разделы ГТД" присутствуют и другие ГТД?
  11. Hr0n
    Offline

    Hr0n Опытный в 1С

    Регистрация:
    17 авг 2009
    Сообщения:
    353
    Симпатии:
    0
    Баллы:
    26
    У меня "ГТД по Импорту" всегда создается на основе одной ГТД. И соответственно эта ГТД содержит в себе разделы, 1 раздел - 1 код ТНВЭД. Т.е. тот документ ГТД который у меня используется, представляет собой расширенную табличную часть "Разделы" с доп. реквизитами. Для удобства добавил к стандартной ТЧ "Разделы" реквизит "Код ТНВЭД".
    К тому же сильно сомневаюсь, что типовой документ поддерживает систему "Много разных ГТД в одном ГТД по Импорту", т.к. у него самого есть реквизит "Номер ГТД". Рекомендую все же воздержаться от заполнения разными ГТД.
  12. Svb
    Offline

    Svb Опытный в 1С Команда форума

    Регистрация:
    12 янв 2011
    Сообщения:
    980
    Симпатии:
    19
    Баллы:
    29
    Понял теперь :)
    Ну да, в нижке написано, что один документ "ГТД по импорту" - одна ГТД.
    Придется тогда делать обработку или документ, который на основании ПоступленияТоваровИУслуг будет делать пакет документов "ГТДпоИмпорту". Но это, конечно, жесть.

    1С - редиски )

    П.С. А как это у Вас один номер ГТД? Вроде существует письмо МинФина, где прописано, что номер ГТД должен содержать в себе номер строки с товаром из приложения к ГТД?
  13. Hr0n
    Offline

    Hr0n Опытный в 1С

    Регистрация:
    17 авг 2009
    Сообщения:
    353
    Симпатии:
    0
    Баллы:
    26
    Видимо вы неправильно истолковали это письмо. Номер ГТД один, листов ГТД может быть сколько угодно. На листах ГТД ведется нумерация, где указано какой из скольки лист ГТД (допустим 2 и 7). Сам же номер ГТД 23 значный, вида КодПоста(8)/ДатаГТД(6)/ПорядковыйНомерГТД(7) - в скобках указал число символов + 2 /. К тому же не совсем понятно с каких пор такими делами заведует МинФин а не ФТС. Ссылку на письмо плиз, проконсультируюсь с нашим брокером.
    У меня 1 поступление товаров услуг по 1 гтд (в среднем, 10-12 кодов ТНВЭД, соответственно столько же разделов), и где-то 300-400 товаров. На основании этого поступления по методам предложенным выше создаю 1 документ ГТДПоИмпорту, и необходимое количество документов ПоступлениеДопРасходов, по 1 на вид расходов (например, расходы на СВХ, на сертификацию и т.д.). Так что по сути в среднем на 300 товаров и 10 кодов ТНВЭД у меня 1 документ ГТДИмпорт.
  14. Svb
    Offline

    Svb Опытный в 1С Команда форума

    Регистрация:
    12 янв 2011
    Сообщения:
    980
    Симпатии:
    19
    Баллы:
    29
    Прикрепил изображение, как это делалось у нас в 7ке.
    Посмотреть вложение 6979
    С письмом это я спутал. Уточнил еще раз, был прецедент, что налоговая из-за отсутствия этого дополнения к номеру ГТД отказалась принять НДС. Потом было решение верх.суда, что действия налоговой не правомерны.
    Но тем не менее, сейчас указываем с "ГТД/номер". Хотелось бы это перенести и в 8ку. :)

    Вложения:

  15. Hr0n
    Offline

    Hr0n Опытный в 1С

    Регистрация:
    17 авг 2009
    Сообщения:
    353
    Симпатии:
    0
    Баллы:
    26
    Намного проще будет вести учет по схеме 1 ГТД / много товаров, т.к. в этом случае создаем в разы меньше документов и повышаем прозрачность всей схемы в целом (+ упрощенный разбор полетов в случае ошибок).
  16. Svb
    Offline

    Svb Опытный в 1С Команда форума

    Регистрация:
    12 янв 2011
    Сообщения:
    980
    Симпатии:
    19
    Баллы:
    29
    С этим согласны все :) Но задача пока есть.
    Спасибо, за содействие!
  17. TopicStarter Overlay
    Goldy
    Offline

    Goldy Опытный в 1С

    Регистрация:
    14 апр 2009
    Сообщения:
    57
    Симпатии:
    0
    Баллы:
    26
    И все равно не понятно. В типовой восьмерке на поступление товаров с разными кодами ТНВЭД создается один документ ГТД по импорту с количеством разделов. соответствующем номерам товаров по ГТД????
  18. Hr0n
    Offline

    Hr0n Опытный в 1С

    Регистрация:
    17 авг 2009
    Сообщения:
    353
    Симпатии:
    0
    Баллы:
    26
    Именно так. Для удобства добавил реквизит "Код ТНВЭД" в ТЧ "Разделы", чтобы легко можно было понять какой раздел активен.
  19. TopicStarter Overlay
    Goldy
    Offline

    Goldy Опытный в 1С

    Регистрация:
    14 апр 2009
    Сообщения:
    57
    Симпатии:
    0
    Баллы:
    26
    а на то что система ругается что не соответсвуют номер ГТД с номерами по разделам не обращать внимания?
  20. Svb
    Offline

    Svb Опытный в 1С Команда форума

    Регистрация:
    12 янв 2011
    Сообщения:
    980
    Симпатии:
    19
    Баллы:
    29
    помоему нельзя проигнорировать это

Поделиться этой страницей